The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4

   1 dnl Copyright (c) 1995, 1996, 1997, 1998
   2 dnl     The Regents of the University of California.  All rights reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms, with or without
   5 dnl modification, are permitted provided that: (1) source code distributions
   6 dnl retain the above copyright notice and this paragraph in its entirety, (2)
   7 dnl distributions including binary code include the above copyright notice and
   8 dnl this paragraph in its entirety in the documentation or other materials
   9 dnl provided with the distribution, and (3) all advertising materials mentioning
  10 dnl features or use of this software display the following acknowledgement:
  11 dnl ``This product includes software developed by the University of California,
  12 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  13 dnl the University nor the names of its contributors may be used to endorse
  14 dnl or promote products derived from this software without specific prior
  15 dnl written permission.
  16 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  17 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  18 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  19 dnl
  20 dnl LBL autoconf macros
  21 dnl
  22
  23 dnl
  24 dnl Do whatever AC_LBL_C_INIT work is necessary before using AC_PROG_CC.
  25 dnl
  26 dnl It appears that newer versions of autoconf (2.64 and later) will,
  27 dnl if you use AC_TRY_COMPILE in a macro, stick AC_PROG_CC at the
  28 dnl beginning of the macro, even if the macro itself calls AC_PROG_CC.
  29 dnl See the "Prerequisite Macros" and "Expanded Before Required" sections
  30 dnl in the Autoconf documentation.
  31 dnl
  32 dnl This causes a steaming heap of fail in our case, as we were, in
  33 dnl AC_LBL_C_INIT, doing the tests we now do in AC_LBL_C_INIT_BEFORE_CC,
  34 dnl calling AC_PROG_CC, and then doing the tests we now do in
  35 dnl AC_LBL_C_INIT.  Now, we run AC_LBL_C_INIT_BEFORE_CC, AC_PROG_CC,
  36 dnl and AC_LBL_C_INIT at the top level.
  37 dnl
  38 AC_DEFUN(AC_LBL_C_INIT_BEFORE_CC,
  39 [
  40     AC_BEFORE([$0], [AC_LBL_C_INIT])
  41     AC_BEFORE([$0], [AC_PROG_CC])
  42     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  43     AC_BEFORE([$0], [AC_LBL_DEVEL])
  44     AC_ARG_WITH(gcc, [  --without-gcc           don't use gcc])
  45     $1=""
  46     if test "${srcdir}" != "." ; then
  47             $1="-I$srcdir"
  48     fi
  49     if test "${CFLAGS+set}" = set; then
  50             LBL_CFLAGS="$CFLAGS"
  51     fi
  52     if test -z "$CC" ; then
  53             case "$host_os" in
  54
  55             bsdi*)
  56                     AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
  57                     if test $SHLICC2 = yes ; then
  58                             CC=shlicc2
  59                             export CC
  60                     fi
  61                     ;;
  62             esac
  63     fi
  64     if test -z "$CC" -a "$with_gcc" = no ; then
  65             CC=cc
  66             export CC
  67     fi
  68 ])
  69
  70 dnl
  71 dnl Determine which compiler we're using (cc or gcc)
  72 dnl If using gcc, determine the version number
  73 dnl If using cc:
  74 dnl     require that it support ansi prototypes
  75 dnl     use -O (AC_PROG_CC will use -g -O2 on gcc, so we don't need to
  76 dnl     do that ourselves for gcc)
  77 dnl     add -g flags, as appropriate
  78 dnl     explicitly specify /usr/local/include
  79 dnl
  80 dnl NOTE WELL: with newer versions of autoconf, "gcc" means any compiler
  81 dnl that defines __GNUC__, which means clang, for example, counts as "gcc".
  82 dnl
  83 dnl usage:
  84 dnl
  85 dnl     AC_LBL_C_INIT(copt, incls)
  86 dnl
  87 dnl results:
  88 dnl
  89 dnl     $1 (copt set)
  90 dnl     $2 (incls set)
  91 dnl     CC
  92 dnl     LDFLAGS
  93 dnl     LBL_CFLAGS
  94 dnl
  95 AC_DEFUN(AC_LBL_C_INIT,
  96 [
  97     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  98     AC_BEFORE([$0], [AC_LBL_DEVEL])
  99     AC_BEFORE([$0], [AC_LBL_SHLIBS_INIT])
 100     if test "$GCC" = yes ; then
 101             #
 102             # -Werror forces warnings to be errors.
 103             #
 104             ac_lbl_cc_force_warning_errors=-Werror
 105
 106             #
 107             # Use -ffloat-store so that, on 32-bit x86, we don't
 108             # do 80-bit arithmetic with the FPU; that way we should
 109             # get the same results for floating-point calculations
 110             # on x86-32 and x86-64.
 111             #
 112             AC_LBL_CHECK_COMPILER_OPT($1, -ffloat-store)
 113     else
 114             $2="$$2 -I/usr/local/include"
 115             LDFLAGS="$LDFLAGS -L/usr/local/lib"
 116
 117             case "$host_os" in
 118
 119             darwin*)
 120                     #
 121                     # This is assumed either to be GCC or clang, both
 122                     # of which use -Werror to force warnings to be errors.
 123                     #
 124                     ac_lbl_cc_force_warning_errors=-Werror
 125                     ;;
 126
 127             hpux*)
 128                     #
 129                     # HP C, which is what we presume we're using, doesn't
 130                     # exit with a non-zero exit status if we hand it an
 131                     # invalid -W flag, can't be forced to do so even with
 132                     # +We, and doesn't handle GCC-style -W flags, so we
 133                     # don't want to try using GCC-style -W flags.
 134                     #
 135                     ac_lbl_cc_dont_try_gcc_dashW=yes
 136                     ;;
 137
 138             irix*)
 139                     #
 140                     # MIPS C, which is what we presume we're using, doesn't
 141                     # necessarily exit with a non-zero exit status if we
 142                     # hand it an invalid -W flag, can't be forced to do
 143                     # so, and doesn't handle GCC-style -W flags, so we
 144                     # don't want to try using GCC-style -W flags.
 145                     #
 146                     ac_lbl_cc_dont_try_gcc_dashW=yes
 147                     #
 148                     # It also, apparently, defaults to "char" being
 149                     # unsigned, unlike most other C implementations;
 150                     # I suppose we could say "signed char" whenever
 151                     # we want to guarantee a signed "char", but let's
 152                     # just force signed chars.
 153                     #
 154                     # -xansi is normally the default, but the
 155                     # configure script was setting it; perhaps -cckr
 156                     # was the default in the Old Days.  (Then again,
 157                     # that would probably be for backwards compatibility
 158                     # in the days when ANSI C was Shiny and New, i.e.
 159                     # 1989 and the early '90's, so maybe we can just
 160                     # drop support for those compilers.)
 161                     #
 162                     # -g is equivalent to -g2, which turns off
 163                     # optimization; we choose -g3, which generates
 164                     # debugging information but doesn't turn off
 165                     # optimization (even if the optimization would
 166                     # cause inaccuracies in debugging).
 167                     #
 168                     $1="$$1 -xansi -signed -g3"
 169                     ;;
 170
 171             osf*)
 172                     #
 173                     # Presumed to be DEC OSF/1, Digital UNIX, or
 174                     # Tru64 UNIX.
 175                     #
 176                     # The DEC C compiler, which is what we presume we're
 177                     # using, doesn't exit with a non-zero exit status if we
 178                     # hand it an invalid -W flag, can't be forced to do
 179                     # so, and doesn't handle GCC-style -W flags, so we
 180                     # don't want to try using GCC-style -W flags.
 181                     #
 182                     ac_lbl_cc_dont_try_gcc_dashW=yes
 183                     #
 184                     # -g is equivalent to -g2, which turns off
 185                     # optimization; we choose -g3, which generates
 186                     # debugging information but doesn't turn off
 187                     # optimization (even if the optimization would
 188                     # cause inaccuracies in debugging).
 189                     #
 190                     $1="$$1 -g3"
 191                     ;;
 192
 193             solaris*)
 194                     #
 195                     # Assumed to be Sun C, which requires -errwarn to force
 196                     # warnings to be treated as errors.
 197                     #
 198                     ac_lbl_cc_force_warning_errors=-errwarn
 199                     ;;
 200
 201             ultrix*)
 202                     AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
 203                     AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
 204                         AC_TRY_COMPILE(
 205                             [#include <sys/types.h>],
 206                             [struct a { int b; };
 207                             void c(const struct a *)],
 208                             ac_cv_lbl_cc_const_proto=yes,
 209                             ac_cv_lbl_cc_const_proto=no))
 210                     AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
 211                     if test $ac_cv_lbl_cc_const_proto = no ; then
 212                             AC_DEFINE(const,[],
 213                                 [to handle Ultrix compilers that don't support const in prototypes])
 214                     fi
 215                     ;;
 216             esac
 217             $1="$$1 -O"
 218     fi
 219 ])
 220
 221 dnl
 222 dnl Check whether, if you pass an unknown warning option to the
 223 dnl compiler, it fails or just prints a warning message and succeeds.
 224 dnl Set ac_lbl_unknown_warning_option_error to the appropriate flag
 225 dnl to force an error if it would otherwise just print a warning message
 226 dnl and succeed.
 227 dnl
 228 AC_DEFUN(AC_LBL_CHECK_UNKNOWN_WARNING_OPTION_ERROR,
 229     [
 230         AC_MSG_CHECKING([whether the compiler fails when given an unknown warning option])
 231         save_CFLAGS="$CFLAGS"
 232         CFLAGS="$CFLAGS -Wxyzzy-this-will-never-succeed-xyzzy"
 233         AC_TRY_COMPILE(
 234             [],
 235             [return 0],
 236             [
 237                 AC_MSG_RESULT([no])
 238                 #
 239                 # We're assuming this is clang, where
 240                 # -Werror=unknown-warning-option is the appropriate
 241                 # option to force the compiler to fail.
 242                 #
 243                 ac_lbl_unknown_warning_option_error="-Werror=unknown-warning-option"
 244             ],
 245             [
 246                 AC_MSG_RESULT([yes])
 247             ])
 248         CFLAGS="$save_CFLAGS"
 249     ])
 250
 251 dnl
 252 dnl Check whether the compiler option specified as the second argument
 253 dnl is supported by the compiler and, if so, add it to the macro
 254 dnl specified as the first argument
 255 dnl
 256 AC_DEFUN(AC_LBL_CHECK_COMPILER_OPT,
 257     [
 258         AC_MSG_CHECKING([whether the compiler supports the $2 option])
 259         save_CFLAGS="$CFLAGS"
 260         if expr "x$2" : "x-W.*" >/dev/null
 261         then
 262             CFLAGS="$CFLAGS $ac_lbl_unknown_warning_option_error $2"
 263         elif expr "x$2" : "x-f.*" >/dev/null
 264         then
 265             CFLAGS="$CFLAGS -Werror $2"
 266         elif expr "x$2" : "x-m.*" >/dev/null
 267         then
 268             CFLAGS="$CFLAGS -Werror $2"
 269         else
 270             CFLAGS="$CFLAGS $2"
 271         fi
 272         AC_TRY_COMPILE(
 273             [],
 274             [return 0],
 275             [
 276                 AC_MSG_RESULT([yes])
 277                 CFLAGS="$save_CFLAGS"
 278                 $1="$$1 $2"
 279             ],
 280             [
 281                 AC_MSG_RESULT([no])
 282                 CFLAGS="$save_CFLAGS"
 283             ])
 284     ])
 285
 286 dnl
 287 dnl Check whether the compiler supports an option to generate
 288 dnl Makefile-style dependency lines
 289 dnl
 290 dnl GCC uses -M for this.  Non-GCC compilers that support this
 291 dnl use a variety of flags, including but not limited to -M.
 292 dnl
 293 dnl We test whether the flag in question is supported, as older
 294 dnl versions of compilers might not support it.
 295 dnl
 296 dnl We don't try all the possible flags, just in case some flag means
 297 dnl "generate dependencies" on one compiler but means something else
 298 dnl on another compiler.
 299 dnl
 300 dnl Most compilers that support this send the output to the standard
 301 dnl output by default.  IBM's XLC, however, supports -M but sends
 302 dnl the output to {sourcefile-basename}.u, and AIX has no /dev/stdout
 303 dnl to work around that, so we don't bother with XLC.
 304 dnl
 305 AC_DEFUN(AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT,
 306     [
 307         AC_MSG_CHECKING([whether the compiler supports generating dependencies])
 308         if test "$GCC" = yes ; then
 309                 #
 310                 # GCC, or a compiler deemed to be GCC by AC_PROG_CC (even
 311                 # though it's not); we assume that, in this case, the flag
 312                 # would be -M.
 313                 #
 314                 ac_lbl_dependency_flag="-M"
 315         else
 316                 #
 317                 # Not GCC or a compiler deemed to be GCC; what platform is
 318                 # this?  (We're assuming that if the compiler isn't GCC
 319                 # it's the compiler from the vendor of the OS; that won't
 320                 # necessarily be true for x86 platforms, where it might be
 321                 # the Intel C compiler.)
 322                 #
 323                 case "$host_os" in
 324
 325                 irix*|osf*|darwin*)
 326                         #
 327                         # MIPS C for IRIX, DEC C, and clang all use -M.
 328                         #
 329                         ac_lbl_dependency_flag="-M"
 330                         ;;
 331
 332                 solaris*)
 333                         #
 334                         # Sun C uses -xM.
 335                         #
 336                         ac_lbl_dependency_flag="-xM"
 337                         ;;
 338
 339                 hpux*)
 340                         #
 341                         # HP's older C compilers don't support this.
 342                         # HP's newer C compilers support this with
 343                         # either +M or +Make; the older compilers
 344                         # interpret +M as something completely
 345                         # different, so we use +Make so we don't
 346                         # think it works with the older compilers.
 347                         #
 348                         ac_lbl_dependency_flag="+Make"
 349                         ;;
 350
 351                 *)
 352                         #
 353                         # Not one of the above; assume no support for
 354                         # generating dependencies.
 355                         #
 356                         ac_lbl_dependency_flag=""
 357                         ;;
 358                 esac
 359         fi
 360
 361         #
 362         # Is ac_lbl_dependency_flag defined and, if so, does the compiler
 363         # complain about it?
 364         #
 365         # Note: clang doesn't seem to exit with an error status when handed
 366         # an unknown non-warning error, even if you pass it
 367         # -Werror=unknown-warning-option.  However, it always supports
 368         # -M, so the fact that this test always succeeds with clang
 369         # isn't an issue.
 370         #
 371         if test ! -z "$ac_lbl_dependency_flag"; then
 372                 AC_LANG_CONFTEST(
 373                     [AC_LANG_SOURCE([[int main(void) { return 0; }]])])
 374                 if AC_RUN_LOG([eval "$CC $ac_lbl_dependency_flag conftest.c >/dev/null 2>&1"]); then
 375                         AC_MSG_RESULT([yes, with $ac_lbl_dependency_flag])
 376                         DEPENDENCY_CFLAG="$ac_lbl_dependency_flag"
 377                         MKDEP='${srcdir}/mkdep'
 378                 else
 379                         AC_MSG_RESULT([no])
 380                         #
 381                         # We can't run mkdep, so have "make depend" do
 382                         # nothing.
 383                         #
 384                         MKDEP=:
 385                 fi
 386                 rm -rf conftest*
 387         else
 388                 AC_MSG_RESULT([no])
 389                 #
 390                 # We can't run mkdep, so have "make depend" do
 391                 # nothing.
 392                 #
 393                 MKDEP=:
 394         fi
 395         AC_SUBST(DEPENDENCY_CFLAG)
 396         AC_SUBST(MKDEP)
 397     ])
 398
 399 #
 400 # Try compiling a sample of the type of code that appears in
 401 # gencode.c with "inline", "__inline__", and "__inline".
 402 #
 403 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
 404 # as it just tests whether a function returning "int" can be inlined;
 405 # at least some versions of HP's C compiler can inline that, but can't
 406 # inline a function that returns a struct pointer.
 407 #
 408 # Make sure we use the V_CCOPT flags, because some of those might
 409 # disable inlining.
 410 #
 411 AC_DEFUN(AC_LBL_C_INLINE,
 412     [AC_MSG_CHECKING(for inline)
 413     save_CFLAGS="$CFLAGS"
 414     CFLAGS="$V_CCOPT"
 415     AC_CACHE_VAL(ac_cv_lbl_inline, [
 416         ac_cv_lbl_inline=""
 417         ac_lbl_cc_inline=no
 418         for ac_lbl_inline in inline __inline__ __inline
 419         do
 420             AC_TRY_COMPILE(
 421                 [#define inline $ac_lbl_inline
 422                 static inline struct iltest *foo(void);
 423                 struct iltest {
 424                     int iltest1;
 425                     int iltest2;
 426                 };
 427
 428                 static inline struct iltest *
 429                 foo()
 430                 {
 431                     static struct iltest xxx;
 432
 433                     return &xxx;
 434                 }],,ac_lbl_cc_inline=yes,)
 435             if test "$ac_lbl_cc_inline" = yes ; then
 436                 break;
 437             fi
 438         done
 439         if test "$ac_lbl_cc_inline" = yes ; then
 440             ac_cv_lbl_inline=$ac_lbl_inline
 441         fi])
 442     CFLAGS="$save_CFLAGS"
 443     if test ! -z "$ac_cv_lbl_inline" ; then
 444         AC_MSG_RESULT($ac_cv_lbl_inline)
 445     else
 446         AC_MSG_RESULT(no)
 447     fi
 448     AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
 449
 450 dnl
 451 dnl Use pfopen.c if available and pfopen() not in standard libraries
 452 dnl Require libpcap
 453 dnl Look for libpcap in directories under ..; those are local versions.
 454 dnl Look for an installed libpcap if there is no local version or if
 455 dnl the user said not to look for a local version.
 456 dnl
 457 dnl usage:
 458 dnl
 459 dnl     AC_LBL_LIBPCAP(pcapdep, incls)
 460 dnl
 461 dnl results:
 462 dnl
 463 dnl     $1 (pcapdep set)
 464 dnl     $2 (incls appended)
 465 dnl     LIBS
 466 dnl     LBL_LIBS
 467 dnl
 468 AC_DEFUN(AC_LBL_LIBPCAP,
 469     [AC_REQUIRE([AC_LBL_LIBRARY_NET])
 470     dnl
 471     dnl save a copy before locating libpcap.a
 472     dnl
 473     LBL_LIBS="$LIBS"
 474     pfopen=/usr/examples/packetfilter/pfopen.c
 475     if test -f $pfopen ; then
 476         AC_CHECK_FUNCS(pfopen)
 477         if test $ac_cv_func_pfopen = "no" ; then
 478             AC_MSG_RESULT(Using $pfopen)
 479             LIBS="$LIBS $pfopen"
 480         fi
 481     fi
 482     libpcap=FAIL
 483     AC_ARG_WITH([system-libpcap],
 484         [AS_HELP_STRING([--with-system-libpcap], [don't use local pcap library])],
 485         [
 486             #
 487             # Don't look for a local libpcap.
 488             #
 489             using_local_libpcap=no
 490         ],
 491         [
 492             #
 493             # Look for a local pcap library.
 494             #
 495             AC_MSG_CHECKING(for local pcap library)
 496             lastdir=FAIL
 497             places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 498                 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT)?$'`
 499             places2=`ls .. | sed -e 's,/$,,' -e "s,^,../," | \
 500                 egrep '/libpcap-[[0-9]]+\.[[0-9]]+(\.[[0-9]]*)?([[ab]][[0-9]]*|-PRE-GIT)?$'`
 501             for dir in $places $srcdir/../libpcap ../libpcap $srcdir/libpcap $places2 ; do
 502                 basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//' | \
 503                     sed -e 's/-PRE-GIT$//' `
 504                 if test $lastdir = $basedir ; then
 505                     dnl skip alphas when an actual release is present
 506                     continue;
 507                 fi
 508                 lastdir=$dir
 509                 if test -r $dir/libpcap.a ; then
 510                     libpcap=$dir/libpcap.a
 511                     local_pcap_dir=$dir
 512                     dnl continue and select the last one that exists
 513                 fi
 514             done
 515             if test $libpcap = FAIL ; then
 516                 #
 517                 # We didn't find a local libpcap.
 518                 #
 519                 AC_MSG_RESULT(not found)
 520                 using_local_libpcap=no;
 521             else
 522                 #
 523                 # We found a local libpcap.
 524                 #
 525                 AC_MSG_RESULT($libpcap)
 526                 using_local_libpcap=yes
 527             fi
 528         ])
 529
 530     if test $using_local_libpcap = no ; then
 531         #
 532         # We didn't find a local libpcap.
 533         # Look for an installed pkg-config.
 534         #
 535         AC_PATH_TOOL(PKG_CONFIG, pkg-config)
 536         if test -n "$PKG_CONFIG" ; then
 537             #
 538             # We have it.  Are there .pc files for libpcap?
 539             #
 540             AC_MSG_CHECKING(whether there are .pc files for libpcap)
 541             if "$PKG_CONFIG" libpcap --exists ; then
 542                 #
 543                 # Yes, so we can use pkg-config to get configuration
 544                 # information for libpcap.
 545                 #
 546                 AC_MSG_RESULT(yes)
 547                 pkg_config_usable=yes
 548             else
 549                 #
 550                 # No, so we can't use pkg-config to get configuration
 551                 # information for libpcap.
 552                 #
 553                 AC_MSG_RESULT(no)
 554                 pkg_config_usable=no
 555             fi
 556         else
 557             #
 558             # We don't have it, so we obviously can't use it.
 559             #
 560             pkg_config_usable=no
 561         fi
 562         if test "$pkg_config_usable" = "yes" ; then
 563             #
 564             # Found both - use pkg-config to get the include flags for
 565             # libpcap and the flags to link with libpcap.
 566             #
 567             # Please read section 11.6 "Shell Substitutions"
 568             # in the autoconf manual before doing anything
 569             # to this that involves quoting.  Especially note
 570             # the statement "There is just no portable way to use
 571             # double-quoted strings inside double-quoted back-quoted
 572             # expressions (pfew!)."
 573             #
 574             cflags=`"$PKG_CONFIG" libpcap --cflags`
 575             $2="$cflags $$2"
 576             libpcap=`"$PKG_CONFIG" libpcap --libs`
 577         else
 578             #
 579             # No pkg-config
 580             # Look for an installed pcap-config.
 581             #
 582             AC_PATH_TOOL(PCAP_CONFIG, pcap-config)
 583             if test -n "$PCAP_CONFIG" ; then
 584                 #
 585                 # Found - use it to get the include flags for
 586                 # libpcap and the flags to link with libpcap.
 587                 #
 588                 # Please read section 11.6 "Shell Substitutions"
 589                 # in the autoconf manual before doing anything
 590                 # to this that involves quoting.  Especially note
 591                 # the statement "There is just no portable way to use
 592                 # double-quoted strings inside double-quoted back-quoted
 593                 # expressions (pfew!)."
 594                 #
 595                 cflags=`"$PCAP_CONFIG" --cflags`
 596                 $2="$cflags $$2"
 597                 libpcap=`"$PCAP_CONFIG" --libs`
 598             else
 599                 #
 600                 # Not found; look for an installed pcap.
 601                 #
 602                 AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
 603                 if test $libpcap = FAIL ; then
 604                     AC_MSG_ERROR(see the INSTALL doc for more info)
 605                 fi
 606                 dnl
 607                 dnl Some versions of Red Hat Linux put "pcap.h" in
 608                 dnl "/usr/include/pcap"; had the LBL folks done so,
 609                 dnl that would have been a good idea, but for
 610                 dnl the Red Hat folks to do so just breaks source
 611                 dnl compatibility with other systems.
 612                 dnl
 613                 dnl We work around this by assuming that, as we didn't
 614                 dnl find a local libpcap, libpcap is in /usr/lib or
 615                 dnl /usr/local/lib and that the corresponding header
 616                 dnl file is under one of those directories; if we don't
 617                 dnl find it in either of those directories, we check to
 618                 dnl see if it's in a "pcap" subdirectory of them and,
 619                 dnl if so, add that subdirectory to the "-I" list.
 620                 dnl
 621                 dnl (We now also put pcap.h in /usr/include/pcap, but we
 622                 dnl leave behind a /usr/include/pcap.h that includes it,
 623                 dnl so you can still just include <pcap.h>.)
 624                 dnl
 625                 AC_MSG_CHECKING(for extraneous pcap header directories)
 626                 if test \( ! -r /usr/local/include/pcap.h \) -a \
 627                         \( ! -r /usr/include/pcap.h \); then
 628                     if test -r /usr/local/include/pcap/pcap.h; then
 629                         d="/usr/local/include/pcap"
 630                     elif test -r /usr/include/pcap/pcap.h; then
 631                         d="/usr/include/pcap"
 632                     fi
 633                 fi
 634                 if test -z "$d" ; then
 635                     AC_MSG_RESULT(not found)
 636                 else
 637                     $2="-I$d $$2"
 638                     AC_MSG_RESULT(found -- -I$d added)
 639                 fi
 640             fi
 641         fi
 642     else
 643         #
 644         # We found a local libpcap.  Add it to the dependencies for
 645         # tcpdump.
 646         #
 647         $1=$libpcap
 648
 649         #
 650         # Look for its pcap-config script.
 651         #
 652         AC_PATH_PROG(PCAP_CONFIG, pcap-config,, $local_pcap_dir)
 653
 654         if test -n "$PCAP_CONFIG"; then
 655             #
 656             # We don't want its --cflags or --libs output, because
 657             # those presume it's installed.  For the C compiler flags,
 658             # we add the source directory for the local libpcap, so
 659             # we pick up its header files.
 660             #
 661             # We do, however, want its additional libraries, as required
 662             # when linking statically, because it makes calls to
 663             # routines in those libraries, so we'll need to link with
 664             # them, because we'll be linking statically with it.
 665             #
 666             $2="-I$local_pcap_dir $$2"
 667             additional_libs=`"$PCAP_CONFIG" --static --additional-libs`
 668             libpcap="$libpcap $additional_libs"
 669         else
 670             #
 671             # It doesn't have a pcap-config script.
 672             # Make sure it has a pcap.h file.
 673             #
 674             places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 675                 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 676             places2=`ls .. | sed -e 's,/$,,' -e "s,^,../," | \
 677                 egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 678             pcapH=FAIL
 679             if test -r $local_pcap_dir/pcap.h; then
 680                 pcapH=$local_pcap_dir
 681             else
 682                 for dir in $places $srcdir/../libpcap ../libpcap $srcdir/libpcap $places2 ; do
 683                     if test -r $dir/pcap.h ; then
 684                         pcapH=$dir
 685                     fi
 686                 done
 687             fi
 688
 689             if test $pcapH = FAIL ; then
 690                 AC_MSG_ERROR(cannot find pcap.h: see INSTALL)
 691             fi
 692
 693             #
 694             # Force the compiler to look for header files in the
 695             # directory containing pcap.h.
 696             #
 697             $2="-I$pcapH $$2"
 698         fi
 699     fi
 700
 701     if test -z "$PKG_CONFIG" -a -z "$PCAP_CONFIG"; then
 702         #
 703         # We don't have pkg-config or pcap-config; find out any additional
 704         # link flags we need.  (If we have pkg-config or pcap-config, we
 705         # assume it tells us what we need.)
 706         #
 707         case "$host_os" in
 708
 709         aix*)
 710             #
 711             # If libpcap is DLPI-based, we have to use /lib/pse.exp if
 712             # present, as we use the STREAMS routines.
 713             #
 714             # (XXX - true only if we're linking with a static libpcap?)
 715             #
 716             pseexe="/lib/pse.exp"
 717             AC_MSG_CHECKING(for $pseexe)
 718             if test -f $pseexe ; then
 719                 AC_MSG_RESULT(yes)
 720                 LIBS="$LIBS -I:$pseexe"
 721             fi
 722
 723             #
 724             # If libpcap is BPF-based, we need "-lodm" and "-lcfg", as
 725             # we use them to load the BPF module.
 726             #
 727             # (XXX - true only if we're linking with a static libpcap?)
 728             #
 729             LIBS="$LIBS -lodm -lcfg"
 730             ;;
 731
 732         solaris*)
 733             # libdlpi is needed for Solaris 11 and later.
 734             AC_CHECK_LIB(dlpi, dlpi_walk, LIBS="$LIBS -ldlpi" LDFLAGS="-L/lib $LDFLAGS", ,-L/lib)
 735             ;;
 736         esac
 737     fi
 738
 739     LIBS="$libpcap $LIBS"
 740
 741     dnl
 742     dnl Check for "pcap_loop()", to make sure we found a working
 743     dnl libpcap and have all the right other libraries with which
 744     dnl to link.  (Otherwise, the checks below will fail, not
 745     dnl because the routines are missing from the library, but
 746     dnl because we aren't linking properly with libpcap, and
 747     dnl that will cause confusing errors at build time.)
 748     dnl
 749     AC_CHECK_FUNC(pcap_loop,,
 750     [
 751         AC_MSG_ERROR(
 752 [This is a bug, please follow the guidelines in CONTRIBUTING and include the
 753 config.log file in your report.  If you have downloaded libpcap from
 754 tcpdump.org, and built it yourself, please also include the config.log
 755 file from the libpcap source directory, the Makefile from the libpcap
 756 source directory, and the output of the make process for libpcap, as
 757 this could be a problem with the libpcap that was built, and we will
 758 not be able to determine why this is happening, and thus will not be
 759 able to fix it, without that information, as we have not been able to
 760 reproduce this problem ourselves.])
 761     ])
 762 ])
 763
 764 dnl
 765 dnl If using gcc, make sure we have ANSI ioctl definitions
 766 dnl
 767 dnl usage:
 768 dnl
 769 dnl     AC_LBL_FIXINCLUDES
 770 dnl
 771 AC_DEFUN(AC_LBL_FIXINCLUDES,
 772     [if test "$GCC" = yes ; then
 773             AC_MSG_CHECKING(for ANSI ioctl definitions)
 774             AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
 775                 AC_TRY_COMPILE(
 776                     [/*
 777                      * This generates a "duplicate case value" when fixincludes
 778                      * has not be run.
 779                      */
 780 #               include <sys/types.h>
 781 #               include <sys/time.h>
 782 #               include <sys/ioctl.h>
 783 #               ifdef HAVE_SYS_IOCCOM_H
 784 #               include <sys/ioccom.h>
 785 #               endif],
 786                     [switch (0) {
 787                     case _IO('A', 1):;
 788                     case _IO('B', 1):;
 789                     }],
 790                     ac_cv_lbl_gcc_fixincludes=yes,
 791                     ac_cv_lbl_gcc_fixincludes=no))
 792             AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
 793             if test $ac_cv_lbl_gcc_fixincludes = no ; then
 794                     # Don't cache failure
 795                     unset ac_cv_lbl_gcc_fixincludes
 796                     AC_MSG_ERROR(see the INSTALL for more info)
 797             fi
 798     fi])
 799
 800 dnl
 801 dnl Checks to see if union wait is used with WEXITSTATUS()
 802 dnl
 803 dnl usage:
 804 dnl
 805 dnl     AC_LBL_UNION_WAIT
 806 dnl
 807 dnl results:
 808 dnl
 809 dnl     DECLWAITSTATUS (defined)
 810 dnl
 811 AC_DEFUN(AC_LBL_UNION_WAIT,
 812     [AC_MSG_CHECKING(if union wait is used)
 813     AC_CACHE_VAL(ac_cv_lbl_union_wait,
 814         AC_TRY_COMPILE([
 815 #       include <sys/types.h>
 816 #       include <sys/wait.h>],
 817             [int status;
 818             u_int i = WEXITSTATUS(status);
 819             u_int j = waitpid(0, &status, 0);],
 820             ac_cv_lbl_union_wait=no,
 821             ac_cv_lbl_union_wait=yes))
 822     AC_MSG_RESULT($ac_cv_lbl_union_wait)
 823     if test $ac_cv_lbl_union_wait = yes ; then
 824             AC_DEFINE(DECLWAITSTATUS,union wait,[type for wait])
 825     else
 826             AC_DEFINE(DECLWAITSTATUS,int,[type for wait])
 827     fi])
 828
 829 dnl
 830 dnl Checks to see if -R is used
 831 dnl
 832 dnl usage:
 833 dnl
 834 dnl     AC_LBL_HAVE_RUN_PATH
 835 dnl
 836 dnl results:
 837 dnl
 838 dnl     ac_cv_lbl_have_run_path (yes or no)
 839 dnl
 840 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
 841     [AC_MSG_CHECKING(for ${CC-cc} -R)
 842     AC_CACHE_VAL(ac_cv_lbl_have_run_path,
 843         [echo 'main(){}' > conftest.c
 844         ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
 845         if test ! -s conftest.out ; then
 846                 ac_cv_lbl_have_run_path=yes
 847         else
 848                 ac_cv_lbl_have_run_path=no
 849         fi
 850         rm -f -r conftest*])
 851     AC_MSG_RESULT($ac_cv_lbl_have_run_path)
 852     ])
 853
 854 dnl
 855 dnl Check whether a given format can be used to print 64-bit integers
 856 dnl
 857 AC_DEFUN(AC_LBL_CHECK_64BIT_FORMAT,
 858   [
 859     AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
 860     AC_RUN_IFELSE(
 861       [
 862         AC_LANG_SOURCE(
 863           [[
 864 #           ifdef HAVE_INTTYPES_H
 865             #include <inttypes.h>
 866 #           endif
 867             #include <stdio.h>
 868             #include <sys/types.h>
 869
 870             main()
 871             {
 872               uint64_t t = 1;
 873               char strbuf[16+1];
 874               sprintf(strbuf, "%016$1x", t << 32);
 875               if (strcmp(strbuf, "0000000100000000") == 0)
 876                 exit(0);
 877               else
 878                 exit(1);
 879             }
 880           ]])
 881       ],
 882       [
 883         AC_DEFINE(PRId64, "$1d", [define if the platform doesn't define PRId64])
 884         AC_DEFINE(PRIo64, "$1o", [define if the platform doesn't define PRIo64])
 885         AC_DEFINE(PRIx64, "$1x", [define if the platform doesn't define PRIu64])
 886         AC_DEFINE(PRIu64, "$1u", [define if the platform doesn't define PRIx64])
 887         AC_MSG_RESULT(yes)
 888       ],
 889       [
 890         AC_MSG_RESULT(no)
 891         $2
 892       ])
 893   ])
 894
 895 dnl
 896 dnl If the file .devel exists:
 897 dnl     Add some warning flags if the compiler supports them
 898 dnl     If an os prototype include exists, symlink os-proto.h to it
 899 dnl
 900 dnl usage:
 901 dnl
 902 dnl     AC_LBL_DEVEL(copt)
 903 dnl
 904 dnl results:
 905 dnl
 906 dnl     $1 (copt appended)
 907 dnl     HAVE_OS_PROTO_H (defined)
 908 dnl     os-proto.h (symlinked)
 909 dnl
 910 AC_DEFUN(AC_LBL_DEVEL,
 911     [rm -f os-proto.h
 912     if test "${LBL_CFLAGS+set}" = set; then
 913             $1="$$1 ${LBL_CFLAGS}"
 914     fi
 915     if test -f .devel ; then
 916             #
 917             # Skip all the warning option stuff on some compilers.
 918             #
 919             if test "$ac_lbl_cc_dont_try_gcc_dashW" != yes; then
 920                     AC_LBL_CHECK_UNKNOWN_WARNING_OPTION_ERROR()
 921                     AC_LBL_CHECK_COMPILER_OPT($1, -W)
 922                     AC_LBL_CHECK_COMPILER_OPT($1, -Wall)
 923                     AC_LBL_CHECK_COMPILER_OPT($1, -Wassign-enum)
 924                     AC_LBL_CHECK_COMPILER_OPT($1, -Wcast-qual)
 925                     AC_LBL_CHECK_COMPILER_OPT($1, -Wmissing-prototypes)
 926                     AC_LBL_CHECK_COMPILER_OPT($1, -Wold-style-definition)
 927                     AC_LBL_CHECK_COMPILER_OPT($1, -Wpedantic)
 928                     AC_LBL_CHECK_COMPILER_OPT($1, -Wpointer-arith)
 929                     AC_LBL_CHECK_COMPILER_OPT($1, -Wshadow)
 930                     AC_LBL_CHECK_COMPILER_OPT($1, -Wsign-compare)
 931                     AC_LBL_CHECK_COMPILER_OPT($1, -Wstrict-prototypes)
 932                     AC_LBL_CHECK_COMPILER_OPT($1, -Wunreachable-code-return)
 933                     AC_LBL_CHECK_COMPILER_OPT($1, -Wused-but-marked-unused)
 934                     AC_LBL_CHECK_COMPILER_OPT($1, -Wwrite-strings)
 935             fi
 936             AC_LBL_CHECK_DEPENDENCY_GENERATION_OPT()
 937             #
 938             # We used to set -n32 for IRIX 6 when not using GCC (presumed
 939             # to mean that we're using MIPS C or MIPSpro C); it specified
 940             # the "new" faster 32-bit ABI, introduced in IRIX 6.2.  I'm
 941             # not sure why that would be something to do *only* with a
 942             # .devel file; why should the ABI for which we produce code
 943             # depend on .devel?
 944             #
 945             os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
 946             name="lbl/os-$os.h"
 947             if test -f $name ; then
 948                     ln -s $name os-proto.h
 949                     AC_DEFINE(HAVE_OS_PROTO_H, 1,
 950                         [if there's an os_proto.h for this platform, to use additional prototypes])
 951             else
 952                     AC_MSG_WARN(can't find $name)
 953             fi
 954     fi])
 955
 956 dnl
 957 dnl Improved version of AC_CHECK_LIB
 958 dnl
 959 dnl Thanks to John Hawkinson (jhawk@mit.edu)
 960 dnl
 961 dnl usage:
 962 dnl
 963 dnl     AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
 964 dnl         ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 965 dnl
 966 dnl results:
 967 dnl
 968 dnl     LIBS
 969 dnl
 970 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
 971 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
 972 dnl We keep it around for reference purposes in case it's ever
 973 dnl useful in the future.
 974 dnl
 975
 976 define(AC_LBL_CHECK_LIB,
 977 [AC_MSG_CHECKING([for $2 in -l$1])
 978 dnl Use a cache variable name containing the library, function
 979 dnl name, and extra libraries to link with, because the test really is
 980 dnl for library $1 defining function $2, when linked with potinal
 981 dnl library $5, not just for library $1.  Separate tests with the same
 982 dnl $1 and different $2's or $5's may have different results.
 983 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
 984 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
 985 [ac_save_LIBS="$LIBS"
 986 LIBS="-l$1 $5 $LIBS"
 987 AC_TRY_LINK(dnl
 988 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 989 [/* Override any gcc2 internal prototype to avoid an error.  */
 990 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 991 extern "C"
 992 #endif
 993 ])dnl
 994 [/* We use char because int might match the return type of a gcc2
 995     builtin and then its argument prototype would still apply.  */
 996 char $2();
 997 ]),
 998             [$2()],
 999             eval "ac_cv_lbl_lib_$ac_lib_var=yes",
1000             eval "ac_cv_lbl_lib_$ac_lib_var=no")
1001 LIBS="$ac_save_LIBS"
1002 ])dnl
1003 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
1004   AC_MSG_RESULT(yes)
1005   ifelse([$3], ,
1006 [changequote(, )dnl
1007   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
1008     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
1009 changequote([, ])dnl
1010   AC_DEFINE_UNQUOTED($ac_tr_lib)
1011   LIBS="-l$1 $LIBS"
1012 ], [$3])
1013 else
1014   AC_MSG_RESULT(no)
1015 ifelse([$4], , , [$4
1016 ])dnl
1017 fi
1018 ])
1019
1020 dnl
1021 dnl AC_LBL_LIBRARY_NET
1022 dnl
1023 dnl This test is for network applications that need socket() and
1024 dnl gethostbyname() -ish functions.  Under Solaris, those applications
1025 dnl need to link with "-lsocket -lnsl".  Under IRIX, they need to link
1026 dnl with "-lnsl" but should *not* link with "-lsocket" because
1027 dnl libsocket.a breaks a number of things (for instance:
1028 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
1029 dnl versions of IRIX).
1030 dnl
1031 dnl Unfortunately, many application developers are not aware of this,
1032 dnl and mistakenly write tests that cause -lsocket to be used under
1033 dnl IRIX.  It is also easy to write tests that cause -lnsl to be used
1034 dnl under operating systems where neither are necessary (or useful),
1035 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
1036 dnl
1037 dnl This test exists so that every application developer does not test
1038 dnl this in a different, and subtly broken fashion.
1039
1040 dnl It has been argued that this test should be broken up into two
1041 dnl separate tests, one for the resolver libraries, and one for the
1042 dnl libraries necessary for using Sockets API. Unfortunately, the two
1043 dnl are carefully intertwined and allowing the autoconf user to use
1044 dnl them independently potentially results in unfortunate ordering
1045 dnl dependencies -- as such, such component macros would have to
1046 dnl carefully use indirection and be aware if the other components were
1047 dnl executed. Since other autoconf macros do not go to this trouble,
1048 dnl and almost no applications use sockets without the resolver, this
1049 dnl complexity has not been implemented.
1050 dnl
1051 dnl The check for libresolv is in case you are attempting to link
1052 dnl statically and happen to have a libresolv.a lying around (and no
1053 dnl libnsl.a).
1054 dnl
1055 AC_DEFUN(AC_LBL_LIBRARY_NET, [
1056     # Most operating systems have gethostbyname() in the default searched
1057     # libraries (i.e. libc):
1058     # Some OSes (eg. Solaris) place it in libnsl
1059     # Some strange OSes (SINIX) have it in libsocket:
1060     AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
1061     # Unfortunately libsocket sometimes depends on libnsl and
1062     # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
1063     if test "$ac_cv_search_gethostbyname" = "no"
1064     then
1065         AC_CHECK_LIB(socket, gethostbyname,
1066                      LIBS="-lsocket -lnsl $LIBS", , -lnsl)
1067     fi
1068     AC_SEARCH_LIBS(socket, socket, ,
1069         AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
1070     # DLPI needs putmsg under HPUX so test for -lstr while we're at it
1071     AC_SEARCH_LIBS(putmsg, str)
1072     ])
1073
1074 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
1075 dnl
1076 dnl Redistribution and use in source and binary forms, with or without
1077 dnl modification, are permitted provided that the following conditions
1078 dnl are met:
1079 dnl 1. Redistributions of source code must retain the above copyright
1080 dnl    notice, this list of conditions and the following disclaimer.
1081 dnl 2. Redistributions in binary form must reproduce the above copyright
1082 dnl    notice, this list of conditions and the following disclaimer in the
1083 dnl    documentation and/or other materials provided with the distribution.
1084 dnl 3. Neither the name of the project nor the names of its contributors
1085 dnl    may be used to endorse or promote products derived from this software
1086 dnl    without specific prior written permission.
1087 dnl
1088 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
1089 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
1090 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
1091 dnl ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
1092 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
1093 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
1094 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
1095 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
1096 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
1097 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
1098 dnl SUCH DAMAGE.
1099
1100 AC_DEFUN(AC_LBL_SSLEAY,
1101     [
1102         #
1103         # Find the last component of $libdir; it's not necessarily
1104         # "lib" - it might be "lib64" on, for example, x86-64
1105         # Linux systems.
1106         #
1107         # We assume the directory in which we're looking for
1108         # libcrypto has a subdirectory with that as its name.
1109         #
1110         tmplib=`echo "$libdir" | sed 's,.*/,,'`
1111
1112         #
1113         # XXX - is there a better way to check if a given library is
1114         # in a given directory than checking each of the possible
1115         # shared library suffixes?
1116         #
1117         # Are there any other suffixes we need to look for?  Do we
1118         # have to worry about ".so.{version}"?
1119         #
1120         # Or should we just look for "libcrypto.*"?
1121         #
1122         if test -d "$1/$tmplib" -a \( -f "$1/$tmplib/libcrypto.a" -o \
1123                                     -f "$1/$tmplib/libcrypto.so" -o \
1124                                     -f "$1/$tmplib/libcrypto.sl" -o \
1125                                     -f "$1/$tmplib/libcrypto.dylib" \); then
1126                 ac_cv_ssleay_path="$1"
1127         fi
1128
1129         #
1130         # Make sure we have the headers as well.
1131         #
1132         if test -d "$1/include/openssl" -a -f "$1/include/openssl/des.h"; then
1133                 incdir="-I$1/include"
1134         fi
1135 ])