The Tcpdump Group git mirrors - tcpdump/blob - aclocal.m4

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/aclocal.m4,v 1.97 2003-05-02 08:41:01 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1995, 1996, 1997, 1998
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Redistribution and use in source and binary forms, with or without
   7 dnl modification, are permitted provided that: (1) source code distributions
   8 dnl retain the above copyright notice and this paragraph in its entirety, (2)
   9 dnl distributions including binary code include the above copyright notice and
  10 dnl this paragraph in its entirety in the documentation or other materials
  11 dnl provided with the distribution, and (3) all advertising materials mentioning
  12 dnl features or use of this software display the following acknowledgement:
  13 dnl ``This product includes software developed by the University of California,
  14 dnl Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15 dnl the University nor the names of its contributors may be used to endorse
  16 dnl or promote products derived from this software without specific prior
  17 dnl written permission.
  18 dnl THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19 dnl WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20 dnl MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21 dnl
  22 dnl LBL autoconf macros
  23 dnl
  24
  25 dnl
  26 dnl Determine which compiler we're using (cc or gcc)
  27 dnl If using gcc, determine the version number
  28 dnl If using cc, require that it support ansi prototypes
  29 dnl If using gcc, use -O2 (otherwise use -O)
  30 dnl If using cc, explicitly specify /usr/local/include
  31 dnl
  32 dnl usage:
  33 dnl
  34 dnl     AC_LBL_C_INIT(copt, incls)
  35 dnl
  36 dnl results:
  37 dnl
  38 dnl     $1 (copt set)
  39 dnl     $2 (incls set)
  40 dnl     CC
  41 dnl     LDFLAGS
  42 dnl     ac_cv_lbl_gcc_vers
  43 dnl     LBL_CFLAGS
  44 dnl
  45 AC_DEFUN(AC_LBL_C_INIT,
  46     [AC_PREREQ(2.12)
  47     AC_BEFORE([$0], [AC_PROG_CC])
  48     AC_BEFORE([$0], [AC_LBL_FIXINCLUDES])
  49     AC_BEFORE([$0], [AC_LBL_DEVEL])
  50     AC_ARG_WITH(gcc, [  --without-gcc           don't use gcc])
  51     $1="-O"
  52     $2=""
  53     if test "${srcdir}" != "." ; then
  54             $2="-I\$(srcdir)"
  55     fi
  56     if test "${CFLAGS+set}" = set; then
  57             LBL_CFLAGS="$CFLAGS"
  58     fi
  59     if test -z "$CC" ; then
  60             case "$host_os" in
  61
  62             bsdi*)
  63                     AC_CHECK_PROG(SHLICC2, shlicc2, yes, no)
  64                     if test $SHLICC2 = yes ; then
  65                             CC=shlicc2
  66                             export CC
  67                     fi
  68                     ;;
  69             esac
  70     fi
  71     if test -z "$CC" -a "$with_gcc" = no ; then
  72             CC=cc
  73             export CC
  74     fi
  75     AC_PROG_CC
  76     if test "$GCC" = yes ; then
  77             if test "$SHLICC2" = yes ; then
  78                     ac_cv_lbl_gcc_vers=2
  79                     $1="-O2"
  80             else
  81                     AC_MSG_CHECKING(gcc version)
  82                     AC_CACHE_VAL(ac_cv_lbl_gcc_vers,
  83                         ac_cv_lbl_gcc_vers=`$CC -v 2>&1 | \
  84                             sed -e '/^gcc version /!d' \
  85                                 -e 's/^gcc version //' \
  86                                 -e 's/ .*//' -e 's/^[[[^0-9]]]*//' \
  87                                 -e 's/\..*//'`)
  88                     AC_MSG_RESULT($ac_cv_lbl_gcc_vers)
  89                     if test $ac_cv_lbl_gcc_vers -gt 1 ; then
  90                             $1="-O2"
  91                     fi
  92             fi
  93     else
  94             AC_MSG_CHECKING(that $CC handles ansi prototypes)
  95             AC_CACHE_VAL(ac_cv_lbl_cc_ansi_prototypes,
  96                 AC_TRY_COMPILE(
  97                     [#include <sys/types.h>],
  98                     [int frob(int, char *)],
  99                     ac_cv_lbl_cc_ansi_prototypes=yes,
 100                     ac_cv_lbl_cc_ansi_prototypes=no))
 101             AC_MSG_RESULT($ac_cv_lbl_cc_ansi_prototypes)
 102             if test $ac_cv_lbl_cc_ansi_prototypes = no ; then
 103                     case "$host_os" in
 104
 105                     hpux*)
 106                             AC_MSG_CHECKING(for HP-UX ansi compiler ($CC -Aa -D_HPUX_SOURCE))
 107                             savedcflags="$CFLAGS"
 108                             CFLAGS="-Aa -D_HPUX_SOURCE $CFLAGS"
 109                             AC_CACHE_VAL(ac_cv_lbl_cc_hpux_cc_aa,
 110                                 AC_TRY_COMPILE(
 111                                     [#include <sys/types.h>],
 112                                     [int frob(int, char *)],
 113                                     ac_cv_lbl_cc_hpux_cc_aa=yes,
 114                                     ac_cv_lbl_cc_hpux_cc_aa=no))
 115                             AC_MSG_RESULT($ac_cv_lbl_cc_hpux_cc_aa)
 116                             if test $ac_cv_lbl_cc_hpux_cc_aa = no ; then
 117                                     AC_MSG_ERROR(see the INSTALL doc for more info)
 118                             fi
 119                             CFLAGS="$savedcflags"
 120                             V_CCOPT="-Aa $V_CCOPT"
 121                             AC_DEFINE(_HPUX_SOURCE)
 122                             ;;
 123
 124                     *)
 125                             AC_MSG_ERROR(see the INSTALL doc for more info)
 126                             ;;
 127                     esac
 128             fi
 129             $2="$$2 -I/usr/local/include"
 130             LDFLAGS="$LDFLAGS -L/usr/local/lib"
 131
 132             case "$host_os" in
 133
 134             irix*)
 135                     V_CCOPT="$V_CCOPT -xansi -signed -O"
 136                     ;;
 137
 138             osf*)
 139                     V_CCOPT="$V_CCOPT -std1 -O"
 140                     ;;
 141
 142             ultrix*)
 143                     AC_MSG_CHECKING(that Ultrix $CC hacks const in prototypes)
 144                     AC_CACHE_VAL(ac_cv_lbl_cc_const_proto,
 145                         AC_TRY_COMPILE(
 146                             [#include <sys/types.h>],
 147                             [struct a { int b; };
 148                             void c(const struct a *)],
 149                             ac_cv_lbl_cc_const_proto=yes,
 150                             ac_cv_lbl_cc_const_proto=no))
 151                     AC_MSG_RESULT($ac_cv_lbl_cc_const_proto)
 152                     if test $ac_cv_lbl_cc_const_proto = no ; then
 153                             AC_DEFINE(const,)
 154                     fi
 155                     ;;
 156             esac
 157     fi
 158 ])
 159
 160 #
 161 # Try compiling a sample of the type of code that appears in
 162 # gencode.c with "inline", "__inline__", and "__inline".
 163 #
 164 # Autoconf's AC_C_INLINE, at least in autoconf 2.13, isn't good enough,
 165 # as it just tests whether a function returning "int" can be inlined;
 166 # at least some versions of HP's C compiler can inline that, but can't
 167 # inline a function that returns a struct pointer.
 168 #
 169 AC_DEFUN(AC_LBL_C_INLINE,
 170     [AC_MSG_CHECKING(for inline)
 171     AC_CACHE_VAL(ac_cv_lbl_inline, [
 172         ac_cv_lbl_inline=""
 173         ac_lbl_cc_inline=no
 174         for ac_lbl_inline in inline __inline__ __inline
 175         do
 176             AC_TRY_COMPILE(
 177                 [#define inline $ac_lbl_inline
 178                 static inline struct iltest *foo(void);
 179                 struct iltest {
 180                     int iltest1;
 181                     int iltest2;
 182                 };
 183
 184                 static inline struct iltest *
 185                 foo()
 186                 {
 187                     static struct iltest xxx;
 188
 189                     return &xxx;
 190                 }],,ac_lbl_cc_inline=yes,)
 191             if test "$ac_lbl_cc_inline" = yes ; then
 192                 break;
 193             fi
 194         done
 195         if test "$ac_lbl_cc_inline" = yes ; then
 196             ac_cv_lbl_inline=$ac_lbl_inline
 197         fi])
 198     if test ! -z "$ac_cv_lbl_inline" ; then
 199         AC_MSG_RESULT($ac_cv_lbl_inline)
 200     else
 201         AC_MSG_RESULT(no)
 202     fi
 203     AC_DEFINE_UNQUOTED(inline, $ac_cv_lbl_inline, [Define as token for inline if inlining supported])])
 204
 205 dnl
 206 dnl Use pfopen.c if available and pfopen() not in standard libraries
 207 dnl Require libpcap
 208 dnl Look for libpcap in ..
 209 dnl Use the installed libpcap if there is no local version
 210 dnl
 211 dnl usage:
 212 dnl
 213 dnl     AC_LBL_LIBPCAP(pcapdep, incls)
 214 dnl
 215 dnl results:
 216 dnl
 217 dnl     $1 (pcapdep set)
 218 dnl     $2 (incls appended)
 219 dnl     LIBS
 220 dnl     LBL_LIBS
 221 dnl
 222 AC_DEFUN(AC_LBL_LIBPCAP,
 223     [AC_REQUIRE([AC_LBL_LIBRARY_NET])
 224     dnl
 225     dnl save a copy before locating libpcap.a
 226     dnl
 227     LBL_LIBS="$LIBS"
 228     pfopen=/usr/examples/packetfilter/pfopen.c
 229     if test -f $pfopen ; then
 230             AC_CHECK_FUNCS(pfopen)
 231             if test $ac_cv_func_pfopen = "no" ; then
 232                     AC_MSG_RESULT(Using $pfopen)
 233                     LIBS="$LIBS $pfopen"
 234             fi
 235     fi
 236     AC_MSG_CHECKING(for local pcap library)
 237     libpcap=FAIL
 238     lastdir=FAIL
 239     places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 240         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 241     for dir in $places $srcdir/../libpcap $srcdir/libpcap ; do
 242             basedir=`echo $dir | sed -e 's/[[ab]][[0-9]]*$//'`
 243             if test $lastdir = $basedir ; then
 244                     dnl skip alphas when an actual release is present
 245                     continue;
 246             fi
 247             lastdir=$dir
 248             if test -r $dir/libpcap.a ; then
 249                     libpcap=$dir/libpcap.a
 250                     d=$dir
 251                     dnl continue and select the last one that exists
 252             fi
 253     done
 254     if test $libpcap = FAIL ; then
 255             AC_MSG_RESULT(not found)
 256             AC_CHECK_LIB(pcap, main, libpcap="-lpcap")
 257             if test $libpcap = FAIL ; then
 258                     AC_MSG_ERROR(see the INSTALL doc for more info)
 259             fi
 260             dnl
 261             dnl Good old Red Hat Linux puts "pcap.h" in
 262             dnl "/usr/include/pcap"; had the LBL folks done so,
 263             dnl that would have been a good idea, but for
 264             dnl the Red Hat folks to do so just breaks source
 265             dnl compatibility with other systems.
 266             dnl
 267             dnl We work around this by assuming that, as we didn't
 268             dnl find a local libpcap, libpcap is in /usr/lib or
 269             dnl /usr/local/lib and that the corresponding header
 270             dnl file is under one of those directories; if we don't
 271             dnl find it in either of those directories, we check to
 272             dnl see if it's in a "pcap" subdirectory of them and,
 273             dnl if so, add that subdirectory to the "-I" list.
 274             dnl
 275             AC_MSG_CHECKING(for extraneous pcap header directories)
 276             if test \( ! -r /usr/local/include/pcap.h \) -a \
 277                         \( ! -r /usr/include/pcap.h \); then
 278                 if test -r /usr/local/include/pcap/pcap.h; then
 279                     d="/usr/local/include/pcap"
 280                 elif test -r /usr/include/pcap/pcap.h; then
 281                     d="/usr/include/pcap"
 282                 fi
 283             fi
 284             if test -z "$d" ; then
 285                 AC_MSG_RESULT(not found)
 286             else
 287                 $2="-I$d $$2"
 288                 AC_MSG_RESULT(found -- -I$d added)
 289             fi
 290     else
 291             $1=$libpcap
 292             places=`ls $srcdir/.. | sed -e 's,/$,,' -e "s,^,$srcdir/../," | \
 293                         egrep '/libpcap-[[0-9]]*.[[0-9]]*(.[[0-9]]*)?([[ab]][[0-9]]*)?$'`
 294             if test -r $d/pcap.h; then
 295                     $2="-I$d $$2"
 296             elif test -r $places/pcap.h; then
 297                     $2="-I$places $$2"
 298             else
 299                     AC_MSG_ERROR(cannot find pcap.h, see INSTALL)
 300             fi
 301             AC_MSG_RESULT($libpcap)
 302     fi
 303     LIBS="$libpcap $LIBS"
 304     case "$host_os" in
 305
 306     aix*)
 307             pseexe="/lib/pse.exp"
 308             AC_MSG_CHECKING(for $pseexe)
 309             if test -f $pseexe ; then
 310                     AC_MSG_RESULT(yes)
 311                     LIBS="$LIBS -I:$pseexe"
 312             fi
 313             #
 314             # We need "-lodm" and "-lcfg", as libpcap requires them on
 315             # AIX, and we just build a static libpcap.a and thus can't
 316             # arrange that when you link with libpcap you automatically
 317             # link with those libraries.
 318             #
 319             LIBS="$LIBS -lodm -lcfg"
 320             ;;
 321     esac
 322
 323     dnl
 324     dnl Check for "pcap_list_datalinks()", "pcap_set_datalink()",
 325     dnl and "pcap_datalink_name_to_val()".
 326     dnl
 327     AC_CHECK_FUNC(pcap_list_datalinks,
 328         AC_DEFINE(HAVE_PCAP_LIST_DATALINKS),
 329         LIBOBJS="$LIBOBJS datalinks.o")
 330     AC_CHECK_FUNC(pcap_set_datalink,
 331         AC_DEFINE(HAVE_PCAP_SET_DATALINK))
 332     AC_CHECK_FUNC(pcap_datalink_name_to_val,
 333         AC_DEFINE(HAVE_PCAP_DATALINK_NAME_TO_VAL),
 334         LIBOBJS="$LIBOBJS dlnames.o")
 335 ])
 336
 337 dnl
 338 dnl Define RETSIGTYPE and RETSIGVAL
 339 dnl
 340 dnl usage:
 341 dnl
 342 dnl     AC_LBL_TYPE_SIGNAL
 343 dnl
 344 dnl results:
 345 dnl
 346 dnl     RETSIGTYPE (defined)
 347 dnl     RETSIGVAL (defined)
 348 dnl
 349 AC_DEFUN(AC_LBL_TYPE_SIGNAL,
 350     [AC_BEFORE([$0], [AC_LBL_LIBPCAP])
 351     AC_TYPE_SIGNAL
 352     if test "$ac_cv_type_signal" = void ; then
 353             AC_DEFINE(RETSIGVAL,)
 354     else
 355             AC_DEFINE(RETSIGVAL,(0))
 356     fi
 357     case "$host_os" in
 358
 359     irix*)
 360             AC_DEFINE(_BSD_SIGNALS)
 361             ;;
 362
 363     *)
 364             dnl prefer sigaction() to sigset()
 365             AC_CHECK_FUNCS(sigaction)
 366             if test $ac_cv_func_sigaction = no ; then
 367                     AC_CHECK_FUNCS(sigset)
 368             fi
 369             ;;
 370     esac])
 371
 372 dnl
 373 dnl If using gcc, make sure we have ANSI ioctl definitions
 374 dnl
 375 dnl usage:
 376 dnl
 377 dnl     AC_LBL_FIXINCLUDES
 378 dnl
 379 AC_DEFUN(AC_LBL_FIXINCLUDES,
 380     [if test "$GCC" = yes ; then
 381             AC_MSG_CHECKING(for ANSI ioctl definitions)
 382             AC_CACHE_VAL(ac_cv_lbl_gcc_fixincludes,
 383                 AC_TRY_COMPILE(
 384                     [/*
 385                      * This generates a "duplicate case value" when fixincludes
 386                      * has not be run.
 387                      */
 388 #               include <sys/types.h>
 389 #               include <sys/time.h>
 390 #               include <sys/ioctl.h>
 391 #               ifdef HAVE_SYS_IOCCOM_H
 392 #               include <sys/ioccom.h>
 393 #               endif],
 394                     [switch (0) {
 395                     case _IO('A', 1):;
 396                     case _IO('B', 1):;
 397                     }],
 398                     ac_cv_lbl_gcc_fixincludes=yes,
 399                     ac_cv_lbl_gcc_fixincludes=no))
 400             AC_MSG_RESULT($ac_cv_lbl_gcc_fixincludes)
 401             if test $ac_cv_lbl_gcc_fixincludes = no ; then
 402                     # Don't cache failure
 403                     unset ac_cv_lbl_gcc_fixincludes
 404                     AC_MSG_ERROR(see the INSTALL for more info)
 405             fi
 406     fi])
 407
 408 dnl
 409 dnl Check for flex, default to lex
 410 dnl Require flex 2.4 or higher
 411 dnl Check for bison, default to yacc
 412 dnl Default to lex/yacc if both flex and bison are not available
 413 dnl Define the yy prefix string if using flex and bison
 414 dnl
 415 dnl usage:
 416 dnl
 417 dnl     AC_LBL_LEX_AND_YACC(lex, yacc, yyprefix)
 418 dnl
 419 dnl results:
 420 dnl
 421 dnl     $1 (lex set)
 422 dnl     $2 (yacc appended)
 423 dnl     $3 (optional flex and bison -P prefix)
 424 dnl
 425 AC_DEFUN(AC_LBL_LEX_AND_YACC,
 426     [AC_ARG_WITH(flex, [  --without-flex          don't use flex])
 427     AC_ARG_WITH(bison, [  --without-bison         don't use bison])
 428     if test "$with_flex" = no ; then
 429             $1=lex
 430     else
 431             AC_CHECK_PROGS($1, flex, lex)
 432     fi
 433     if test "$$1" = flex ; then
 434             # The -V flag was added in 2.4
 435             AC_MSG_CHECKING(for flex 2.4 or higher)
 436             AC_CACHE_VAL(ac_cv_lbl_flex_v24,
 437                 if flex -V >/dev/null 2>&1; then
 438                         ac_cv_lbl_flex_v24=yes
 439                 else
 440                         ac_cv_lbl_flex_v24=no
 441                 fi)
 442             AC_MSG_RESULT($ac_cv_lbl_flex_v24)
 443             if test $ac_cv_lbl_flex_v24 = no ; then
 444                     s="2.4 or higher required"
 445                     AC_MSG_WARN(ignoring obsolete flex executable ($s))
 446                     $1=lex
 447             fi
 448     fi
 449     if test "$with_bison" = no ; then
 450             $2=yacc
 451     else
 452             AC_CHECK_PROGS($2, bison, yacc)
 453     fi
 454     if test "$$2" = bison ; then
 455             $2="$$2 -y"
 456     fi
 457     if test "$$1" != lex -a "$$2" = yacc -o "$$1" = lex -a "$$2" != yacc ; then
 458             AC_MSG_WARN(don't have both flex and bison; reverting to lex/yacc)
 459             $1=lex
 460             $2=yacc
 461     fi
 462     if test "$$1" = flex -a -n "$3" ; then
 463             $1="$$1 -P$3"
 464             $2="$$2 -p $3"
 465     fi])
 466
 467 dnl
 468 dnl Checks to see if union wait is used with WEXITSTATUS()
 469 dnl
 470 dnl usage:
 471 dnl
 472 dnl     AC_LBL_UNION_WAIT
 473 dnl
 474 dnl results:
 475 dnl
 476 dnl     DECLWAITSTATUS (defined)
 477 dnl
 478 AC_DEFUN(AC_LBL_UNION_WAIT,
 479     [AC_MSG_CHECKING(if union wait is used)
 480     AC_CACHE_VAL(ac_cv_lbl_union_wait,
 481         AC_TRY_COMPILE([
 482 #       include <sys/types.h>
 483 #       include <sys/wait.h>],
 484             [int status;
 485             u_int i = WEXITSTATUS(status);
 486             u_int j = waitpid(0, &status, 0);],
 487             ac_cv_lbl_union_wait=no,
 488             ac_cv_lbl_union_wait=yes))
 489     AC_MSG_RESULT($ac_cv_lbl_union_wait)
 490     if test $ac_cv_lbl_union_wait = yes ; then
 491             AC_DEFINE(DECLWAITSTATUS,union wait)
 492     else
 493             AC_DEFINE(DECLWAITSTATUS,int)
 494     fi])
 495
 496 dnl
 497 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 498 dnl
 499 dnl usage:
 500 dnl
 501 dnl     AC_LBL_SOCKADDR_SA_LEN
 502 dnl
 503 dnl results:
 504 dnl
 505 dnl     HAVE_SOCKADDR_SA_LEN (defined)
 506 dnl
 507 AC_DEFUN(AC_LBL_SOCKADDR_SA_LEN,
 508     [AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 509     AC_CACHE_VAL(ac_cv_lbl_sockaddr_has_sa_len,
 510         AC_TRY_COMPILE([
 511 #       include <sys/types.h>
 512 #       include <sys/socket.h>],
 513         [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 514         ac_cv_lbl_sockaddr_has_sa_len=yes,
 515         ac_cv_lbl_sockaddr_has_sa_len=no))
 516     AC_MSG_RESULT($ac_cv_lbl_sockaddr_has_sa_len)
 517     if test $ac_cv_lbl_sockaddr_has_sa_len = yes ; then
 518             AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 519     fi])
 520
 521 dnl
 522 dnl Checks to see if -R is used
 523 dnl
 524 dnl usage:
 525 dnl
 526 dnl     AC_LBL_HAVE_RUN_PATH
 527 dnl
 528 dnl results:
 529 dnl
 530 dnl     ac_cv_lbl_have_run_path (yes or no)
 531 dnl
 532 AC_DEFUN(AC_LBL_HAVE_RUN_PATH,
 533     [AC_MSG_CHECKING(for ${CC-cc} -R)
 534     AC_CACHE_VAL(ac_cv_lbl_have_run_path,
 535         [echo 'main(){}' > conftest.c
 536         ${CC-cc} -o conftest conftest.c -R/a1/b2/c3 >conftest.out 2>&1
 537         if test ! -s conftest.out ; then
 538                 ac_cv_lbl_have_run_path=yes
 539         else
 540                 ac_cv_lbl_have_run_path=no
 541         fi
 542         rm -f conftest*])
 543     AC_MSG_RESULT($ac_cv_lbl_have_run_path)
 544     ])
 545
 546 dnl
 547 dnl Due to the stupid way it's implemented, AC_CHECK_TYPE is nearly useless.
 548 dnl
 549 dnl usage:
 550 dnl
 551 dnl     AC_LBL_CHECK_TYPE
 552 dnl
 553 dnl results:
 554 dnl
 555 dnl     int32_t (defined)
 556 dnl     u_int32_t (defined)
 557 dnl
 558 AC_DEFUN(AC_LBL_CHECK_TYPE,
 559     [AC_MSG_CHECKING(for $1 using $CC)
 560     AC_CACHE_VAL(ac_cv_lbl_have_$1,
 561         AC_TRY_COMPILE([
 562 #       include "confdefs.h"
 563 #       include <sys/types.h>
 564 #       if STDC_HEADERS
 565 #       include <stdlib.h>
 566 #       include <stddef.h>
 567 #       endif],
 568         [$1 i],
 569         ac_cv_lbl_have_$1=yes,
 570         ac_cv_lbl_have_$1=no))
 571     AC_MSG_RESULT($ac_cv_lbl_have_$1)
 572     if test $ac_cv_lbl_have_$1 = no ; then
 573             AC_DEFINE($1, $2)
 574     fi])
 575
 576 dnl
 577 dnl Checks to see if unaligned memory accesses fail
 578 dnl
 579 dnl usage:
 580 dnl
 581 dnl     AC_LBL_UNALIGNED_ACCESS
 582 dnl
 583 dnl results:
 584 dnl
 585 dnl     LBL_ALIGN (DEFINED)
 586 dnl
 587 AC_DEFUN(AC_LBL_UNALIGNED_ACCESS,
 588     [AC_MSG_CHECKING(if unaligned accesses fail)
 589     AC_CACHE_VAL(ac_cv_lbl_unaligned_fail,
 590         [case "$host_cpu" in
 591
 592         #
 593         # These are CPU types where:
 594         #
 595         #       the CPU faults on an unaligned access, but at least some
 596         #       OSes that support that CPU catch the fault and simulate
 597         #       the unaligned access (e.g., Alpha/{Digital,Tru64} UNIX) -
 598         #       the simulation is slow, so we don't want to use it;
 599         #
 600         #       the CPU, I infer (from the old
 601         #
 602         # XXX: should also check that they don't do weird things (like on arm)
 603         #
 604         #       comment) doesn't fault on unaligned accesses, but doesn't
 605         #       do a normal unaligned fetch, either (e.g., presumably, ARM);
 606         #
 607         #       for whatever reason, the test program doesn't work
 608         #       (this has been claimed to be the case for several of those
 609         #       CPUs - I don't know what the problem is; the problem
 610         #       was reported as "the test program dumps core" for SuperH,
 611         #       but that's what the test program is *supposed* to do -
 612         #       it dumps core before it writes anything, so the test
 613         #       for an empty output file should find an empty output
 614         #       file and conclude that unaligned accesses don't work).
 615         #
 616         # This run-time test won't work if you're cross-compiling, so
 617         # in order to support cross-compiling for a particular CPU,
 618         # we have to wire in the list of CPU types anyway, as far as
 619         # I know, so perhaps we should just have a set of CPUs on
 620         # which we know it doesn't work, a set of CPUs on which we
 621         # know it does work, and have the script just fail on other
 622         # cpu types and update it when such a failure occurs.
 623         #
 624         alpha*|arm*|hp*|mips*|sh*|sparc*|ia64)
 625                 ac_cv_lbl_unaligned_fail=yes
 626                 ;;
 627
 628         *)
 629                 cat >conftest.c <<EOF
 630 #               include <sys/types.h>
 631 #               include <sys/wait.h>
 632 #               include <stdio.h>
 633                 unsigned char a[[5]] = { 1, 2, 3, 4, 5 };
 634                 main() {
 635                 unsigned int i;
 636                 pid_t pid;
 637                 int status;
 638                 /* avoid "core dumped" message */
 639                 pid = fork();
 640                 if (pid <  0)
 641                         exit(2);
 642                 if (pid > 0) {
 643                         /* parent */
 644                         pid = waitpid(pid, &status, 0);
 645                         if (pid < 0)
 646                                 exit(3);
 647                         exit(!WIFEXITED(status));
 648                 }
 649                 /* child */
 650                 i = *(unsigned int *)&a[[1]];
 651                 printf("%d\n", i);
 652                 exit(0);
 653                 }
 654 EOF
 655                 ${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS \
 656                     conftest.c $LIBS >/dev/null 2>&1
 657                 if test ! -x conftest ; then
 658                         dnl failed to compile for some reason
 659                         ac_cv_lbl_unaligned_fail=yes
 660                 else
 661                         ./conftest >conftest.out
 662                         if test ! -s conftest.out ; then
 663                                 ac_cv_lbl_unaligned_fail=yes
 664                         else
 665                                 ac_cv_lbl_unaligned_fail=no
 666                         fi
 667                 fi
 668                 rm -f conftest* core core.conftest
 669                 ;;
 670         esac])
 671     AC_MSG_RESULT($ac_cv_lbl_unaligned_fail)
 672     if test $ac_cv_lbl_unaligned_fail = yes ; then
 673             AC_DEFINE(LBL_ALIGN)
 674     fi])
 675
 676 dnl
 677 dnl If using gcc and the file .devel exists:
 678 dnl     Compile with -g (if supported) and -Wall
 679 dnl     If using gcc 2 or later, do extra prototype checking and some other
 680 dnl     checks
 681 dnl     If an os prototype include exists, symlink os-proto.h to it
 682 dnl
 683 dnl usage:
 684 dnl
 685 dnl     AC_LBL_DEVEL(copt)
 686 dnl
 687 dnl results:
 688 dnl
 689 dnl     $1 (copt appended)
 690 dnl     HAVE_OS_PROTO_H (defined)
 691 dnl     os-proto.h (symlinked)
 692 dnl
 693 AC_DEFUN(AC_LBL_DEVEL,
 694     [rm -f os-proto.h
 695     if test "${LBL_CFLAGS+set}" = set; then
 696             $1="$$1 ${LBL_CFLAGS}"
 697     fi
 698     if test -f .devel ; then
 699             if test "$GCC" = yes ; then
 700                     if test "${LBL_CFLAGS+set}" != set; then
 701                             if test "$ac_cv_prog_cc_g" = yes ; then
 702                                     $1="-g $$1"
 703                             fi
 704                             $1="$$1 -Wall"
 705                             if test $ac_cv_lbl_gcc_vers -gt 1 ; then
 706                                     $1="$$1 -Wmissing-prototypes -Wstrict-prototypes -Wwrite-strings -W"
 707                             fi
 708                     fi
 709             else
 710                     case "$host_os" in
 711
 712                     irix6*)
 713                             V_CCOPT="$V_CCOPT -n32"
 714                             ;;
 715
 716                     *)
 717                             ;;
 718                     esac
 719             fi
 720             os=`echo $host_os | sed -e 's/\([[0-9]][[0-9]]*\)[[^0-9]].*$/\1/'`
 721             name="lbl/os-$os.h"
 722             if test -f $name ; then
 723                     ln -s $name os-proto.h
 724                     AC_DEFINE(HAVE_OS_PROTO_H)
 725             else
 726                     AC_MSG_WARN(can't find $name)
 727             fi
 728     fi])
 729
 730 dnl
 731 dnl Improved version of AC_CHECK_LIB
 732 dnl
 733 dnl Thanks to John Hawkinson (jhawk@mit.edu)
 734 dnl
 735 dnl usage:
 736 dnl
 737 dnl     AC_LBL_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [,
 738 dnl         ACTION-IF-NOT-FOUND [, OTHER-LIBRARIES]]])
 739 dnl
 740 dnl results:
 741 dnl
 742 dnl     LIBS
 743 dnl
 744 dnl XXX - "AC_LBL_LIBRARY_NET" was redone to use "AC_SEARCH_LIBS"
 745 dnl rather than "AC_LBL_CHECK_LIB", so this isn't used any more.
 746 dnl We keep it around for reference purposes in case it's ever
 747 dnl useful in the future.
 748 dnl
 749
 750 define(AC_LBL_CHECK_LIB,
 751 [AC_MSG_CHECKING([for $2 in -l$1])
 752 dnl Use a cache variable name containing the library, function
 753 dnl name, and extra libraries to link with, because the test really is
 754 dnl for library $1 defining function $2, when linked with potinal
 755 dnl library $5, not just for library $1.  Separate tests with the same
 756 dnl $1 and different $2's or $5's may have different results.
 757 ac_lib_var=`echo $1['_']$2['_']$5 | sed 'y%./+- %__p__%'`
 758 AC_CACHE_VAL(ac_cv_lbl_lib_$ac_lib_var,
 759 [ac_save_LIBS="$LIBS"
 760 LIBS="-l$1 $5 $LIBS"
 761 AC_TRY_LINK(dnl
 762 ifelse([$2], [main], , dnl Avoid conflicting decl of main.
 763 [/* Override any gcc2 internal prototype to avoid an error.  */
 764 ]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
 765 extern "C"
 766 #endif
 767 ])dnl
 768 [/* We use char because int might match the return type of a gcc2
 769     builtin and then its argument prototype would still apply.  */
 770 char $2();
 771 ]),
 772             [$2()],
 773             eval "ac_cv_lbl_lib_$ac_lib_var=yes",
 774             eval "ac_cv_lbl_lib_$ac_lib_var=no")
 775 LIBS="$ac_save_LIBS"
 776 ])dnl
 777 if eval "test \"`echo '$ac_cv_lbl_lib_'$ac_lib_var`\" = yes"; then
 778   AC_MSG_RESULT(yes)
 779   ifelse([$3], ,
 780 [changequote(, )dnl
 781   ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
 782     -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
 783 changequote([, ])dnl
 784   AC_DEFINE_UNQUOTED($ac_tr_lib)
 785   LIBS="-l$1 $LIBS"
 786 ], [$3])
 787 else
 788   AC_MSG_RESULT(no)
 789 ifelse([$4], , , [$4
 790 ])dnl
 791 fi
 792 ])
 793
 794 dnl
 795 dnl AC_LBL_LIBRARY_NET
 796 dnl
 797 dnl This test is for network applications that need socket() and
 798 dnl gethostbyname() -ish functions.  Under Solaris, those applications
 799 dnl need to link with "-lsocket -lnsl".  Under IRIX, they need to link
 800 dnl with "-lnsl" but should *not* link with "-lsocket" because
 801 dnl libsocket.a breaks a number of things (for instance:
 802 dnl gethostbyname() under IRIX 5.2, and snoop sockets under most
 803 dnl versions of IRIX).
 804 dnl
 805 dnl Unfortunately, many application developers are not aware of this,
 806 dnl and mistakenly write tests that cause -lsocket to be used under
 807 dnl IRIX.  It is also easy to write tests that cause -lnsl to be used
 808 dnl under operating systems where neither are necessary (or useful),
 809 dnl such as SunOS 4.1.4, which uses -lnsl for TLI.
 810 dnl
 811 dnl This test exists so that every application developer does not test
 812 dnl this in a different, and subtly broken fashion.
 813
 814 dnl It has been argued that this test should be broken up into two
 815 dnl seperate tests, one for the resolver libraries, and one for the
 816 dnl libraries necessary for using Sockets API. Unfortunately, the two
 817 dnl are carefully intertwined and allowing the autoconf user to use
 818 dnl them independantly potentially results in unfortunate ordering
 819 dnl dependancies -- as such, such component macros would have to
 820 dnl carefully use indirection and be aware if the other components were
 821 dnl executed. Since other autoconf macros do not go to this trouble,
 822 dnl and almost no applications use sockets without the resolver, this
 823 dnl complexity has not been implemented.
 824 dnl
 825 dnl The check for libresolv is in case you are attempting to link
 826 dnl statically and happen to have a libresolv.a lying around (and no
 827 dnl libnsl.a).
 828 dnl
 829 AC_DEFUN(AC_LBL_LIBRARY_NET, [
 830     # Most operating systems have gethostbyname() in the default searched
 831     # libraries (i.e. libc):
 832     # Some OSes (eg. Solaris) place it in libnsl
 833     # Some strange OSes (SINIX) have it in libsocket:
 834     AC_SEARCH_LIBS(gethostbyname, nsl socket resolv)
 835     # Unfortunately libsocket sometimes depends on libnsl and
 836     # AC_SEARCH_LIBS isn't up to the task of handling dependencies like this.
 837     if test "$ac_cv_search_gethostbyname" = "no"
 838     then
 839         AC_CHECK_LIB(socket, gethostbyname,
 840                      LIBS="-lsocket -lnsl $LIBS", , -lnsl)
 841     fi
 842     AC_SEARCH_LIBS(socket, socket, ,
 843         AC_CHECK_LIB(socket, socket, LIBS="-lsocket -lnsl $LIBS", , -lnsl))
 844     # DLPI needs putmsg under HPUX so test for -lstr while we're at it
 845     AC_SEARCH_LIBS(putmsg, str)
 846     ])
 847
 848 dnl Copyright (c) 1999 WIDE Project. All rights reserved.
 849 dnl
 850 dnl Redistribution and use in source and binary forms, with or without
 851 dnl modification, are permitted provided that the following conditions
 852 dnl are met:
 853 dnl 1. Redistributions of source code must retain the above copyright
 854 dnl    notice, this list of conditions and the following disclaimer.
 855 dnl 2. Redistributions in binary form must reproduce the above copyright
 856 dnl    notice, this list of conditions and the following disclaimer in the
 857 dnl    documentation and/or other materials provided with the distribution.
 858 dnl 3. Neither the name of the project nor the names of its contributors
 859 dnl    may be used to endorse or promote products derived from this software
 860 dnl    without specific prior written permission.
 861 dnl
 862 dnl THIS SOFTWARE IS PROVIDED BY THE PROJECT AND CONTRIBUTORS ``AS IS'' AND
 863 dnl ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 864 dnl IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 865 dnl ARE DISCLAIMED.  IN NO EVENT SHALL THE PROJECT OR CONTRIBUTORS BE LIABLE
 866 dnl FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 867 dnl DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 868 dnl OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 869 dnl HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 870 dnl LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 871 dnl OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 872 dnl SUCH DAMAGE.
 873
 874 dnl
 875 dnl Checks to see if AF_INET6 is defined
 876 AC_DEFUN(AC_CHECK_AF_INET6, [
 877         AC_MSG_CHECKING(for AF_INET6)
 878         AC_CACHE_VAL($1,
 879         AC_TRY_COMPILE([
 880 #               include <sys/types.h>
 881 #               include <sys/socket.h>],
 882                 [int a = AF_INET6],
 883                 $1=yes,
 884                 $1=no))
 885         AC_MSG_RESULT($$1)
 886                 if test $$1 = yes ; then
 887                         AC_DEFINE(HAVE_AF_INET6)
 888         fi
 889 ])
 890
 891 dnl
 892 dnl Checks to see if the sockaddr struct has the 4.4 BSD sa_len member
 893 dnl borrowed from LBL libpcap
 894 AC_DEFUN(AC_CHECK_SA_LEN, [
 895         AC_MSG_CHECKING(if sockaddr struct has sa_len member)
 896         AC_CACHE_VAL($1,
 897         AC_TRY_COMPILE([
 898 #               include <sys/types.h>
 899 #               include <sys/socket.h>],
 900                 [u_int i = sizeof(((struct sockaddr *)0)->sa_len)],
 901                 $1=yes,
 902                 $1=no))
 903         AC_MSG_RESULT($$1)
 904                 if test $$1 = yes ; then
 905                         AC_DEFINE(HAVE_SOCKADDR_SA_LEN)
 906         fi
 907 ])
 908
 909 dnl
 910 dnl Checks for portable prototype declaration macro
 911 AC_DEFUN(AC_CHECK_PORTABLE_PROTO,  [
 912         AC_MSG_CHECKING(for __P)
 913         AC_CACHE_VAL($1,
 914         AC_TRY_COMPILE([
 915 #               include <unistd.h>],
 916                 [int f __P(())],
 917                 $1=yes,
 918                 $1=no))
 919         AC_MSG_RESULT($$1)
 920         if test $$1 = yes; then
 921                 AC_DEFINE(HAVE_PORTABLE_PROTOTYPE)
 922         fi
 923 ])
 924
 925 dnl checks for u_intXX_t
 926 AC_DEFUN(AC_CHECK_BITTYPES, [
 927         $1=yes
 928 dnl check for u_int8_t
 929         AC_MSG_CHECKING(for u_int8_t)
 930         AC_CACHE_VAL(ac_cv_u_int8_t,
 931         AC_TRY_COMPILE([
 932 #               include <sys/types.h>],
 933                 [u_int8_t i],
 934                 ac_cv_u_int8_t=yes,
 935                 ac_cv_u_int8_t=no))
 936         AC_MSG_RESULT($ac_cv_u_int8_t)
 937         if test $ac_cv_u_int8_t = yes; then
 938                 AC_DEFINE(HAVE_U_INT8_T)
 939         else
 940                 $1=no
 941         fi
 942 dnl check for u_int16_t
 943         AC_MSG_CHECKING(for u_int16_t)
 944         AC_CACHE_VAL(ac_cv_u_int16_t,
 945         AC_TRY_COMPILE([
 946 #               include <sys/types.h>],
 947                 [u_int16_t i],
 948                 ac_cv_u_int16_t=yes,
 949                 ac_cv_u_int16_t=no))
 950         AC_MSG_RESULT($ac_cv_u_int16_t)
 951         if test $ac_cv_u_int16_t = yes; then
 952                 AC_DEFINE(HAVE_U_INT16_T)
 953         else
 954                 $1=no
 955         fi
 956 dnl check for u_int32_t
 957         AC_MSG_CHECKING(for u_int32_t)
 958         AC_CACHE_VAL(ac_cv_u_int32_t,
 959         AC_TRY_COMPILE([
 960 #               include <sys/types.h>],
 961                 [u_int32_t i],
 962                 ac_cv_u_int32_t=yes,
 963                 ac_cv_u_int32_t=no))
 964         AC_MSG_RESULT($ac_cv_u_int32_t)
 965         if test $ac_cv_u_int32_t = yes; then
 966                 AC_DEFINE(HAVE_U_INT32_T)
 967         else
 968                 $1=no
 969         fi
 970 ])
 971
 972 dnl
 973 dnl Checks for addrinfo structure
 974 AC_DEFUN(AC_STRUCT_ADDRINFO, [
 975         AC_MSG_CHECKING(for addrinfo)
 976         AC_CACHE_VAL($1,
 977         AC_TRY_COMPILE([
 978 #               include <netdb.h>],
 979                 [struct addrinfo a],
 980                 $1=yes,
 981                 $1=no))
 982         AC_MSG_RESULT($$1)
 983         if test $$1 = yes; then
 984                 AC_DEFINE(HAVE_ADDRINFO)
 985         else
 986                 AC_DEFINE(NEED_ADDRINFO_H)
 987         fi
 988 ])
 989
 990 dnl
 991 dnl Checks for NI_MAXSERV
 992 AC_DEFUN(AC_NI_MAXSERV, [
 993         AC_MSG_CHECKING(for NI_MAXSERV)
 994         AC_CACHE_VAL($1,
 995         AC_EGREP_CPP(yes, [#include <netdb.h>
 996 #ifdef NI_MAXSERV
 997 yes
 998 #endif],
 999                 $1=yes,
1000                 $1=no))
1001         AC_MSG_RESULT($$1)
1002         if test $$1 != yes; then
1003                 AC_DEFINE(NEED_ADDRINFO_H)
1004         fi
1005 ])
1006
1007 dnl
1008 dnl Checks for NI_NAMEREQD
1009 AC_DEFUN(AC_NI_NAMEREQD, [
1010         AC_MSG_CHECKING(for NI_NAMEREQD)
1011         AC_CACHE_VAL($1,
1012         AC_EGREP_CPP(yes, [#include <netdb.h>
1013 #ifdef NI_NOFQDN
1014 yes
1015 #endif],
1016                 $1=yes,
1017                 $1=no))
1018         AC_MSG_RESULT($$1)
1019         if test $$1 != yes; then
1020                 AC_DEFINE(NEED_ADDRINFO_H)
1021         fi
1022 ])
1023
1024 dnl
1025 dnl Checks for sockaddr_storage structure
1026 AC_DEFUN(AC_STRUCT_SA_STORAGE, [
1027         AC_MSG_CHECKING(for sockaddr_storage)
1028         AC_CACHE_VAL($1,
1029         AC_TRY_COMPILE([
1030 #               include <sys/types.h>
1031 #               include <sys/socket.h>],
1032                 [struct sockaddr_storage s],
1033                 $1=yes,
1034                 $1=no))
1035         AC_MSG_RESULT($$1)
1036         if test $$1 = yes; then
1037                 AC_DEFINE(HAVE_SOCKADDR_STORAGE)
1038         fi
1039 ])
1040
1041 dnl
1042 dnl Checks for macro of IP address size
1043 AC_DEFUN(AC_CHECK_ADDRSZ, [
1044         $1=yes
1045 dnl check for INADDRSZ
1046         AC_MSG_CHECKING(for INADDRSZ)
1047         AC_CACHE_VAL(ac_cv_inaddrsz,
1048         AC_TRY_COMPILE([
1049 #               include <arpa/nameser.h>],
1050                 [int a = INADDRSZ],
1051                 ac_cv_inaddrsz=yes,
1052                 ac_cv_inaddrsz=no))
1053         AC_MSG_RESULT($ac_cv_inaddrsz)
1054         if test $ac_cv_inaddrsz = yes; then
1055                 AC_DEFINE(HAVE_INADDRSZ)
1056         else
1057                 $1=no
1058         fi
1059 dnl check for IN6ADDRSZ
1060         AC_MSG_CHECKING(for IN6ADDRSZ)
1061         AC_CACHE_VAL(ac_cv_in6addrsz,
1062         AC_TRY_COMPILE([
1063 #               include <arpa/nameser.h>],
1064                 [int a = IN6ADDRSZ],
1065                 ac_cv_in6addrsz=yes,
1066                 ac_cv_in6addrsz=no))
1067         AC_MSG_RESULT($ac_cv_in6addrsz)
1068         if test $ac_cv_in6addrsz = yes; then
1069                 AC_DEFINE(HAVE_IN6ADDRSZ)
1070         else
1071                 $1=no
1072         fi
1073 ])
1074
1075 dnl
1076 dnl check for RES_USE_INET6
1077 AC_DEFUN(AC_CHECK_RES_USE_INET6, [
1078         AC_MSG_CHECKING(for RES_USE_INET6)
1079         AC_CACHE_VAL($1,
1080         AC_TRY_COMPILE([
1081 #               include <sys/types.h>
1082 #               include <netinet/in.h>
1083 #               include <resolv.h>],
1084                 [int a = RES_USE_INET6],
1085                 $1=yes,
1086                 $1=no))
1087         AC_MSG_RESULT($$1)
1088         if test $$1 = yes; then
1089                 AC_DEFINE(HAVE_RES_USE_INET6)
1090         fi
1091 ])
1092
1093 dnl
1094 dnl check for AAAA
1095 AC_DEFUN(AC_CHECK_AAAA, [
1096         AC_MSG_CHECKING(for AAAA)
1097         AC_CACHE_VAL($1,
1098         AC_TRY_COMPILE([
1099 #               include <sys/types.h>
1100 #               include <arpa/nameser.h>],
1101                 [int a = T_AAAA],
1102                 $1=yes,
1103                 $1=no))
1104         AC_MSG_RESULT($$1)
1105         if test $$1 = yes; then
1106                 AC_DEFINE(HAVE_AAAA)
1107         fi
1108 ])
1109
1110 dnl
1111 dnl check for struct res_state_ext
1112 AC_DEFUN(AC_STRUCT_RES_STATE_EXT, [
1113         AC_MSG_CHECKING(for res_state_ext)
1114         AC_CACHE_VAL($1,
1115         AC_TRY_COMPILE([
1116 #               include <sys/types.h>
1117 #               include <netinet/in.h>
1118 #               include <netinet6/in6.h>
1119 #               include <resolv.h>],
1120                 [struct __res_state_ext e],
1121                 $1=yes,
1122                 $1=no))
1123         AC_MSG_RESULT($$1)
1124         if test $$1 = yes; then
1125                 AC_DEFINE(HAVE_RES_STATE_EXT)
1126         fi
1127 ])
1128
1129 dnl
1130 dnl check for struct res_state_ext
1131 AC_DEFUN(AC_STRUCT_RES_STATE, [
1132         AC_MSG_CHECKING(for nsort in res_state)
1133         AC_CACHE_VAL($1,
1134         AC_TRY_COMPILE([
1135 #               include <sys/types.h>
1136 #               include <netinet/in.h>
1137 #               include <netinet6/in6.h>
1138 #               include <resolv.h>],
1139                 [struct __res_state e; e.nsort = 0],
1140                 $1=yes,
1141                 $1=no))
1142         AC_MSG_RESULT($$1)
1143         if test $$1 = yes; then
1144                 AC_DEFINE(HAVE_NEW_RES_STATE)
1145         fi
1146 ])
1147
1148 dnl
1149 dnl check for h_errno
1150 AC_DEFUN(AC_VAR_H_ERRNO, [
1151         AC_MSG_CHECKING(for h_errno)
1152         AC_CACHE_VAL(ac_cv_var_h_errno,
1153         AC_TRY_COMPILE([
1154 #               include <sys/types.h>
1155 #               include <netdb.h>],
1156                 [int foo = h_errno;],
1157                 ac_cv_var_h_errno=yes,
1158                 ac_cv_var_h_errno=no))
1159         AC_MSG_RESULT($ac_cv_var_h_errno)
1160         if test "$ac_cv_var_h_errno" = "yes"; then
1161                 AC_DEFINE(HAVE_H_ERRNO)
1162         fi
1163 ])
1164
1165 dnl
1166 dnl Test for __attribute__
1167 dnl
1168
1169 AC_DEFUN(AC_C___ATTRIBUTE__, [
1170 AC_MSG_CHECKING(for __attribute__)
1171 AC_CACHE_VAL(ac_cv___attribute__, [
1172 AC_TRY_COMPILE([
1173 #include <stdlib.h>
1174 ],
1175 [
1176 static void foo(void) __attribute__ ((noreturn));
1177
1178 static void
1179 foo(void)
1180 {
1181   exit(1);
1182 }
1183 ],
1184 ac_cv___attribute__=yes,
1185 ac_cv___attribute__=no)])
1186 if test "$ac_cv___attribute__" = "yes"; then
1187   AC_DEFINE(HAVE___ATTRIBUTE__, 1, [define if your compiler has __attribute__])
1188 fi
1189 AC_MSG_RESULT($ac_cv___attribute__)
1190 ])