The Tcpdump Group git mirrors - tcpdump/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/tcpdump/configure.in,v 1.155 2002-08-03 22:37:01 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 AC_REVISION($Revision: 1.155 $)
  10 AC_PREREQ(2.13)
  11 AC_INIT(tcpdump.c)
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  16 AC_LBL_C_INLINE
  17 AC_C___ATTRIBUTE__
  18
  19 AC_CHECK_HEADERS(fcntl.h rpc/rpcent.h netinet/if_ether.h netdnet/dnetdb.h)
  20 AC_HEADER_TIME
  21
  22 case "$host_os" in
  23
  24 linux*)
  25         AC_MSG_CHECKING(Linux kernel version)
  26         if test "$cross_compiling" = yes; then
  27                 AC_CACHE_VAL(ac_cv_linux_vers,
  28                     ac_cv_linux_vers=unknown)
  29         else
  30                 AC_CACHE_VAL(ac_cv_linux_vers,
  31                     ac_cv_linux_vers=`uname -r 2>&1 | \
  32                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
  33         fi
  34         AC_MSG_RESULT($ac_cv_linux_vers)
  35         if test $ac_cv_linux_vers = unknown ; then
  36                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
  37         fi
  38         if test $ac_cv_linux_vers -lt 2 ; then
  39                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
  40         fi
  41         ;;
  42
  43 *)
  44         ;;
  45 esac
  46
  47
  48 AC_CHECK_HEADERS(smi.h)
  49 AC_CHECK_LIB(smi, smiInit)
  50 if test "$ac_cv_header_smi_h" = yes -a "$ac_cv_lib_smi_smiInit" = yes
  51 then
  52 AC_MSG_CHECKING([whether to enable libsmi])
  53         AC_TRY_RUN([ /* libsmi available check */
  54 #include <smi.h>
  55 main()
  56 {
  57   int current, revision, age, n;
  58   const int required = 2;
  59   if (smiInit(""))
  60     exit(1);
  61   if (strcmp(SMI_LIBRARY_VERSION, smi_library_version))
  62     exit(2);
  63   n = sscanf(smi_library_version, "%d:%d:%d", &current, &revision, &age);
  64   if (n != 3)
  65     exit(3);
  66   if (required < current - age || required > current)
  67     exit(4);
  68   exit(0);
  69 }
  70 ],
  71 [ AC_MSG_RESULT(yes)
  72   AC_DEFINE(LIBSMI)
  73   libsmi=yes],
  74 dnl autoconf documentation says that $? contains the exit value.
  75 dnl reality is that it does not.  We leave this in just in case
  76 dnl autoconf ever comes back to match the documentation.
  77 [ case $? in
  78   1) AC_MSG_RESULT(no - smiInit failed) ;;
  79   2) AC_MSG_RESULT(no - header/library version mismatch) ;;
  80   3) AC_MSG_RESULT(no - can't determine library version) ;;
  81   4) AC_MSG_RESULT(no - too old) ;;
  82   *) AC_MSG_RESULT(no) ;;
  83   esac
  84   libsmi=no],
  85 [ AC_MSG_RESULT(not when cross-compiling)
  86   libsmi=no]
  87 )
  88 fi
  89
  90 AC_MSG_CHECKING([whether to enable the possibly-buggy SMB printer])
  91 AC_ARG_ENABLE(smb,
  92 [  --enable-smb            enable possibly-buggy SMB printer [default=yes]
  93   --disable-smb           disable possibly-buggy SMB printer],,
  94    enableval=yes)
  95 case "$enableval" in
  96 yes)    AC_MSG_RESULT(yes)
  97         AC_WARN([The SMB printer may have exploitable buffer overflows!!!])
  98         AC_DEFINE(TCPDUMP_DO_SMB)
  99         LOCALSRC="print-smb.c smbutil.c $LOCALSRC"
 100         ;;
 101 *)      AC_MSG_RESULT(no)
 102         ;;
 103 esac
 104
 105 AC_MSG_CHECKING([whether to enable ipv6])
 106 AC_ARG_ENABLE(ipv6,
 107 [  --enable-ipv6           enable ipv6 (with ipv4) support
 108   --disable-ipv6          disable ipv6 support],
 109 [ case "$enableval" in
 110 yes)   AC_MSG_RESULT(yes)
 111        LOCALSRC="print-ip6.c print-ip6opts.c print-mobility.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 112        AC_DEFINE(INET6)
 113        ipv6=yes
 114        ;;
 115 *)
 116        AC_MSG_RESULT(no)
 117        ipv6=no
 118        ;;
 119   esac ],
 120
 121   AC_TRY_RUN([ /* AF_INET6 available check */
 122 #include <sys/types.h>
 123 #include <sys/socket.h>
 124 main()
 125 {
 126  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 127    exit(1);
 128  else
 129    exit(0);
 130 }
 131 ],
 132 [ AC_MSG_RESULT(yes)
 133   LOCALSRC="print-ip6.c print-ip6opts.c print-mobility.c print-ripng.c print-icmp6.c print-frag6.c print-rt6.c print-ospf6.c print-dhcp6.c $LOCALSRC"
 134   AC_DEFINE(INET6)
 135   ipv6=yes],
 136 [ AC_MSG_RESULT(no)
 137   ipv6=no],
 138 [ AC_MSG_RESULT(no)
 139   ipv6=no]
 140 ))
 141
 142 ipv6type=unknown
 143 ipv6lib=none
 144 ipv6trylibc=no
 145
 146 if test "$ipv6" = "yes"; then
 147         AC_MSG_CHECKING([ipv6 stack type])
 148         for i in inria kame linux-glibc linux-libinet6 toshiba v6d zeta; do
 149                 case $i in
 150                 inria)
 151                         dnl http://www.kame.net/
 152                         AC_EGREP_CPP(yes, [dnl
 153 #include <netinet/in.h>
 154 #ifdef IPV6_INRIA_VERSION
 155 yes
 156 #endif],
 157                                 [ipv6type=$i;
 158                                 CFLAGS="-DINET6 $CFLAGS"])
 159                         ;;
 160                 kame)
 161                         dnl http://www.kame.net/
 162                         AC_EGREP_CPP(yes, [dnl
 163 #include <netinet/in.h>
 164 #ifdef __KAME__
 165 yes
 166 #endif],
 167                                 [ipv6type=$i;
 168                                 ipv6lib=inet6;
 169                                 ipv6libdir=/usr/local/v6/lib;
 170                                 ipv6trylibc=yes;
 171                                 CFLAGS="-DINET6 $CFLAGS"])
 172                         ;;
 173                 linux-glibc)
 174                         dnl http://www.v6.linux.or.jp/
 175                         AC_EGREP_CPP(yes, [dnl
 176 #include <features.h>
 177 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 178 yes
 179 #endif],
 180                                 [ipv6type=$i;
 181                                 CFLAGS="-DINET6 $CFLAGS"])
 182                         ;;
 183                 linux-libinet6)
 184                         dnl http://www.v6.linux.or.jp/
 185                         dnl
 186                         dnl This also matches Solaris 8 and Tru64 UNIX 5.1,
 187                         dnl and possibly other versions of those OSes
 188                         dnl
 189                         if test -d /usr/inet6 -o -f /usr/include/netinet/ip6.h; then
 190                                 ipv6type=$i
 191                                 ipv6lib=inet6
 192                                 ipv6libdir=/usr/inet6/lib
 193                                 ipv6trylibc=yes;
 194                                 CFLAGS="-DINET6 -I/usr/inet6/include $CFLAGS"
 195                         fi
 196                         ;;
 197                 toshiba)
 198                         AC_EGREP_CPP(yes, [dnl
 199 #include <sys/param.h>
 200 #ifdef _TOSHIBA_INET6
 201 yes
 202 #endif],
 203                                 [ipv6type=$i;
 204                                 ipv6lib=inet6;
 205                                 ipv6libdir=/usr/local/v6/lib;
 206                                 CFLAGS="-DINET6 $CFLAGS"])
 207                         ;;
 208                 v6d)
 209                         AC_EGREP_CPP(yes, [dnl
 210 #include </usr/local/v6/include/sys/v6config.h>
 211 #ifdef __V6D__
 212 yes
 213 #endif],
 214                                 [ipv6type=$i;
 215                                 ipv6lib=v6;
 216                                 ipv6libdir=/usr/local/v6/lib;
 217                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 218                         ;;
 219                 zeta)
 220                         AC_EGREP_CPP(yes, [dnl
 221 #include <sys/param.h>
 222 #ifdef _ZETA_MINAMI_INET6
 223 yes
 224 #endif],
 225                                 [ipv6type=$i;
 226                                 ipv6lib=inet6;
 227                                 ipv6libdir=/usr/local/v6/lib;
 228                                 CFLAGS="-DINET6 $CFLAGS"])
 229                         ;;
 230                 esac
 231                 if test "$ipv6type" != "unknown"; then
 232                         break
 233                 fi
 234         done
 235         AC_MSG_RESULT($ipv6type)
 236 fi
 237
 238 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 239         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 240                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 241                 echo "You have $ipv6lib library, using it"
 242         else
 243                 if test "$ipv6trylibc" = "yes"; then
 244                         echo "You do not have $ipv6lib library, using libc"
 245                 else
 246                         echo 'Fatal: no $ipv6lib library found.  cannot continue.'
 247                         echo "You need to fetch lib$ipv6lib.a from appropriate"
 248                         echo 'ipv6 kit and compile beforehand.'
 249                         exit 1
 250                 fi
 251         fi
 252 fi
 253
 254
 255 if test "$ipv6" = "yes"; then
 256         #
 257         # XXX - on Tru64 UNIX 5.1, there is no "getaddrinfo()"
 258         # function in libc; there are "ngetaddrinfo()" and
 259         # "ogetaddrinfo()" functions, and <netdb.h> #defines
 260         # "getaddrinfo" to be either "ngetaddrinfo" or
 261         # "ogetaddrinfo", depending on whether _SOCKADDR_LEN
 262         # or _XOPEN_SOURCE_EXTENDED are defined or not.
 263         #
 264         # So this test doesn't work on Tru64 5.1, and possibly
 265         # on other 5.x releases.  This causes the configure
 266         # script to become confused, and results in libpcap
 267         # being unbuildable.
 268         #
 269         AC_SEARCH_LIBS(getaddrinfo, socket, [dnl
 270         AC_MSG_CHECKING(getaddrinfo bug)
 271         AC_CACHE_VAL(td_cv_buggygetaddrinfo, [AC_TRY_RUN([
 272 #include <sys/types.h>
 273 #include <netdb.h>
 274 #include <string.h>
 275 #include <sys/socket.h>
 276 #include <netinet/in.h>
 277
 278 main()
 279 {
 280   int passive, gaierr, inet4 = 0, inet6 = 0;
 281   struct addrinfo hints, *ai, *aitop;
 282   char straddr[INET6_ADDRSTRLEN], strport[16];
 283
 284   for (passive = 0; passive <= 1; passive++) {
 285     memset(&hints, 0, sizeof(hints));
 286     hints.ai_family = AF_UNSPEC;
 287     hints.ai_flags = passive ? AI_PASSIVE : 0;
 288     hints.ai_socktype = SOCK_STREAM;
 289     if ((gaierr = getaddrinfo(NULL, "54321", &hints, &aitop)) != 0) {
 290       (void)gai_strerror(gaierr);
 291       goto bad;
 292     }
 293     for (ai = aitop; ai; ai = ai->ai_next) {
 294       if (ai->ai_addr == NULL ||
 295           ai->ai_addrlen == 0 ||
 296           getnameinfo(ai->ai_addr, ai->ai_addrlen,
 297                       straddr, sizeof(straddr), strport, sizeof(strport),
 298                       NI_NUMERICHOST|NI_NUMERICSERV) != 0) {
 299         goto bad;
 300       }
 301       switch (ai->ai_family) {
 302       case AF_INET:
 303         if (strcmp(strport, "54321") != 0) {
 304           goto bad;
 305         }
 306         if (passive) {
 307           if (strcmp(straddr, "0.0.0.0") != 0) {
 308             goto bad;
 309           }
 310         } else {
 311           if (strcmp(straddr, "127.0.0.1") != 0) {
 312             goto bad;
 313           }
 314         }
 315         inet4++;
 316         break;
 317       case AF_INET6:
 318         if (strcmp(strport, "54321") != 0) {
 319           goto bad;
 320         }
 321         if (passive) {
 322           if (strcmp(straddr, "::") != 0) {
 323             goto bad;
 324           }
 325         } else {
 326           if (strcmp(straddr, "::1") != 0) {
 327             goto bad;
 328           }
 329         }
 330         inet6++;
 331         break;
 332       case AF_UNSPEC:
 333         goto bad;
 334         break;
 335 #ifdef AF_UNIX
 336       case AF_UNIX:
 337 #else
 338 #ifdef AF_LOCAL
 339       case AF_LOCAL:
 340 #endif
 341 #endif
 342       default:
 343         /* another family support? */
 344         break;
 345       }
 346     }
 347   }
 348
 349   /* supported family should be 2, unsupported family should be 0 */
 350   if (!(inet4 == 0 || inet4 == 2))
 351     goto bad;
 352   if (!(inet6 == 0 || inet6 == 2))
 353     goto bad;
 354
 355   if (aitop)
 356     freeaddrinfo(aitop);
 357   exit(0);
 358
 359  bad:
 360   if (aitop)
 361     freeaddrinfo(aitop);
 362   exit(1);
 363 }
 364 ],
 365         td_cv_buggygetaddrinfo=no,
 366         td_cv_buggygetaddrinfo=yes,
 367         td_cv_buggygetaddrinfo=yes)])
 368         if test "$td_cv_buggygetaddrinfo" = no; then
 369                 AC_MSG_RESULT(good)
 370         else
 371                 AC_MSG_RESULT(buggy)
 372         fi
 373
 374         if test "$td_cv_buggygetaddrinfo" = "yes"; then
 375                 #
 376                 # XXX - it doesn't appear that "ipv6type" can ever be
 377                 # set to "linux".  Should this be testing for
 378                 # "linux-glibc", or for that *or* "linux-libinet6"?
 379                 # If the latter, note that "linux-libinet6" is also
 380                 # the type given to some non-Linux OSes.
 381                 #
 382                 if test "$ipv6type" != "linux"; then
 383                         echo 'Fatal: You must get working getaddrinfo() function.'
 384                         echo '       or you can specify "--disable-ipv6"'.
 385                         exit 1
 386                 else
 387                         echo 'Warning: getaddrinfo() implementation on your system seems be buggy.'
 388                         echo '         Better upgrade your system library to newest version'
 389                         echo '         of GNU C library (aka glibc).'
 390                 fi
 391         fi
 392         ])
 393         AC_REPLACE_FUNCS(getaddrinfo getnameinfo)
 394 fi
 395 dnl AC_TRY_COMPILE(inet_ntop inet_pton inet_aton)
 396 AC_MSG_CHECKING(for inet_ntop)
 397 AC_TRY_COMPILE([#include <sys/types.h>
 398 #include <sys/socket.h>
 399 #include <netinet/in.h>
 400 #include <arpa/inet.h>], [char src[4], dst[128];
 401 inet_ntop(AF_INET, src, dst, sizeof(dst));],
 402         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 403         AC_REPLACE_FUNCS(inet_ntop)])
 404 AC_MSG_CHECKING(for inet_pton)
 405 AC_TRY_COMPILE([#include <sys/types.h>
 406 #include <sys/socket.h>
 407 #include <netinet/in.h>
 408 #include <arpa/inet.h>], [char src[128], dst[4];
 409 inet_pton(AF_INET, src, dst);],
 410         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 411         AC_REPLACE_FUNCS(inet_pton)])
 412 AC_MSG_CHECKING(for inet_aton)
 413 AC_TRY_COMPILE([#include <sys/types.h>
 414 #include <netinet/in.h>
 415 #include <arpa/inet.h>], [char src[128];
 416 struct in_addr dst;
 417 inet_aton(src, &dst);],
 418         [AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)
 419         AC_REPLACE_FUNCS(inet_aton)])
 420
 421 dnl portability macros for getaddrinfo/getnameinfo
 422 dnl
 423 dnl Check for sa_len
 424 AC_CHECK_SA_LEN(ac_cv_sockaddr_has_sa_len)
 425 if test "$ac_cv_sockaddr_has_sa_len" = no; then
 426         missing_includes=yes
 427 fi
 428
 429 AC_CACHE_CHECK([for dnet_htoa declaration in netdnet/dnetdb.h],
 430 [td_cv_decl_netdnet_dnetdb_h_dnet_htoa],
 431 [AC_EGREP_HEADER(dnet_htoa, netdnet/dnetdb.h,
 432         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=yes,
 433         td_cv_decl_netdnet_dnetdb_h_dnet_htoa=no)])
 434 if test "$td_cv_decl_netdnet_dnetdb_h_dnet_htoa" = yes; then
 435         AC_DEFINE(HAVE_NETDNET_DNETDB_H_DNET_HTOA)
 436 fi
 437
 438 dnl
 439 dnl check sizeof basic types.
 440 dnl They're very likely to be wrong for cross-compiling.
 441 AC_CHECK_SIZEOF(char, 1)
 442 AC_CHECK_SIZEOF(short, 2)
 443 AC_CHECK_SIZEOF(int, 4)
 444 AC_CHECK_SIZEOF(long, 4)
 445
 446 dnl
 447 dnl Checks for u_intXX_t
 448 dnl AC_CHECK_BITTYPES(ac_cv_bittypes)
 449 dnl if test "$ac_cv_bittypes" = no; then
 450 dnl     missing_includes=yes
 451 dnl fi
 452
 453 dnl
 454 dnl Checks for addrinfo structure
 455 AC_STRUCT_ADDRINFO(ac_cv_addrinfo)
 456 if test "$ac_cv_addrinfo" = no; then
 457         missing_includes=yes
 458 fi
 459
 460 dnl
 461 dnl Checks for NI_MAXSERV
 462 AC_NI_MAXSERV(ac_cv_maxserv)
 463 if test "$ac_cv_maxserv" = no; then
 464         missing_includes=yes
 465 fi
 466
 467 dnl
 468 dnl Checks for NI_NAMEREQD
 469 AC_NI_NAMEREQD(ac_cv_namereqd)
 470 if test "$ac_cv_namereqd" = no; then
 471         missing_includes=yes
 472 fi
 473
 474 dnl
 475 dnl Checks for sockaddr_storage structure
 476 AC_STRUCT_SA_STORAGE(ac_cv_sa_storage)
 477 if test "$ac_cv_sa_storage" = no; then
 478         missing_includes=yes
 479 fi
 480
 481 dnl
 482 dnl Checks for IN[6]ADDRSZ
 483 AC_CHECK_ADDRSZ(ac_cv_addrsz)
 484 if test "$ac_cv_addrsz" = no; then
 485         missing_includes=yes
 486 fi
 487
 488 dnl
 489 dnl Checks for RES_USE_INET6
 490 AC_CHECK_RES_USE_INET6(ac_cv_res_inet6)
 491 if test "$ac_cv_res_inet6" = no; then
 492         missing_includes=yes
 493 fi
 494
 495 dnl
 496 dnl Checks for res_state_ext structure
 497 AC_STRUCT_RES_STATE_EXT(ac_cv_res_state_ext)
 498 if test "$ac_cv_res_state_ext" = no; then
 499         missing_includes=yes
 500 fi
 501
 502 dnl
 503 dnl Checks if res_state structure has nsort member.
 504 AC_STRUCT_RES_STATE(ac_cv_res_state)
 505
 506 dnl
 507 dnl set additional include path if necessary
 508 if test "$missing_includes" = "yes"; then
 509         CPPFLAGS="$CPPFLAGS -I\$(srcdir)/missing"
 510         V_INCLS="$V_INCLS -I\$(srcdir)/missing"
 511 fi
 512
 513
 514 AC_REPLACE_FUNCS(vfprintf strcasecmp strlcat strlcpy strdup)
 515 AC_CHECK_FUNCS(ether_ntohost, [
 516     AC_CACHE_CHECK(for buggy ether_ntohost, ac_cv_buggy_ether_ntohost, [
 517         AC_TRY_RUN([
 518                 #include <netdb.h>
 519                 #include <sys/types.h>
 520                 #include <sys/param.h>
 521                 #include <sys/socket.h>
 522
 523                 int
 524                 main(int argc, char **argv)
 525                 {
 526                         u_char ea[6] = { 0xff, 0xff, 0xff, 0xff, 0xff };
 527                         char name[MAXHOSTNAMELEN];
 528
 529                         ether_ntohost(name, (struct ether_addr *)ea);
 530                         exit(0);
 531                 }
 532         ], [ac_cv_buggy_ether_ntohost=no],
 533            [ac_cv_buggy_ether_ntohost=yes],
 534            [ac_cv_buggy_ether_ntohost="not while cross-compiling"])])
 535     if test "$ac_cv_buggy_ether_ntohost" = "no"; then
 536         AC_DEFINE(USE_ETHER_NTOHOST)
 537     fi
 538 ])
 539 AC_CHECK_FUNCS(setlinebuf)
 540
 541 needsnprintf=no
 542 AC_CHECK_FUNCS(vsnprintf snprintf,,
 543         [needsnprintf=yes])
 544 if test $needsnprintf = yes; then
 545         LIBOBJS="$LIBOBJS snprintf.o"
 546 fi
 547
 548 AC_LBL_TYPE_SIGNAL
 549
 550 AC_SEARCH_LIBS(dnet_htoa, dnet, AC_DEFINE(HAVE_DNET_HTOA))
 551
 552 AC_CHECK_LIB(rpc, main)         dnl It's unclear why we might need -lrpc
 553
 554 dnl HP/UX may need -lnsl for getrpcbynumber.
 555 AC_SEARCH_LIBS(getrpcbynumber, nsl)
 556
 557 dnl AC_CHECK_LIB(z, uncompress)
 558 dnl AC_CHECK_HEADERS(zlib.h)
 559
 560 AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)
 561
 562 AC_CHECK_FUNCS(pcap_findalldevs)
 563 AC_REPLACE_FUNCS(bpf_dump)      dnl moved to libpcap in 0.6
 564
 565 V_GROUP=0
 566 if test -f /etc/group -a ! -z "`grep '^wheel:' /etc/group`" ; then
 567         V_GROUP=wheel
 568 fi
 569 case "$host_os" in
 570
 571 aix*)
 572         dnl Workaround to enable certain features
 573         AC_DEFINE(_SUN)
 574         ;;
 575
 576 irix*)
 577         V_GROUP=sys
 578         ;;
 579
 580 osf*)
 581         V_GROUP=system
 582         ;;
 583
 584 solaris*)
 585         V_GROUP=sys
 586         ;;
 587 esac
 588
 589 if test -f /dev/bpf0 ; then
 590         V_GROUP=bpf
 591 fi
 592
 593 AC_LBL_CHECK_TYPE(u_int8_t, u_char)
 594 AC_LBL_CHECK_TYPE(int16_t, short)
 595 AC_LBL_CHECK_TYPE(u_int16_t, u_short)
 596 AC_LBL_CHECK_TYPE(int32_t, int)
 597 AC_LBL_CHECK_TYPE(u_int32_t, u_int)
 598
 599 AC_LBL_DEVEL(V_CCOPT)
 600
 601 AC_LBL_SOCKADDR_SA_LEN
 602
 603 AC_LBL_UNALIGNED_ACCESS
 604
 605 AC_VAR_H_ERRNO
 606
 607 AC_ARG_WITH(crypto, [  --without-crypto        disable crypto support],
 608         [], [
 609 AC_MSG_CHECKING(for SSLeay)
 610 ac_cv_ssleay_path=no
 611 incdir=no
 612 for dir in /usr/${host_alias} /usr /usr/local /usr/local/ssl /usr/pkg; do
 613         if test -d $dir/lib -a -f $dir/lib/libcrypto.a; then
 614                 ac_cv_ssleay_path=$dir
 615         fi
 616         if test -d $dir/include/openssl -a -f $dir/include/openssl/des.h; then
 617                 incdir="-I$dir/include"
 618         fi
 619         if test "$ac_cv_ssleay_path" != "no" -a "$incdir" != "no"; then
 620                 break;
 621         else
 622                 ac_cv_ssleay_path=no
 623                 incdir=no
 624         fi
 625 done
 626 AC_MSG_RESULT($ac_cv_ssleay_path)
 627 if test "$ac_cv_ssleay_path" != no; then
 628         V_INCLS="$V_INCLS $incdir"
 629         LDFLAGS="-L$dir/lib $LDFLAGS"
 630         if test -f $ac_cv_ssleay_path/lib/libRSAglue.a; then
 631                 LIBS="$LIBS -lRSAglue"
 632         fi
 633         if test -f $ac_cv_ssleay_path/lib/librsaref.a; then
 634                 LIBS="$LIBS -lrsaref"
 635         fi
 636         AC_CHECK_LIB(crypto, des_cbc_encrypt)
 637
 638         bak_CPPFLAGS=$CPPFLAGS
 639         CPPFLAGS="$CPPFLAGS $V_INCLS"
 640         AC_CHECK_HEADERS(openssl/cast.h)
 641
 642         if test "$ac_cv_header_openssl_cast_h" = "yes"; then
 643                 AC_MSG_CHECKING(for buggy CAST128)
 644                 AC_CACHE_VAL(td_cv_buggy_cast128, [AC_TRY_RUN(dnl
 645 [
 646 #include <openssl/cast.h>
 647 main()
 648 {
 649         unsigned char key[] = {0x01,0x23,0x45,0x67,0x12};
 650         unsigned char in[] = {0x01,0x23,0x45,0x67,0x89,0xAB,0xCD,0xEF};
 651         unsigned char out[sizeof(in)];
 652         unsigned char ok[] = {0x7A,0xC8,0x16,0xD1,0x6E,0x9B,0x30,0x2E};
 653         CAST_KEY ks;
 654         CAST_set_key(&ks, sizeof(key), key);
 655         CAST_ecb_encrypt(in, out, &ks, CAST_ENCRYPT);
 656         if (memcmp(out, ok, sizeof(ok)) != 0)
 657                 return 0;
 658         else
 659                 return 1;
 660 }],
 661                         [td_cv_buggy_cast128=yes],
 662                         [td_cv_buggy_cast128=no],
 663                         [td_cv_buggy_cast128="cross-compiling, assume yes"])])
 664                 AC_MSG_RESULT($td_cv_buggy_cast128)
 665                 if test "$td_cv_buggy_cast128" != no; then
 666                         echo "NOTE: SSLeay 0.9.0b has a bug in CAST128 en/decoding routine."
 667                         echo "disabling CAST128 support."
 668                         AC_DEFINE(HAVE_BUGGY_CAST128)
 669                 fi
 670         fi
 671
 672         CPPFLAGS=$bak_CPPFLAGS
 673 fi
 674 ])
 675 AC_CHECK_HEADERS(openssl/rc5.h)
 676
 677 AC_SUBST(V_CCOPT)
 678 AC_SUBST(V_GROUP)
 679 AC_SUBST(V_INCLS)
 680 AC_SUBST(V_PCAPDEP)
 681 AC_SUBST(LOCALSRC)
 682
 683 AC_PROG_INSTALL
 684
 685 AC_CONFIG_HEADER(config.h)
 686
 687 AC_OUTPUT_COMMANDS([if test -f .devel; then
 688         echo timestamp > stamp-h
 689         cat Makefile-devel-adds >> Makefile
 690         make depend
 691 fi])
 692 AC_OUTPUT(Makefile)
 693 exit 0