The Tcpdump Group git mirrors - libpcap/blob - scanner.l

   1 %top {
   2 /* Must come first for _LARGE_FILE_API on AIX. */
   3 #include <config.h>
   4
   5 /*
   6  * Must come first to avoid warnings on Windows.
   7  *
   8  * Flex-generated scanners may only include <inttypes.h> if __STDC_VERSION__
   9  * is defined with a value >= 199901, meaning "full C99", and MSVC may not
  10  * define it with that value, because it isn't 100% C99-compliant, even
  11  * though it has an <inttypes.h> capable of defining everything the Flex
  12  * scanner needs.
  13  *
  14  * We, however, will include it if we know we have an MSVC version that has
  15  * it; this means that we may define the INTn_MAX and UINTn_MAX values in
  16  * scanner.c, and then include <stdint.h>, which may define them differently
  17  * (same value, but different string of characters), causing compiler warnings.
  18  *
  19  * If we include it here, and they're defined, that'll prevent scanner.c
  20  * from defining them.  So we include <pcap/pcap-inttypes.h>, to get
  21  * <inttypes.h> if we have it.
  22  */
  23 #include <pcap/pcap-inttypes.h>
  24
  25 /*
  26  * grammar.h requires gencode.h and sometimes breaks in a polluted namespace
  27  * (see ftmacros.h), so include it early.
  28  */
  29 #include "gencode.h"
  30 #include "grammar.h"
  31
  32 #include "diag-control.h"
  33
  34 /*
  35  * Convert string to 32-bit unsigned integer; the string starts at
  36  * string and is string_len bytes long.
  37  *
  38  * On success, sets *val to the value and returns 1.
  39  * On failure, sets the BPF error string and returns 0.
  40  *
  41  * Also used in gencode.c
  42  */
  43 typedef enum {
  44         STOULEN_OK,
  45         STOULEN_NOT_HEX_NUMBER,
  46         STOULEN_NOT_OCTAL_NUMBER,
  47         STOULEN_NOT_DECIMAL_NUMBER,
  48         STOULEN_ERROR
  49 } stoulen_ret;
  50
  51 stoulen_ret stoulen(const char *string, size_t stringlen, bpf_u_int32 *val,
  52     compiler_state_t *cstate);
  53 }
  54
  55 /*
  56  * We want a reentrant scanner.
  57  */
  58 %option reentrant
  59
  60 /*
  61  * And we need to pass the compiler state to the scanner.
  62  */
  63 %option extra-type="compiler_state_t *"
  64
  65 /*
  66  * We don't use input, so don't generate code for it.
  67  */
  68 %option noinput
  69
  70 /*
  71  * We don't use unput, so don't generate code for it.
  72  */
  73 %option nounput
  74
  75 /*
  76  * We don't read from the terminal.
  77  */
  78 %option never-interactive
  79
  80 /*
  81  * We want to stop processing when we get to the end of the input.
  82  */
  83 %option noyywrap
  84
  85 /*
  86  * We want to generate code that can be used by a reentrant parser
  87  * generated by Bison or Berkeley YACC.
  88  */
  89 %option bison-bridge
  90
  91 %{
  92 /*
  93  * Copyright (c) 1988, 1989, 1990, 1991, 1992, 1993, 1994, 1995, 1996, 1997
  94  *      The Regents of the University of California.  All rights reserved.
  95  *
  96  * Redistribution and use in source and binary forms, with or without
  97  * modification, are permitted provided that: (1) source code distributions
  98  * retain the above copyright notice and this paragraph in its entirety, (2)
  99  * distributions including binary code include the above copyright notice and
 100  * this paragraph in its entirety in the documentation or other materials
 101  * provided with the distribution, and (3) all advertising materials mentioning
 102  * features or use of this software display the following acknowledgement:
 103  * ``This product includes software developed by the University of California,
 104  * Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
 105  * the University nor the names of its contributors may be used to endorse
 106  * or promote products derived from this software without specific prior
 107  * written permission.
 108  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
 109  * WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
 110  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
 111  */
 112
 113 #include <string.h>
 114
 115 #include "pcap-int.h"
 116
 117 /*
 118  * Earlier versions of Flex don't declare these, so we declare them
 119  * ourselves to squelch warnings.
 120  */
 121 int pcap_get_column(yyscan_t);
 122 void pcap_set_column(int, yyscan_t);
 123
 124 #ifdef _WIN32
 125 #include <winsock2.h>
 126 #include <ws2tcpip.h>
 127 #else /* _WIN32 */
 128 #include <sys/socket.h> /* for "struct sockaddr" in "struct addrinfo" */
 129 #include <netdb.h>      /* for "struct addrinfo" */
 130 #endif /* _WIN32 */
 131
 132 #include <pcap/namedb.h>
 133 #include "grammar.h"
 134
 135 #ifdef HAVE_OS_PROTO_H
 136 #include "os-proto.h"
 137 #endif
 138
 139 static int stou(const char *, YYSTYPE *, compiler_state_t *);
 140
 141 /*
 142  * Disable diagnostics in the code generated by Flex.
 143  */
 144 DIAG_OFF_FLEX
 145
 146 %}
 147
 148 N               ([0-9]+|(0X|0x)[0-9A-Fa-f]+)
 149 B               ([0-9A-Fa-f][0-9A-Fa-f]?)
 150 B2              ([0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f])
 151 W               ([0-9A-Fa-f][0-9A-Fa-f]?[0-9A-Fa-f]?[0-9A-Fa-f]?)
 152
 153 %a 18400
 154 %o 21500
 155 %e 7600
 156 %k 4550
 157 %p 27600
 158 %n 2000
 159
 160 V680            {W}:{W}:{W}:{W}:{W}:{W}:{W}:{W}
 161
 162 V670            ::{W}:{W}:{W}:{W}:{W}:{W}:{W}
 163 V671            {W}::{W}:{W}:{W}:{W}:{W}:{W}
 164 V672            {W}:{W}::{W}:{W}:{W}:{W}:{W}
 165 V673            {W}:{W}:{W}::{W}:{W}:{W}:{W}
 166 V674            {W}:{W}:{W}:{W}::{W}:{W}:{W}
 167 V675            {W}:{W}:{W}:{W}:{W}::{W}:{W}
 168 V676            {W}:{W}:{W}:{W}:{W}:{W}::{W}
 169 V677            {W}:{W}:{W}:{W}:{W}:{W}:{W}::
 170
 171 V660            ::{W}:{W}:{W}:{W}:{W}:{W}
 172 V661            {W}::{W}:{W}:{W}:{W}:{W}
 173 V662            {W}:{W}::{W}:{W}:{W}:{W}
 174 V663            {W}:{W}:{W}::{W}:{W}:{W}
 175 V664            {W}:{W}:{W}:{W}::{W}:{W}
 176 V665            {W}:{W}:{W}:{W}:{W}::{W}
 177 V666            {W}:{W}:{W}:{W}:{W}:{W}::
 178
 179 V650            ::{W}:{W}:{W}:{W}:{W}
 180 V651            {W}::{W}:{W}:{W}:{W}
 181 V652            {W}:{W}::{W}:{W}:{W}
 182 V653            {W}:{W}:{W}::{W}:{W}
 183 V654            {W}:{W}:{W}:{W}::{W}
 184 V655            {W}:{W}:{W}:{W}:{W}::
 185
 186 V640            ::{W}:{W}:{W}:{W}
 187 V641            {W}::{W}:{W}:{W}
 188 V642            {W}:{W}::{W}:{W}
 189 V643            {W}:{W}:{W}::{W}
 190 V644            {W}:{W}:{W}:{W}::
 191
 192 V630            ::{W}:{W}:{W}
 193 V631            {W}::{W}:{W}
 194 V632            {W}:{W}::{W}
 195 V633            {W}:{W}:{W}::
 196
 197 V620            ::{W}:{W}
 198 V621            {W}::{W}
 199 V622            {W}:{W}::
 200
 201 V610            ::{W}
 202 V611            {W}::
 203
 204 V600            ::
 205
 206 V6604           {W}:{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 207
 208 V6504           ::{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 209 V6514           {W}::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 210 V6524           {W}:{W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 211 V6534           {W}:{W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 212 V6544           {W}:{W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 213 V6554           {W}:{W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 214
 215 V6404           ::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 216 V6414           {W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 217 V6424           {W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 218 V6434           {W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 219 V6444           {W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 220
 221 V6304           ::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 222 V6314           {W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 223 V6324           {W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 224 V6334           {W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 225
 226 V6204           ::{W}:{W}:{N}\.{N}\.{N}\.{N}
 227 V6214           {W}::{W}:{N}\.{N}\.{N}\.{N}
 228 V6224           {W}:{W}::{N}\.{N}\.{N}\.{N}
 229
 230 V6104           ::{W}:{N}\.{N}\.{N}\.{N}
 231 V6114           {W}::{N}\.{N}\.{N}\.{N}
 232
 233 V6004           ::{N}\.{N}\.{N}\.{N}
 234
 235
 236 V6              ({V680}|{V670}|{V671}|{V672}|{V673}|{V674}|{V675}|{V676}|{V677}|{V660}|{V661}|{V662}|{V663}|{V664}|{V665}|{V666}|{V650}|{V651}|{V652}|{V653}|{V654}|{V655}|{V640}|{V641}|{V642}|{V643}|{V644}|{V630}|{V631}|{V632}|{V633}|{V620}|{V621}|{V622}|{V610}|{V611}|{V600}|{V6604}|{V6504}|{V6514}|{V6524}|{V6534}|{V6544}|{V6554}|{V6404}|{V6414}|{V6424}|{V6434}|{V6444}|{V6304}|{V6314}|{V6324}|{V6334}|{V6204}|{V6214}|{V6224}|{V6104}|{V6114}|{V6004})
 237
 238 MAC             ({B}:{B}:{B}:{B}:{B}:{B}|{B}\-{B}\-{B}\-{B}\-{B}\-{B}|{B}\.{B}\.{B}\.{B}\.{B}\.{B}|{B2}\.{B2}\.{B2}|{B2}{3})
 239
 240
 241
 242 %%
 243 dst             return DST;
 244 src             return SRC;
 245
 246 link|ether|ppp|slip  return LINK;
 247 fddi|tr|wlan    return LINK;
 248 arp             return ARP;
 249 rarp            return RARP;
 250 ip              return IP;
 251 sctp            return SCTP;
 252 tcp             return TCP;
 253 udp             return UDP;
 254 icmp            return ICMP;
 255 igmp            return IGMP;
 256 igrp            return IGRP;
 257 pim             return PIM;
 258 vrrp            return VRRP;
 259 carp            return CARP;
 260 radio           return RADIO;
 261
 262 ip6             return IPV6;
 263 icmp6           return ICMPV6;
 264 ah              return AH;
 265 esp             return ESP;
 266
 267 atalk           return ATALK;
 268 aarp            return AARP;
 269 decnet          return DECNET;
 270 lat             return LAT;
 271 sca             return SCA;
 272 moprc           return MOPRC;
 273 mopdl           return MOPDL;
 274
 275 iso             return ISO;
 276 esis            return ESIS;
 277 es-is           return ESIS;
 278 isis            return ISIS;
 279 is-is           return ISIS;
 280 l1              return L1;
 281 l2              return L2;
 282 iih             return IIH;
 283 lsp             return LSP;
 284 snp             return SNP;
 285 csnp            return CSNP;
 286 psnp            return PSNP;
 287
 288 clnp            return CLNP;
 289
 290 stp             return STP;
 291
 292 ipx             return IPX;
 293
 294 netbeui         return NETBEUI;
 295
 296 host            return HOST;
 297 net             return NET;
 298 mask            return NETMASK;
 299 port            return PORT;
 300 portrange       return PORTRANGE;
 301 proto           return PROTO;
 302 protochain      return PROTOCHAIN;
 303
 304 gateway         return GATEWAY;
 305
 306 type            return TYPE;
 307 subtype         return SUBTYPE;
 308 direction|dir   return DIR;
 309 address1|addr1  return ADDR1;
 310 address2|addr2  return ADDR2;
 311 address3|addr3  return ADDR3;
 312 address4|addr4  return ADDR4;
 313 ra              return RA;
 314 ta              return TA;
 315
 316 less            return LESS;
 317 greater         return GREATER;
 318 byte            return CBYTE;
 319 broadcast       return TK_BROADCAST;
 320 multicast       return TK_MULTICAST;
 321
 322 and|"&&"        return AND;
 323 or|"||"         return OR;
 324 not             return '!';
 325
 326 len|length      return LEN;
 327 inbound         return INBOUND;
 328 outbound        return OUTBOUND;
 329
 330 ifindex         return IFINDEX;
 331
 332 vlan            return VLAN;
 333 mpls            return MPLS;
 334 pppoed          return PPPOED;
 335 pppoes          return PPPOES;
 336 geneve          return GENEVE;
 337 vxlan           return VXLAN;
 338
 339 lane            return LANE;
 340 llc             return LLC;
 341 metac           return METAC;
 342 bcc             return BCC;
 343 oam             return OAM;
 344 oamf4           return OAMF4;
 345 oamf4ec         return OAMF4EC;
 346 oamf4sc         return OAMF4SC;
 347 sc              return SC;
 348 ilmic           return ILMIC;
 349 vpi             return VPI;
 350 vci             return VCI;
 351 connectmsg      return CONNECTMSG;
 352 metaconnect     return METACONNECT;
 353
 354 on|ifname       return PF_IFNAME;
 355 rset|ruleset    return PF_RSET;
 356 rnr|rulenum     return PF_RNR;
 357 srnr|subrulenum return PF_SRNR;
 358 reason          return PF_REASON;
 359 action          return PF_ACTION;
 360
 361 fisu            return FISU;
 362 lssu            return LSSU;
 363 lsu             return LSSU;
 364 msu             return MSU;
 365 hfisu           return HFISU;
 366 hlssu           return HLSSU;
 367 hmsu            return HMSU;
 368 sio             return SIO;
 369 opc             return OPC;
 370 dpc             return DPC;
 371 sls             return SLS;
 372 hsio            return HSIO;
 373 hopc            return HOPC;
 374 hdpc            return HDPC;
 375 hsls            return HSLS;
 376
 377 [ \r\n\t]               ;
 378 [+\-*/%:\[\]!<>()&|\^=] return yytext[0];
 379 ">="                    return GEQ;
 380 "<="                    return LEQ;
 381 "!="                    return NEQ;
 382 "=="                    return '=';
 383 "<<"                    return LSH;
 384 ">>"                    return RSH;
 385 ${B}                    { yylval->s = sdup(yyextra, yytext); return AID; }
 386 {MAC}                   { yylval->s = sdup(yyextra, yytext); return EID; }
 387 {N}                     { return stou(yytext, yylval, yyextra); }
 388 ({N}\.{N})|({N}\.{N}\.{N})|({N}\.{N}\.{N}\.{N}) {
 389                         yylval->s = sdup(yyextra, (char *)yytext); return HID; }
 390 {V6}                    {
 391                           struct addrinfo hints, *res;
 392                           memset(&hints, 0, sizeof(hints));
 393                           hints.ai_family = AF_INET6;
 394                           hints.ai_flags = AI_NUMERICHOST;
 395                           if (getaddrinfo(yytext, NULL, &hints, &res)) {
 396                                 bpf_set_error(yyextra, "bogus IPv6 address %s", yytext);
 397                                 yylval->s = NULL;
 398                           } else {
 399                                 freeaddrinfo(res);
 400                                 yylval->s = sdup(yyextra, (char *)yytext);
 401                           }
 402                           return HID6;
 403                         }
 404 {B}:+({B}:+)+           { bpf_set_error(yyextra, "bogus ethernet address %s", yytext); yylval->s = NULL; return EID; }
 405 icmptype                { yylval->h = 0; return NUM; }
 406 icmpcode                { yylval->h = 1; return NUM; }
 407 icmp-echoreply          { yylval->h = 0; return NUM; }
 408 icmp-unreach            { yylval->h = 3; return NUM; }
 409 icmp-sourcequench       { yylval->h = 4; return NUM; }
 410 icmp-redirect           { yylval->h = 5; return NUM; }
 411 icmp-echo               { yylval->h = 8; return NUM; }
 412 icmp-routeradvert       { yylval->h = 9; return NUM; }
 413 icmp-routersolicit      { yylval->h = 10; return NUM; }
 414 icmp-timxceed           { yylval->h = 11; return NUM; }
 415 icmp-paramprob          { yylval->h = 12; return NUM; }
 416 icmp-tstamp             { yylval->h = 13; return NUM; }
 417 icmp-tstampreply        { yylval->h = 14; return NUM; }
 418 icmp-ireq               { yylval->h = 15; return NUM; }
 419 icmp-ireqreply          { yylval->h = 16; return NUM; }
 420 icmp-maskreq            { yylval->h = 17; return NUM; }
 421 icmp-maskreply          { yylval->h = 18; return NUM; }
 422
 423 icmp6type       { yylval->h = 0; return NUM; }
 424 icmp6code       { yylval->h = 1; return NUM; }
 425
 426 icmp6-destinationunreach        { yylval->h = 1; return NUM; }
 427 icmp6-packettoobig              { yylval->h = 2; return NUM; }
 428 icmp6-timeexceeded              { yylval->h = 3; return NUM; }
 429 icmp6-parameterproblem          { yylval->h = 4; return NUM; }
 430 icmp6-echo      { yylval->h = 128; return NUM; }
 431 icmp6-echoreply { yylval->h = 129; return NUM; }
 432 icmp6-multicastlistenerquery    { yylval->h = 130; return NUM; }
 433 icmp6-multicastlistenerreportv1 { yylval->h = 131; return NUM; }
 434 icmp6-multicastlistenerdone     { yylval->h = 132; return NUM; }
 435 icmp6-routersolicit   { yylval->h = 133; return NUM; }
 436 icmp6-routeradvert    { yylval->h = 134; return NUM; }
 437 icmp6-neighborsolicit { yylval->h = 135; return NUM; }
 438 icmp6-neighboradvert  { yylval->h = 136; return NUM; }
 439 icmp6-redirect    { yylval->h = 137; return NUM; }
 440 icmp6-routerrenum { yylval->h = 138; return NUM; }
 441 icmp6-nodeinformationquery      { yylval->h = 139; return NUM; }
 442 icmp6-nodeinformationresponse   { yylval->h = 140; return NUM; }
 443 icmp6-ineighbordiscoverysolicit { yylval->h = 141; return NUM; }
 444 icmp6-ineighbordiscoveryadvert  { yylval->h = 142; return NUM; }
 445 icmp6-multicastlistenerreportv2 { yylval->h = 143; return NUM; }
 446 icmp6-homeagentdiscoveryrequest { yylval->h = 144; return NUM; }
 447 icmp6-homeagentdiscoveryreply   { yylval->h = 145; return NUM; }
 448 icmp6-mobileprefixsolicit       { yylval->h = 146; return NUM; }
 449 icmp6-mobileprefixadvert        { yylval->h = 147; return NUM; }
 450 icmp6-certpathsolicit           { yylval->h = 148; return NUM; }
 451 icmp6-certpathadvert            { yylval->h = 149; return NUM; }
 452 icmp6-multicastrouteradvert     { yylval->h = 151; return NUM; }
 453 icmp6-multicastroutersolicit    { yylval->h = 152; return NUM; }
 454 icmp6-multicastrouterterm       { yylval->h = 153; return NUM; }
 455
 456 tcpflags                { yylval->h = 13; return NUM; }
 457 tcp-fin                 { yylval->h = 0x01; return NUM; }
 458 tcp-syn                 { yylval->h = 0x02; return NUM; }
 459 tcp-rst                 { yylval->h = 0x04; return NUM; }
 460 tcp-push                { yylval->h = 0x08; return NUM; }
 461 tcp-ack                 { yylval->h = 0x10; return NUM; }
 462 tcp-urg                 { yylval->h = 0x20; return NUM; }
 463 tcp-ece                 { yylval->h = 0x40; return NUM; }
 464 tcp-cwr                 { yylval->h = 0x80; return NUM; }
 465 [A-Za-z0-9]([-_.A-Za-z0-9]*[.A-Za-z0-9])? {
 466                          yylval->s = sdup(yyextra, (char *)yytext); return ID; }
 467 "\\"[^ !()\n\t]+        { yylval->s = sdup(yyextra, (char *)yytext + 1); return ID; }
 468 .                       { return LEX_ERROR; }
 469 %%
 470
 471 /*
 472  * Turn diagnostics back on, so we check the code that we've written.
 473  */
 474 DIAG_ON_FLEX
 475
 476 stoulen_ret
 477 stoulen(const char *string, size_t string_len, bpf_u_int32 *val,
 478     compiler_state_t *cstate)
 479 {
 480         bpf_u_int32 n = 0;
 481         unsigned int digit;
 482         const char *s = string;
 483
 484         /*
 485          * string is guaranteed either to be a string of decimal digits
 486          * or 0[xX] followed by a string of hex digits.
 487          */
 488         if (string_len >= 1 && *s == '0') {
 489                 if (string_len >= 2  && (s[1] == 'x' || s[1] == 'X')) {
 490                         /*
 491                          * Begins with 0x or 0X, so hex.
 492                          * Guaranteed to be all hex digits following the
 493                          * prefix, so anything that's not 0-9 or a-f is
 494                          * A-F.
 495                          */
 496                         s += 2; /* skip the prefix */
 497                         string_len -= 2;
 498                         while (string_len != 0) {
 499                                 digit = *s++;
 500                                 string_len--;
 501                                 if (digit >= '0' && digit <= '9')
 502                                         digit = digit - '0';
 503                                 else if (digit >= 'a' && digit <= 'f')
 504                                         digit = digit - 'a' + 10;
 505                                 else if (digit >= 'A' && digit <= 'F')
 506                                         digit = digit - 'A' + 10;
 507                                 else {
 508                                         /*
 509                                          * Not a valid hex number.
 510                                          * Don't treat this as an error,
 511                                          * in case the caller wants to
 512                                          * interpret it as something else.
 513                                          */
 514                                         return STOULEN_NOT_HEX_NUMBER;
 515                                 }
 516
 517                                 /*
 518                                  * Check for overflow.
 519                                  */
 520                                 if (n > 0xFFFFFFFU) {
 521                                         /*
 522                                          * We have more than 28 bits of
 523                                          * number, and are about to
 524                                          * add 4 more; that won't fit
 525                                          * in 32 bits.
 526                                          */
 527                                         bpf_set_error(cstate,
 528                                             "number %.*s overflows 32 bits",
 529                                            (int)string_len, string);
 530                                         return STOULEN_ERROR;
 531                                 }
 532                                 n = (n << 4) + digit;
 533                         }
 534                 } else {
 535                         /*
 536                          * Begins with 0, but not 0x or 0X, so octal.
 537                          * Guaranteed to be all *decimal* digits following
 538                          * the prefix, so we need to catch 8 and 9 and
 539                          * report an error.
 540                          */
 541                         s += 1;
 542                         string_len -= 1;
 543                         while (string_len != 0) {
 544                                 digit = *s++;
 545                                 string_len--;
 546                                 if (digit >= '0' && digit <= '7')
 547                                         digit = digit - '0';
 548                                 else {
 549                                         /*
 550                                          * Not a valid octal number.
 551                                          * Don't treat this as an error,
 552                                          * in case the caller wants to
 553                                          * interpret it as something else.
 554                                          */
 555                                         return STOULEN_NOT_OCTAL_NUMBER;
 556                                 }
 557                                 if (n > 03777777777U) {
 558                                         /*
 559                                          * We have more than 29 bits of
 560                                          * number, and are about to add
 561                                          * 3 more; that won't fit in
 562                                          * 32 bits.
 563                                          */
 564                                         bpf_set_error(cstate,
 565                                             "number %.*s overflows 32 bits",
 566                                            (int)string_len, string);
 567                                         return STOULEN_ERROR;
 568                                 }
 569                                 n = (n << 3) + digit;
 570                         }
 571                 }
 572         } else {
 573                 /*
 574                  * Decimal.
 575                  */
 576                 while (string_len != 0) {
 577                         digit = *s++;
 578                         string_len--;
 579                         if (digit >= '0' && digit <= '9')
 580                                 digit = digit - '0';
 581                         else {
 582                                 /*
 583                                  * Not a valid decimal number.
 584                                  * Don't treat this as an error,
 585                                  * in case the caller wants to
 586                                  * interpret it as something else.
 587                                  */
 588                                 return STOULEN_NOT_DECIMAL_NUMBER;
 589                         }
 590 #define CUTOFF_DEC      (0xFFFFFFFFU / 10U)
 591 #define CUTLIM_DEC      (0xFFFFFFFFU % 10U)
 592                         if (n > CUTOFF_DEC ||
 593                             (n == CUTOFF_DEC && digit > CUTLIM_DEC)) {
 594                                 /*
 595                                  * Adding that digit will result in a
 596                                  * number that won't fit in 32 bits.
 597                                  */
 598                                 bpf_set_error(cstate,
 599                                     "number %.*s overflows 32 bits",
 600                                    (int)string_len, string);
 601                                 return STOULEN_ERROR;
 602                         }
 603                         n = (n * 10) + digit;
 604                 }
 605         }
 606
 607         *val = n;
 608         return STOULEN_OK;
 609 }
 610
 611 /*
 612  * Convert string to 32-bit unsigned integer.  Just like atoi(), but checks for
 613  * preceding 0x or 0 and uses hex or octal instead of decimal.
 614  *
 615  * On success, sets yylval->h to the value and returns NUM.
 616  * On failure, sets the BPF error string and returns LEX_ERROR, to force
 617  * the parse to stop.
 618  */
 619 static int
 620 stou(const char *yytext_arg, YYSTYPE *yylval_arg, compiler_state_t *yyextra_arg)
 621 {
 622         stoulen_ret ret;
 623
 624         ret = stoulen(yytext_arg, strlen(yytext_arg), &yylval_arg->h,
 625             yyextra_arg);
 626         switch (ret) {
 627
 628         case STOULEN_OK:
 629                 return NUM;
 630
 631         case STOULEN_NOT_OCTAL_NUMBER:
 632                 bpf_set_error(yyextra_arg, "number %s contains non-octal digit",
 633                     yytext_arg);
 634                 return LEX_ERROR;
 635
 636         case STOULEN_NOT_HEX_NUMBER:
 637                 bpf_set_error(yyextra_arg, "number %s contains non-hex digit",
 638                     yytext_arg);
 639                 return LEX_ERROR;
 640
 641         case STOULEN_NOT_DECIMAL_NUMBER:
 642                 bpf_set_error(yyextra_arg, "number %s contains non-decimal digit",
 643                     yytext_arg);
 644                 return LEX_ERROR;
 645
 646         case STOULEN_ERROR:
 647                 /* Error already set. */
 648                 return LEX_ERROR;
 649
 650         default:
 651                 /* Should not happen */
 652                 bpf_set_error(yyextra_arg, "stoulen returned %d - this should not happen", ret);
 653                 return LEX_ERROR;
 654         }
 655 }