The Tcpdump Group git mirrors - libpcap/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/libpcap/configure.in,v 1.168 2008-12-23 20:49:26 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 #
  10 # See
  11 #
  12 #       http://ftp.gnu.org/gnu/config/README
  13 #
  14 # for the URLs to use to fetch new versions of config.guess and
  15 # config.sub.
  16 #
  17
  18 AC_REVISION($Revision: 1.168 $)
  19 AC_PREREQ(2.50)
  20 AC_INIT(pcap.c)
  21
  22 AC_CANONICAL_SYSTEM
  23
  24 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  25 AC_LBL_C_INLINE
  26 AC_C___ATTRIBUTE__
  27
  28 AC_CHECK_HEADERS(sys/bitypes.h)
  29
  30 AC_CHECK_TYPE([int8_t], ,
  31         [AC_DEFINE([int8_t], [signed char],
  32         [Define to `signed char' if int8_t not defined.])],
  33         [AC_INCLUDES_DEFAULT
  34 #ifdef HAVE_SYS_BITYPES_H
  35 #include <sys/bitypes.h>
  36 #endif])
  37 AC_CHECK_TYPE([u_int8_t], ,
  38         [AC_DEFINE([u_int8_t], [unsigned char],
  39         [Define to `unsigned char' if u_int8_t not defined.])],
  40         [AC_INCLUDES_DEFAULT
  41 #ifdef HAVE_SYS_BITYPES_H
  42 #include <sys/bitypes.h>
  43 #endif])
  44 AC_CHECK_TYPE([int16_t], ,
  45         [AC_DEFINE([int16_t], [short],
  46         [Define to `short' if int16_t not defined.])]
  47         [AC_INCLUDES_DEFAULT
  48 #ifdef HAVE_SYS_BITYPES_H
  49 #include <sys/bitypes.h>
  50 #endif])
  51 AC_CHECK_TYPE([u_int16_t], ,
  52         [AC_DEFINE([u_int16_t], [unsigned short],
  53         [Define to `unsigned short' if u_int16_t not defined.])],
  54         [AC_INCLUDES_DEFAULT
  55 #ifdef HAVE_SYS_BITYPES_H
  56 #include <sys/bitypes.h>
  57 #endif])
  58 AC_CHECK_TYPE([int32_t], ,
  59         [AC_DEFINE([int32_t], [int],
  60         [Define to `int' if int32_t not defined.])],
  61         [AC_INCLUDES_DEFAULT
  62 #ifdef HAVE_SYS_BITYPES_H
  63 #include <sys/bitypes.h>
  64 #endif])
  65 AC_CHECK_TYPE([u_int32_t], ,
  66         [AC_DEFINE([u_int32_t], [unsigned int],
  67         [Define to `unsigned int' if u_int32_t not defined.])],
  68         [AC_INCLUDES_DEFAULT
  69 #ifdef HAVE_SYS_BITYPES_H
  70 #include <sys/bitypes.h>
  71 #endif])
  72 AC_CHECK_TYPE([int64_t], ,
  73         [AC_DEFINE([int64_t], [long long],
  74         [Define to `long long' if int64_t not defined.])],
  75         [AC_INCLUDES_DEFAULT
  76 #ifdef HAVE_SYS_BITYPES_H
  77 #include <sys/bitypes.h>
  78 #endif])
  79 AC_CHECK_TYPE([u_int64_t], ,
  80         [AC_DEFINE([u_int64_t], [unsigned long long],
  81         [Define to `unsigned long long' if u_int64_t not defined.])],
  82         [AC_INCLUDES_DEFAULT
  83 #ifdef HAVE_SYS_BITYPES_H
  84 #include <sys/bitypes.h>
  85 #endif])
  86
  87 #
  88 # Try to arrange for large file support.
  89 #
  90 AC_SYS_LARGEFILE
  91 AC_FUNC_FSEEKO
  92
  93 dnl
  94 dnl Even if <net/bpf.h> were, on all OSes that support BPF, fixed to
  95 dnl include <sys/ioccom.h>, and we were to drop support for older
  96 dnl releases without that fix, so that pcap-bpf.c doesn't need to
  97 dnl include <sys/ioccom.h>, the test program in "AC_LBL_FIXINCLUDES"
  98 dnl in "aclocal.m4" uses it, so we would still have to test for it
  99 dnl and set "HAVE_SYS_IOCCOM_H" if we have it, otherwise
 100 dnl "AC_LBL_FIXINCLUDES" wouldn't work on some platforms such as Solaris.
 101 dnl
 102 AC_CHECK_HEADERS(sys/ioccom.h sys/sockio.h limits.h paths.h)
 103 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
 104 #include <sys/socket.h>
 105 #include <net/if.h>])
 106 if test "$ac_cv_header_net_pfvar_h" = yes; then
 107         #
 108         # Check for various PF actions.
 109         #
 110         AC_MSG_CHECKING(whether net/pfvar.h defines PF_NAT through PF_NORDR)
 111         AC_TRY_COMPILE(
 112             [#include <sys/types.h>
 113             #include <sys/socket.h>
 114             #include <net/if.h>
 115             #include <net/pfvar.h>],
 116             [return PF_NAT+PF_NONAT+PF_BINAT+PF_NOBINAT+PF_RDR+PF_NORDR;],
 117             [
 118                 AC_MSG_RESULT(yes)
 119                 AC_DEFINE(HAVE_PF_NAT_THROUGH_PF_NORDR, 1,
 120                     [define if net/pfvar.h defines PF_NAT through PF_NORDR])
 121             ],
 122             AC_MSG_RESULT(no))
 123 fi
 124 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
 125 #include <sys/socket.h>])
 126 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
 127         #
 128         # The simple test didn't work.
 129         # Do we need to include <net/if.h> first?
 130         # Unset ac_cv_header_netinet_if_ether_h so we don't
 131         # treat the previous failure as a cached value and
 132         # suppress the next test.
 133         #
 134         AC_MSG_NOTICE([Rechecking with some additional includes])
 135         unset ac_cv_header_netinet_if_ether_h
 136         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
 137 #include <sys/socket.h>
 138 #include <netinet/in.h>
 139 struct mbuf;
 140 struct rtentry;
 141 #include <net/if.h>])
 142 fi
 143
 144 AC_LBL_FIXINCLUDES
 145
 146 AC_CHECK_FUNCS(strerror strlcpy)
 147
 148 needsnprintf=no
 149 AC_CHECK_FUNCS(vsnprintf snprintf,,
 150         [needsnprintf=yes])
 151 if test $needsnprintf = yes; then
 152         AC_LIBOBJ(snprintf)
 153 fi
 154
 155 #
 156 # Do this before checking for ether_hostton(), as it's a
 157 # "gethostbyname() -ish function".
 158 #
 159 AC_LBL_LIBRARY_NET
 160
 161 #
 162 # You are in a twisty little maze of UN*Xes, all different.
 163 # Some might not have ether_hostton().
 164 # Some might have it, but not declare it in any header file.
 165 # Some might have it, but declare it in <netinet/if_ether.h>.
 166 # Some might have it, but declare it in <netinet/ether.h>
 167 # (And some might have it but document it as something declared in
 168 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
 169 #
 170 # Before you is a C compiler.
 171 #
 172 AC_CHECK_FUNCS(ether_hostton)
 173 if test "$ac_cv_func_ether_hostton" = yes; then
 174         #
 175         # OK, we have ether_hostton().  Do we have <netinet/if_ether.h>?
 176         #
 177         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
 178                 #
 179                 # Yes.  Does it declare ether_hostton()?
 180                 #
 181                 AC_CHECK_DECL(ether_hostton,
 182                     [
 183                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_HOSTTON,,
 184                             [Define to 1 if netinet/if_ether.h declares `ether_hostton'])
 185                     ],,
 186                     [
 187 #include <sys/types.h>
 188 #include <sys/socket.h>
 189 #include <netinet/in.h>
 190 #include <arpa/inet.h>
 191 struct mbuf;
 192 struct rtentry;
 193 #include <net/if.h>
 194 #include <netinet/if_ether.h>
 195                     ])
 196         fi
 197         #
 198         # Did that succeed?
 199         #
 200         if test "$ac_cv_have_decl_ether_hostton" != yes; then
 201                 #
 202                 # No, how about <netinet/ether.h>, as on Linux?
 203                 #
 204                 AC_CHECK_HEADERS(netinet/ether.h)
 205                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 206                         #
 207                         # We have it - does it declare ether_hostton()?
 208                         # Unset ac_cv_have_decl_ether_hostton so we don't
 209                         # treat the previous failure as a cached value and
 210                         # suppress the next test.
 211                         #
 212                         unset ac_cv_have_decl_ether_hostton
 213                         AC_CHECK_DECL(ether_hostton,
 214                             [
 215                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_HOSTTON,,
 216                                     [Define to 1 if netinet/ether.h declares `ether_hostton'])
 217                             ],,
 218                             [
 219 #include <netinet/ether.h>
 220                             ])
 221                 fi
 222         fi
 223         #
 224         # Is ether_hostton() declared?
 225         #
 226         if test "$ac_cv_have_decl_ether_hostton" != yes; then
 227                 #
 228                 # No, we'll have to declare it ourselves.
 229                 # Do we have "struct ether_addr"?
 230                 #
 231                 AC_CHECK_TYPES(struct ether_addr,,,
 232                     [
 233 #include <sys/types.h>
 234 #include <sys/socket.h>
 235 #include <netinet/in.h>
 236 #include <arpa/inet.h>
 237 struct mbuf;
 238 struct rtentry;
 239 #include <net/if.h>
 240 #include <netinet/if_ether.h>
 241                     ])
 242                 AC_DEFINE(HAVE_DECL_ETHER_HOSTTON, 0,
 243                     [Define to 1 if you have the declaration of `ether_hostton', and to 0 if you
 244 don't.])
 245         else
 246                 AC_DEFINE(HAVE_DECL_ETHER_HOSTTON, 1,
 247                     [Define to 1 if you have the declaration of `ether_hostton', and to 0 if you
 248 don't.])
 249         fi
 250 fi
 251
 252 dnl to pacify those who hate protochain insn
 253 AC_MSG_CHECKING(if --disable-protochain option is specified)
 254 AC_ARG_ENABLE(protochain,
 255 AC_HELP_STRING([--disable-protochain],[disable \"protochain\" insn]))
 256 case "x$enable_protochain" in
 257 xyes)   enable_protochain=enabled       ;;
 258 xno)    enable_protochain=disabled      ;;
 259 x)      enable_protochain=enabled       ;;
 260 esac
 261
 262 if test "$enable_protochain" = "disabled"; then
 263         AC_DEFINE(NO_PROTOCHAIN,1,[do not use protochain])
 264 fi
 265 AC_MSG_RESULT(${enable_protochain})
 266
 267 #
 268 # SITA support is mutually exclusive with native capture support;
 269 # "--with-sita" selects SITA support.
 270 #
 271 AC_ARG_WITH(sita,
 272 AC_HELP_STRING([--with-sita],[include SITA support]),
 273 [
 274         if test ! "x$withval" = "xno" ; then
 275                 AC_DEFINE(SITA,1,[include ACN support])
 276                 AC_MSG_NOTICE(Enabling SITA ACN support)
 277                 V_PCAP=sita
 278                 V_FINDALLDEVS=sita
 279         fi
 280 ],
 281 [
 282 dnl
 283 dnl Not all versions of test support -c (character special) but it's a
 284 dnl better way of testing since the device might be protected. So we
 285 dnl check in our normal order using -r and then check the for the /dev
 286 dnl guys again using -c.
 287 dnl
 288 dnl XXX This could be done for cross-compiling, but for now it's not.
 289 dnl
 290 if test -z "$with_pcap" && test "$cross_compiling" = yes; then
 291         AC_MSG_ERROR(pcap type not determined when cross-compiling; use --with-pcap=...)
 292 fi
 293 AC_ARG_WITH(pcap,
 294 AC_HELP_STRING([--with-pcap=TYPE],[use packet capture TYPE]))
 295 AC_MSG_CHECKING(packet capture type)
 296 if test ! -z "$with_pcap" ; then
 297         V_PCAP="$withval"
 298 elif test -r /dev/bpf ; then
 299         #
 300         # Cloning BPF device.
 301         #
 302         V_PCAP=bpf
 303         AC_DEFINE(HAVE_CLONING_BPF,1,[define if you have a cloning BPF device])
 304 elif test -r /dev/bpf0 ; then
 305         V_PCAP=bpf
 306 elif test -r /usr/include/net/pfilt.h ; then
 307         V_PCAP=pf
 308 elif test -r /dev/enet ; then
 309         V_PCAP=enet
 310 elif test -r /dev/nit ; then
 311         V_PCAP=snit
 312 elif test -r /usr/include/sys/net/nit.h ; then
 313         V_PCAP=nit
 314 elif test -r /usr/include/linux/socket.h ; then
 315         V_PCAP=linux
 316 elif test -r /usr/include/net/raw.h ; then
 317         V_PCAP=snoop
 318 elif test -r /usr/include/odmi.h ; then
 319         #
 320         # On AIX, the BPF devices might not yet be present - they're
 321         # created the first time libpcap runs after booting.
 322         # We check for odmi.h instead.
 323         #
 324         V_PCAP=bpf
 325 elif test -c /dev/bpf0 ; then           # check again in case not readable
 326         V_PCAP=bpf
 327 elif test -r /usr/include/sys/dlpi.h ; then
 328         V_PCAP=dlpi
 329 elif test -c /dev/enet ; then           # check again in case not readable
 330         V_PCAP=enet
 331 elif test -c /dev/nit ; then            # check again in case not readable
 332         V_PCAP=snit
 333 else
 334         V_PCAP=null
 335 fi
 336 AC_MSG_RESULT($V_PCAP)
 337
 338 #
 339 # Do capture-mechanism-dependent tests.
 340 #
 341 case "$V_PCAP" in
 342 dlpi)
 343         #
 344         # Checks to see if Solaris has the public libdlpi(3LIB) library.
 345         # Note: The existence of /usr/include/libdlpi.h does not mean it is the
 346         # public libdlpi(3LIB) version. Before libdlpi was made public, a
 347         # private version also existed, which did not have the same APIs.
 348         # Due to a gcc bug, the default search path for 32-bit libraries does
 349         # not include /lib, we add it explicitly here.
 350         # [http://bugs.opensolaris.org/view_bug.do?bug_id=6619485].
 351         # Also, due to the bug above applications that link to libpcap with
 352         # libdlpi will have to add "-L/lib" option to "configure".
 353         #
 354         saved_ldflags=$LDFLAGS
 355         LDFLAGS="$LIBS -L/lib"
 356         AC_CHECK_LIB(dlpi, dlpi_walk,
 357                 LIBS="-ldlpi $LIBS"
 358                 V_PCAP=libdlpi
 359                 AC_DEFINE(HAVE_LIBDLPI,1,[if libdlpi exists]),
 360                 V_PCAP=dlpi)
 361         LDFLAGS=$saved_ldflags
 362
 363         #
 364         # Checks whether <sys/dlpi.h> is usable, to catch weird SCO
 365         # versions of DLPI.
 366         #
 367         AC_MSG_CHECKING(whether <sys/dlpi.h> is usable)
 368         AC_CACHE_VAL(ac_cv_sys_dlpi_usable,
 369                 AC_TRY_COMPILE(
 370                     [
 371                         #include <sys/types.h>
 372                         #include <sys/time.h>
 373                         #include <sys/dlpi.h>
 374                     ],
 375                     [int i = DL_PROMISC_PHYS;],
 376                     ac_cv_sys_dlpi_usable=yes,
 377                     ac_cv_sys_dlpi_usable=no))
 378         AC_MSG_RESULT($ac_cv_sys_dlpi_usable)
 379         if test $ac_cv_sys_dlpi_usable = no ; then
 380                 AC_MSG_ERROR(<sys/dlpi.h> is not usable on this system; it probably has a non-standard DLPI)
 381         fi
 382
 383         #
 384         # Check whether we have a /dev/dlpi device or have multiple devices.
 385         #
 386         AC_MSG_CHECKING(for /dev/dlpi device)
 387         if test -c /dev/dlpi ; then
 388                 AC_MSG_RESULT(yes)
 389                 AC_DEFINE(HAVE_DEV_DLPI, 1, [define if you have a /dev/dlpi])
 390         else
 391                 AC_MSG_RESULT(no)
 392                 dir="/dev/dlpi"
 393                 AC_MSG_CHECKING(for $dir directory)
 394                 if test -d $dir ; then
 395                         AC_MSG_RESULT(yes)
 396                         AC_DEFINE_UNQUOTED(PCAP_DEV_PREFIX, "$dir", [/dev/dlpi directory])
 397                 else
 398                         AC_MSG_RESULT(no)
 399                 fi
 400         fi
 401
 402         #
 403         # This check is for Solaris with DLPI support for passive modes.
 404         # See dlpi(7P) for more details.
 405         #
 406         AC_LBL_DL_PASSIVE_REQ_T
 407         ;;
 408
 409 linux)
 410         AC_MSG_CHECKING(Linux kernel version)
 411         if test "$cross_compiling" = yes; then
 412                 AC_CACHE_VAL(ac_cv_linux_vers,
 413                     ac_cv_linux_vers=unknown)
 414         else
 415                 AC_CACHE_VAL(ac_cv_linux_vers,
 416                     ac_cv_linux_vers=`uname -r 2>&1 | \
 417                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
 418         fi
 419         AC_MSG_RESULT($ac_cv_linux_vers)
 420         if test $ac_cv_linux_vers = unknown ; then
 421                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
 422         fi
 423         if test $ac_cv_linux_vers -lt 2 ; then
 424                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
 425         fi
 426
 427         #
 428         # Do we have the wireless extensions?
 429         #
 430         AC_CHECK_HEADERS(linux/wireless.h, [], [],
 431         [
 432 #include <sys/socket.h>
 433 #include <linux/if.h>
 434 #include <linux/types.h>
 435         ])
 436
 437         #
 438         # Do we have libnl?
 439         #
 440         AC_ARG_WITH(libnl,
 441         AC_HELP_STRING([--without-libnl],[disable libnl support @<:@default=yes, on Linux, if present@:>@]),
 442                 with_libnl=$withval,,)
 443
 444         if test x$with_libnl != xno ; then
 445                 AC_CHECK_LIB(nl, nl_handle_alloc,
 446                         LIBS="-lnl $LIBS"
 447                         AC_DEFINE(HAVE_LIBNL,1,[if libnl exists]),
 448                         if test x$with_libnl = xyes ; then
 449                                 AC_MSG_ERROR([libnl support requested but libnl not found])
 450                         fi
 451                 )
 452         fi
 453
 454         AC_LBL_TPACKET_STATS
 455         AC_LBL_LINUX_TPACKET_AUXDATA_TP_VLAN_TCI
 456         ;;
 457
 458 bpf)
 459         #
 460         # Check whether we have the *BSD-style ioctls.
 461         #
 462         AC_CHECK_HEADERS(net/if_media.h)
 463
 464         AC_MSG_CHECKING(whether the system supports zerocopy BPF)
 465         AC_TRY_COMPILE(
 466             [#include <sys/socket.h>
 467             #include <sys/ioctl.h>
 468             #include <net/if.h>
 469             #include <net/bpf.h>],
 470             [return (BIOCROTZBUF + BPF_BUFMODE_ZBUF);],
 471             [
 472                 AC_MSG_RESULT(yes)
 473                 AC_DEFINE(HAVE_ZEROCOPY_BPF, 1,
 474                 [define if the system supports zerocopy BPF])
 475             ],
 476             AC_MSG_RESULT(no))
 477         ;;
 478
 479 dag)
 480         V_DEFS="$V_DEFS -DDAG_ONLY"
 481         ;;
 482
 483 septel)
 484         V_DEFS="$V_DEFS -DSEPTEL_ONLY"
 485         ;;
 486
 487 null)
 488         AC_MSG_WARN(cannot determine packet capture interface)
 489         AC_MSG_WARN((see the INSTALL doc for more info))
 490         ;;
 491 esac
 492
 493 dnl
 494 dnl Now figure out how we get a list of interfaces and addresses,
 495 dnl if we support capturing.  Don't bother if we don't support
 496 dnl capturing.
 497 dnl
 498 if test "$V_PCAP" = null
 499 then
 500         #
 501         # We can't capture, so we can't open any capture
 502         # devices, so we won't return any interfaces.
 503         #
 504         V_FINDALLDEVS=null
 505 else
 506         AC_CHECK_FUNC(getifaddrs,[
 507                 #
 508                 # We have "getifaddrs()"; make sure we have <ifaddrs.h>
 509                 # as well, just in case some platform is really weird.
 510                 #
 511                 AC_CHECK_HEADER(ifaddrs.h,[
 512                     #
 513                     # We have the header, so we use "getifaddrs()" to
 514                     # get the list of interfaces.
 515                     #
 516                     V_FINDALLDEVS=getad
 517                 ],[
 518                     #
 519                     # We don't have the header - give up.
 520                     # XXX - we could also fall back on some other
 521                     # mechanism, but, for now, this'll catch this
 522                     # problem so that we can at least try to figure
 523                     # out something to do on systems with "getifaddrs()"
 524                     # but without "ifaddrs.h", if there is something
 525                     # we can do on those systems.
 526                     #
 527                     AC_MSG_ERROR([Your system has getifaddrs() but doesn't have a usable <ifaddrs.h>.])
 528                 ])
 529         ],[
 530                 #
 531                 # Well, we don't have "getifaddrs()", so we have to use
 532                 # some other mechanism; determine what that mechanism is.
 533                 #
 534                 # The first thing we use is the type of capture mechanism,
 535                 # which is somewhat of a proxy for the OS we're using.
 536                 #
 537                 case "$V_PCAP" in
 538
 539                 dlpi|libdlpi)
 540                         AC_CHECK_HEADERS(sys/bufmod.h sys/dlpi_ext.h)
 541                         #
 542                         # This might be Solaris 8 or later, with
 543                         # SIOCGLIFCONF, or it might be some other OS
 544                         # or some older version of Solaris, with
 545                         # just SIOCGIFCONF.
 546                         #
 547                         AC_MSG_CHECKING(whether we have SIOCGLIFCONF)
 548                         AC_CACHE_VAL(ac_cv_lbl_have_siocglifconf,
 549                             AC_TRY_COMPILE(
 550                                 [#include <sys/param.h>
 551                                 #include <sys/file.h>
 552                                 #include <sys/ioctl.h>
 553                                 #include <sys/socket.h>
 554                                 #include <sys/sockio.h>],
 555                                 [ioctl(0, SIOCGLIFCONF, (char *)0);],
 556                                 ac_cv_lbl_have_siocglifconf=yes,
 557                                 ac_cv_lbl_have_siocglifconf=no))
 558                         AC_MSG_RESULT($ac_cv_lbl_have_siocglifconf)
 559                         if test $ac_cv_lbl_have_siocglifconf = yes ; then
 560                                 V_FINDALLDEVS=glifc
 561                         else
 562                                 V_FINDALLDEVS=gifc
 563                         fi
 564                         #
 565                         # Needed for common functions used by pcap-[dlpi,libdlpi].c
 566                         #
 567                         SSRC="dlpisubs.c"
 568                         ;;
 569
 570                 *)
 571                         #
 572                         # Assume we just have SIOCGIFCONF.
 573                         # (XXX - on at least later Linux kernels, there's
 574                         # another mechanism, and we should be using that
 575                         # instead.)
 576                         #
 577                         V_FINDALLDEVS=gifc
 578                         ;;
 579                 esac])
 580 fi
 581 ])
 582
 583 AC_MSG_CHECKING(for socklen_t)
 584 AC_TRY_COMPILE([
 585         #include <sys/types.h>
 586         #include <sys/socket.h>
 587         ],
 588         [ socklen_t x; ],
 589         have_socklen_t=yes,
 590         have_socklen_t=no)
 591 if test "x$have_socklen_t" = "xyes"; then
 592         AC_DEFINE(HAVE_SOCKLEN_T, 1, [define if socklen_t is defined])
 593 fi
 594 AC_MSG_RESULT($have_socklen_t)
 595
 596 AC_ARG_ENABLE(ipv6,
 597 AC_HELP_STRING([--enable-ipv6],[build IPv6-capable version @<:@default=yes, if getaddrinfo available@:>@]),
 598     [],
 599     [enable_ipv6=ifavailable])
 600 if test "$enable_ipv6" != "no"; then
 601         AC_CHECK_FUNC(getaddrinfo,
 602             [
 603                 AC_DEFINE(INET6,1,[IPv6])
 604             ],
 605             [
 606                 if test "$enable_ipv6" != "ifavailable"; then
 607                         AC_MSG_FAILURE([--enable-ipv6 was given, but getaddrinfo isn't available])
 608                 fi
 609             ])
 610 fi
 611
 612 AC_MSG_CHECKING(whether to build optimizer debugging code)
 613 AC_ARG_ENABLE(optimizer-dbg,
 614 AC_HELP_STRING([--enable-optimizer-dbg],[build optimizer debugging code]))
 615 if test "$enable_optimizer_dbg" = "yes"; then
 616         AC_DEFINE(BDEBUG,1,[Enable optimizer debugging])
 617 fi
 618 AC_MSG_RESULT(${enable_optimizer_dbg-no})
 619
 620 AC_MSG_CHECKING(whether to build parser debugging code)
 621 AC_ARG_ENABLE(yydebug,
 622 AC_HELP_STRING([--enable-yydebug],[build parser debugging code]))
 623 if test "$enable_yydebug" = "yes"; then
 624         AC_DEFINE(YYDEBUG,1,[Enable parser debugging])
 625 fi
 626 AC_MSG_RESULT(${enable_yydebug-no})
 627
 628 AC_MSG_CHECKING(whether we have /proc/net/dev)
 629 if test -r /proc/net/dev ; then
 630         ac_cv_lbl_proc_net_dev=yes
 631 else
 632         ac_cv_lbl_proc_net_dev=no
 633 fi
 634 if test $ac_cv_lbl_proc_net_dev = yes; then
 635         AC_DEFINE(HAVE_PROC_NET_DEV, 1, [define if you have a /proc/net/dev])
 636 fi
 637 AC_MSG_RESULT($ac_cv_lbl_proc_net_dev)
 638
 639 # Check for Endace DAG card support.
 640 AC_ARG_WITH([dag],
 641 AC_HELP_STRING([--with-dag@<:@=DIR@:>@],[include Endace DAG support @<:@"yes", "no" or DIR; default="yes" on BSD and Linux if present@:>@]),
 642 [
 643         if test "$withval" = no
 644         then
 645                 # User doesn't want DAG support.
 646                 want_dag=no
 647         elif test "$withval" = yes
 648         then
 649                 # User wants DAG support but hasn't specified a directory.
 650                 want_dag=yes
 651         else
 652                 # User wants DAG support and has specified a directory, so use the provided value.
 653                 want_dag=yes
 654                 dag_root=$withval
 655         fi
 656 ],[
 657         #
 658         # Use DAG API if present, otherwise don't
 659         #
 660         want_dag=ifpresent
 661 ])
 662
 663 AC_ARG_WITH([dag-includes],
 664 AC_HELP_STRING([--with-dag-includes=DIR],[Endace DAG include directory]),
 665 [
 666         # User wants DAG support and has specified a header directory, so use the provided value.
 667         want_dag=yes
 668         dag_include_dir=$withval
 669 ],[])
 670
 671 AC_ARG_WITH([dag-libraries],
 672 AC_HELP_STRING([--with-dag-libraries=DIR],[Endace DAG library directory]),
 673 [
 674         # User wants DAG support and has specified a library directory, so use the provided value.
 675         want_dag=yes
 676         dag_lib_dir=$withval
 677 ],[])
 678
 679 case "$V_PCAP" in
 680 linux|bpf|dag)
 681         #
 682         # We support the DAG API if we're on Linux or BSD, or if we're
 683         # building a DAG-only libpcap.
 684         #
 685         ;;
 686 *)
 687         #
 688         # If the user explicitly requested DAG, tell them it's not
 689         # supported.
 690         #
 691         # If they expressed no preference, don't include it.
 692         #
 693         if test $want_dag = yes; then
 694                 AC_MSG_ERROR([DAG support is only available with 'linux' 'bpf' and 'dag' packet capture types])
 695         elif test $want_dag = yes; then
 696                 want_dag=no
 697         fi
 698         ;;
 699 esac
 700
 701 ac_cv_lbl_dag_api=no
 702 if test "$want_dag" != no; then
 703
 704         AC_MSG_CHECKING([whether we have DAG API headers])
 705
 706         # If necessary, set default paths for DAG API headers and libraries.
 707         if test -z "$dag_root"; then
 708             dag_root=/usr/local
 709         fi
 710
 711         if test -z "$dag_include_dir"; then
 712                 dag_include_dir="$dag_root/include"
 713         fi
 714
 715         if test -z "$dag_lib_dir"; then
 716             dag_lib_dir="$dag_root/lib"
 717         fi
 718
 719         if test -z "$dag_tools_dir"; then
 720             dag_tools_dir="$dag_root/tools"
 721                 fi
 722
 723         if test -r $dag_include_dir/dagapi.h; then
 724                 ac_cv_lbl_dag_api=yes
 725         fi
 726         AC_MSG_RESULT([$ac_cv_lbl_dag_api ($dag_include_dir)])
 727 fi
 728
 729 if test $ac_cv_lbl_dag_api = yes; then
 730
 731         AC_MSG_CHECKING([dagapi.o])
 732         dagapi_obj=no
 733         if test -r $dag_tools_dir/dagapi.o; then
 734                 # 2.4.x.
 735                 dagapi_obj=$dag_tools_dir/dagapi.o
 736         elif test -r $dag_lib_dir/dagapi.o; then
 737                 # 2.5.x.
 738                 dagapi_obj=$dag_lib_dir/dagapi.o
 739         elif test -r $dag_lib_dir/libdag.a; then
 740                 # 2.5.x.
 741                 ar x $dag_lib_dir/libdag.a dagapi.o 2>/dev/null
 742                 if test -r ./dagapi.o; then
 743                     dagapi_obj=./dagapi.o
 744                 else
 745                     ar x $dag_lib_dir/libdag.a libdag_la-dagapi.o 2>/dev/null
 746                     if test -r ./libdag_la-dagapi.o; then
 747                        dagapi_obj=./libdag_la-dagapi.o
 748                     fi
 749                 fi
 750         fi
 751
 752         if test $dagapi_obj = no; then
 753                 AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_tools_dir  $dag_lib_dir/libdag.a)])
 754                         ac_cv_lbl_dag_api=no
 755         else
 756                 AC_MSG_RESULT([yes ($dagapi_obj)])
 757         fi
 758 fi
 759
 760 if test $ac_cv_lbl_dag_api = yes; then
 761
 762         AC_MSG_CHECKING([dagopts.o])
 763         dagopts_obj=no
 764         if test -r $dag_tools_dir/dagopts.o; then
 765                 # 2.4.x.
 766                 dagopts_obj=$dag_tools_dir/dagopts.o
 767         elif test -r $dag_lib_dir/dagopts.o; then
 768                 # 2.5.x.
 769                 dagopts_obj=$dag_lib_dir/dagopts.o
 770         elif test -r $dag_lib_dir/libdag.a; then
 771                 # 2.5.x.
 772                 ar x $dag_lib_dir/libdag.a dagopts.o 2>/dev/null
 773                 if test -r ./dagopts.o; then
 774                     dagopts_obj=./dagopts.o
 775                 else
 776                     ar x $dag_lib_dir/libdag.a libdag_la-dagopts.o 2>/dev/null
 777                     if test -r ./libdag_la-dagopts.o; then
 778                        dagopts_obj=./libdag_la-dagopts.o
 779                     fi
 780                 fi
 781         fi
 782
 783         if test $dagopts_obj = no; then
 784                 AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_tools_dir  $dag_lib_dir/libdag.a)])
 785                 ac_cv_lbl_dag_api=no
 786         else
 787                 AC_MSG_RESULT([yes ($dagopts_obj)])
 788         fi
 789 fi
 790
 791 if test $ac_cv_lbl_dag_api = yes; then
 792         # Under 2.5.x only we need to add dagreg.o.
 793         if test -r $dag_include_dir/dagreg.h; then
 794                 AC_MSG_CHECKING([dagreg.o])
 795                 dagreg_obj=no
 796                 if test -r $dag_lib_dir/dagreg.o; then
 797                         # Object file is ready and waiting.
 798                         dagreg_obj=$dag_lib_dir/dagreg.o
 799                 elif test -r $dag_lib_dir/libdag.a; then
 800                         # Extract from libdag.a.
 801                         ar x $dag_lib_dir/libdag.a dagreg.o 2>/dev/null
 802                         if test -r ./dagreg.o; then
 803                                 dagreg_obj=./dagreg.o
 804                         else
 805                                 ar x $dag_lib_dir/libdag.a libdag_la-dagreg.o 2>/dev/null
 806                                 if test -r ./libdag_la-dagreg.o; then
 807                                    dagreg_obj=./libdag_la-dagreg.o
 808                                 fi
 809                         fi
 810                 fi
 811
 812                 if test $dagreg_obj = no; then
 813                         AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_lib_dir/libdag.a)])
 814                         ac_cv_lbl_dag_api=no
 815                 else
 816                         AC_MSG_RESULT([yes ($dagreg_obj)])
 817                 fi
 818         fi
 819 fi
 820
 821 if test $ac_cv_lbl_dag_api = yes; then
 822         V_INCLS="$V_INCLS -I$dag_include_dir"
 823         ADDLARCHIVEOBJS="$ADDLARCHIVEOBJS $dagapi_obj $dagopts_obj $dagreg_obj"
 824         if test $V_PCAP != dag ; then
 825                  SSRC="pcap-dag.c"
 826         fi
 827
 828         # See if we can find a general version string.
 829         # Don't need to save and restore LIBS to prevent -ldag being
 830         # included if there's a found-action (arg 3).
 831         saved_ldflags=$LDFLAGS
 832         LDFLAGS="-L$dag_lib_dir"
 833         AC_CHECK_LIB([dag], [dag_attach_stream], [dag_streams="1"], [dag_streams="0"])
 834         AC_CHECK_LIB([dag],[dag_get_erf_types], [
 835                 AC_DEFINE(HAVE_DAG_GET_ERF_TYPES, 1, [define if you have dag_get_erf_types()])])
 836         AC_CHECK_LIB([dag],[dag_get_stream_erf_types], [
 837                 AC_DEFINE(HAVE_DAG_GET_STREAM_ERF_TYPES, 1, [define if you have dag_get_stream_erf_types()])])
 838         LDFLAGS=$saved_ldflags
 839
 840         if test "$dag_streams" = 1; then
 841                 AC_DEFINE(HAVE_DAG_STREAMS_API, 1, [define if you have streams capable DAG API])
 842                 LIBS="$LIBS -ldag"
 843         fi
 844
 845         AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
 846 fi
 847
 848 AC_MSG_CHECKING(whether we have the DAG API)
 849
 850 if test $ac_cv_lbl_dag_api = no; then
 851         AC_MSG_RESULT(no)
 852         if test "$want_dag" = yes; then
 853                 # User wanted DAG support but we couldn't find it.
 854                 AC_MSG_ERROR([DAG API requested, but not found at $dag_root: use --without-dag])
 855         fi
 856
 857         if test "$V_PCAP" = dag; then
 858                 # User requested "dag" capture type but the DAG API wasn't
 859                 # found.
 860                 AC_MSG_ERROR([Specifying the capture type as "dag" requires the DAG API to be present; use the --with-dag options to specify the location. (Try "./configure --help" for more information.)])
 861         fi
 862 else
 863         AC_MSG_RESULT(yes)
 864 fi
 865
 866 AC_ARG_WITH(septel,
 867 AC_HELP_STRING([--with-septel@<:@=DIR@:>@],[include Septel support (located in directory DIR, if supplied).  @<:@default=yes, on Linux, if present@:>@]),
 868 [
 869         if test "$withval" = no
 870         then
 871                 want_septel=no
 872         elif test "$withval" = yes
 873         then
 874                 want_septel=yes
 875                 septel_root=
 876         else
 877                 want_septel=yes
 878                 septel_root=$withval
 879         fi
 880 ],[
 881         #
 882         # Use Septel API if present, otherwise don't
 883         #
 884         want_septel=ifpresent
 885         septel_root=./../septel
 886 ])
 887 ac_cv_lbl_septel_api=no
 888 case "$V_PCAP" in
 889 linux|septel)
 890         #
 891         # We support the Septel API if we're on Linux, or if we're building
 892         # a Septel-only libpcap.
 893         #
 894         ;;
 895 *)
 896         #
 897         # If the user explicitly requested Septel, tell them it's not
 898         # supported.
 899         #
 900         # If they expressed no preference, don't include it.
 901         #
 902         if test $want_septel = yes; then
 903                 AC_MSG_ERROR(Septel support only available with 'linux' and 'septel' packet capture types)
 904         elif test $want_septel = yes; then
 905                 want_septel=no
 906         fi
 907         ;;
 908 esac
 909
 910 if test "$with_septel" != no; then
 911         AC_MSG_CHECKING(whether we have Septel API)
 912
 913         if test -z "$septel_root"; then
 914                 septel_root=$srcdir/../septel
 915         fi
 916
 917         septel_tools_dir="$septel_root"
 918         septel_include_dir="$septel_root/INC"
 919
 920         ac_cv_lbl_septel_api=no
 921         if test -r "$septel_include_dir/msg.h"; then
 922                 V_INCLS="$V_INCLS -I$septel_include_dir"
 923                 ADDLOBJS="$ADDLOBJS $septel_tools_dir/asciibin.o $septel_tools_dir/bit2byte.o $septel_tools_dir/confirm.o $septel_tools_dir/fmtmsg.o $septel_tools_dir/gct_unix.o $septel_tools_dir/hqueue.o $septel_tools_dir/ident.o $septel_tools_dir/mem.o $septel_tools_dir/pack.o $septel_tools_dir/parse.o $septel_tools_dir/pool.o $septel_tools_dir/sdlsig.o $septel_tools_dir/strtonum.o $septel_tools_dir/timer.o $septel_tools_dir/trace.o"
 924                 ADDLARCHIVEOBJS="$ADDLARCHIVEOBJS $septel_tools_dir/asciibin.o $septel_tools_dir/bit2byte.o $septel_tools_dir/confirm.o $septel_tools_dir/fmtmsg.o $septel_tools_dir/gct_unix.o $septel_tools_dir/hqueue.o $septel_tools_dir/ident.o $septel_tools_dir/mem.o $septel_tools_dir/pack.o $septel_tools_dir/parse.o $septel_tools_dir/pool.o $septel_tools_dir/sdlsig.o $septel_tools_dir/strtonum.o $septel_tools_dir/timer.o $septel_tools_dir/trace.o"
 925
 926                 if test "$V_PCAP" != septel ; then
 927                          SSRC="pcap-septel.c"
 928                 fi
 929                 ac_cv_lbl_septel_api=yes
 930         fi
 931
 932         AC_MSG_RESULT($ac_cv_lbl_septel_api)
 933         if test $ac_cv_lbl_septel_api = no; then
 934                 if test "$want_septel" = yes; then
 935                         AC_MSG_ERROR(Septel API not found under directory $septel_root; use --without-septel)
 936                 fi
 937         else
 938                 AC_DEFINE(HAVE_SEPTEL_API, 1, [define if you have a Septel API])
 939         fi
 940 fi
 941
 942 if test "$V_PCAP" = septel -a "$ac_cv_lbl_septel_api" = no; then
 943         AC_MSG_ERROR(Specifying the capture type as 'septel' requires the Septel API to be present; use --with-septel=DIR)
 944 fi
 945
 946
 947 AC_LBL_LEX_AND_YACC(V_LEX, V_YACC, pcap_)
 948 if test "$V_LEX" = lex ; then
 949 # Some versions of lex can't handle the definitions section of scanner.l .
 950 # Try lexing it and complain if it can't deal.
 951         AC_CACHE_CHECK([for capable lex], tcpdump_cv_capable_lex,
 952                 if lex -t scanner.l > /dev/null 2>&1; then
 953                         tcpdump_cv_capable_lex=yes
 954                 else
 955                         tcpdump_cv_capable_lex=insufficient
 956                 fi)
 957         if test $tcpdump_cv_capable_lex = insufficient ; then
 958                 AC_MSG_ERROR([Your operating system's lex is insufficient to compile
 959  libpcap.  flex is a lex replacement that has many advantages, including
 960  being able to compile libpcap.  For more information, see
 961  http://www.gnu.org/software/flex/flex.html .])
 962         fi
 963 fi
 964
 965 #
 966 # Assume, by default, no support for shared libraries and V7/BSD convention
 967 # for man pages (file formats in section 5, miscellaneous info in section 7).
 968 # Individual cases can override this.
 969 #
 970 DYEXT="none"
 971 MAN_FILE_FORMATS=5
 972 MAN_MISC_INFO=7
 973 case "$host_os" in
 974
 975 aix*)
 976         dnl Workaround to enable certain features
 977         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 978
 979         #
 980         # AIX makes it fun to build shared and static libraries,
 981         # because they're *both* ".a" archive libraries.  We
 982         # build the static library for the benefit of the traditional
 983         # scheme of building libpcap and tcpdump in subdirectories of
 984         # the same directory, with tcpdump statically linked with the
 985         # libpcap in question, but we also build a shared library as
 986         # "libpcap.shareda" and install *it*, rather than the static
 987         # library, as "libpcap.a".
 988         #
 989         DYEXT="shareda"
 990
 991         case "$V_PCAP" in
 992
 993         dlpi)
 994                 #
 995                 # If we're using DLPI, applications will need to
 996                 # use /lib/pse.exp if present, as we use the
 997                 # STREAMS routines.
 998                 #
 999                 pseexe="/lib/pse.exp"
1000                 AC_MSG_CHECKING(for $pseexe)
1001                 if test -f $pseexe ; then
1002                         AC_MSG_RESULT(yes)
1003                         LIBS="-I:$pseexe"
1004                 fi
1005                 ;;
1006
1007         bpf)
1008                 #
1009                 # If we're using BPF, we need "-lodm" and "-lcfg", as
1010                 # we use them to load the BPF module.
1011                 #
1012                 LIBS="-lodm -lcfg"
1013                 ;;
1014         esac
1015         ;;
1016
1017 darwin*)
1018         DYEXT="dylib"
1019         V_CCOPT="$V_CCOPT -fno-common"
1020         ;;
1021
1022 hpux9*)
1023         AC_DEFINE(HAVE_HPUX9,1,[on HP-UX 9.x])
1024
1025         #
1026         # Use System V conventions for man pages.
1027         #
1028         MAN_FILE_FORMATS=4
1029         MAN_MISC_INFO=5
1030         ;;
1031
1032 hpux10.0*)
1033
1034         #
1035         # Use System V conventions for man pages.
1036         #
1037         MAN_FILE_FORMATS=4
1038         MAN_MISC_INFO=5
1039         ;;
1040
1041 hpux10.1*)
1042
1043         #
1044         # Use System V conventions for man pages.
1045         #
1046         MAN_FILE_FORMATS=4
1047         MAN_MISC_INFO=5
1048         ;;
1049
1050 hpux*)
1051         dnl HPUX 10.20 and above is similar to HPUX 9, but
1052         dnl not the same....
1053         dnl
1054         dnl XXX - DYEXT should be set to "sl" if this is building
1055         dnl for 32-bit PA-RISC, but should be left as "so" for
1056         dnl 64-bit PA-RISC or, I suspect, IA-64.
1057         AC_DEFINE(HAVE_HPUX10_20_OR_LATER,1,[on HP-UX 10.20 or later])
1058         if test "`uname -m`" = "ia64"; then
1059                 DYEXT="so"
1060         else
1061                 DYEXT="sl"
1062         fi
1063
1064         #
1065         # "-b" builds a shared library; "+h" sets the soname.
1066         #
1067         SHLIB_OPT="-b"
1068         SONAME_OPT="+h"
1069
1070         #
1071         # Use System V conventions for man pages.
1072         #
1073         MAN_FILE_FORMATS=4
1074         MAN_MISC_INFO=5
1075         ;;
1076
1077 irix*)
1078         #
1079         # Use System V conventions for man pages.
1080         #
1081         MAN_FILE_FORMATS=4
1082         MAN_MISC_INFO=5
1083         ;;
1084
1085 linux*|freebsd*|netbsd*|openbsd*|dragonfly*)
1086         DYEXT="so"
1087
1088         #
1089         # Compiler assumed to be GCC; run-time linker may require a -R
1090         # flag.
1091         #
1092         if test "$libdir" != "/usr/lib"; then
1093                 V_RFLAGS=-Wl,-R$libdir
1094         fi
1095         ;;
1096
1097 osf*)
1098         DYEXT="so"
1099
1100         #
1101         # Use System V conventions for man pages.
1102         #
1103         MAN_FILE_FORMATS=4
1104         MAN_MISC_INFO=5
1105         ;;
1106
1107 sinix*)
1108         AC_MSG_CHECKING(if SINIX compiler defines sinix)
1109         AC_CACHE_VAL(ac_cv_cc_sinix_defined,
1110                 AC_TRY_COMPILE(
1111                     [],
1112                     [int i = sinix;],
1113                     ac_cv_cc_sinix_defined=yes,
1114                     ac_cv_cc_sinix_defined=no))
1115             AC_MSG_RESULT($ac_cv_cc_sinix_defined)
1116             if test $ac_cv_cc_sinix_defined = no ; then
1117                     AC_DEFINE(sinix,1,[on sinix])
1118             fi
1119         ;;
1120
1121 solaris*)
1122         AC_DEFINE(HAVE_SOLARIS,1,[On solaris])
1123
1124         DYEXT="so"
1125         #
1126         # Use System V conventions for man pages.
1127         #
1128         MAN_FILE_FORMATS=4
1129         MAN_MISC_INFO=5
1130         ;;
1131 esac
1132
1133 AC_PROG_RANLIB
1134
1135 AC_LBL_DEVEL(V_CCOPT)
1136
1137 AC_LBL_SOCKADDR_SA_LEN
1138
1139 AC_LBL_SOCKADDR_STORAGE
1140
1141 AC_LBL_HP_PPA_INFO_T_DL_MODULE_ID_1
1142
1143 AC_LBL_UNALIGNED_ACCESS
1144
1145 #
1146 # Makefile.in includes rules to generate version.h, so we assume
1147 # that it will be generated if autoconf is used.
1148 #
1149 AC_DEFINE(HAVE_VERSION_H, 1, [define if version.h is generated in the build procedure])
1150
1151 rm -f net
1152 ln -s ${srcdir}/bpf/net net
1153
1154 AC_SUBST(V_CCOPT)
1155 AC_SUBST(V_DEFS)
1156 AC_SUBST(V_FINDALLDEVS)
1157 AC_SUBST(V_INCLS)
1158 AC_SUBST(V_LEX)
1159 AC_SUBST(V_PCAP)
1160 AC_SUBST(V_SHLIB_CMD)
1161 AC_SUBST(V_SHLIB_OPT)
1162 AC_SUBST(V_SONAME_OPT)
1163 AC_SUBST(V_RPATH_OPT)
1164 AC_SUBST(V_YACC)
1165 AC_SUBST(ADDLOBJS)
1166 AC_SUBST(ADDLARCHIVEOBJS)
1167 AC_SUBST(SSRC)
1168 AC_SUBST(DYEXT)
1169 AC_SUBST(MAN_FILE_FORMATS)
1170 AC_SUBST(MAN_MISC_INFO)
1171
1172 dnl check for USB sniffing support
1173 AC_MSG_CHECKING(for USB sniffing support)
1174 case "$host_os" in
1175 linux*)
1176        AC_DEFINE(PCAP_SUPPORT_USB, 1, [target host supports USB sniffing])
1177        USB_SRC=pcap-usb-linux.c
1178        AC_MSG_RESULT(yes)
1179        ac_usb_dev_name=`udevinfo -q name -p /sys/class/usb_device/usbmon 2>/dev/null`
1180        if test $? -ne 0 ; then
1181                ac_usb_dev_name="usbmon"
1182        fi
1183        AC_DEFINE_UNQUOTED(LINUX_USB_MON_DEV, "/dev/$ac_usb_dev_name", [path for device for USB sniffing])
1184        AC_MSG_NOTICE(Device for USB sniffing is /dev/$ac_usb_dev_name)
1185        AC_CHECK_HEADERS(linux/usbdevice_fs.h)
1186        if test "$ac_cv_header_linux_usbdevice_fs_h" = yes; then
1187          #
1188          # OK, does it define bRequestType?  Older versions of the kernel
1189          # define fields with names like "requesttype, "request", and
1190          # "value", rather than "bRequestType", "bRequest", and
1191          # "wValue".
1192          #
1193          AC_MSG_CHECKING(if usbdevfs_ctrltransfer struct has bRequestType member)
1194          AC_CACHE_VAL(ac_cv_usbdevfs_ctrltransfer_has_bRequestType,
1195            AC_TRY_COMPILE([
1196 AC_INCLUDES_DEFAULT
1197 #ifdef HAVE_SYS_BITYPES_H
1198 #include <sys/bitypes.h>
1199 #endif
1200 #            include <linux/usbdevice_fs.h>],
1201              [u_int i = sizeof(((struct usbdevfs_ctrltransfer *)0)->bRequestType)],
1202              ac_cv_usbdevfs_ctrltransfer_has_bRequestType=yes,
1203              ac_cv_usbdevfs_ctrltransfer_has_bRequestType=no))
1204          AC_MSG_RESULT($ac_cv_usbdevfs_ctrltransfer_has_bRequestType)
1205          if test $ac_cv_usbdevfs_ctrltransfer_has_bRequestType = yes ; then
1206             AC_DEFINE(HAVE_USBDEVFS_CTRLTRANSFER_BREQUESTTYPE,1,
1207               [if struct usbdevfs_ctrltransfer has bRequestType])
1208          fi
1209        fi
1210        ;;
1211 *)
1212        AC_MSG_RESULT(no)
1213        ;;
1214 esac
1215 AC_SUBST(PCAP_SUPPORT_USB)
1216 AC_SUBST(USB_SRC)
1217
1218 AC_ARG_ENABLE([bluetooth],
1219 [AC_HELP_STRING([--enable-bluetooth],[enable bluetooth support @<:@default=yes, if support available@:>@])],
1220 ,enable_bluetooth=yes)
1221
1222 if test "x$enable_bluetooth" != "xno" ; then
1223         dnl check for bluetooth sniffing support
1224         case "$host_os" in
1225         linux*)
1226                AC_CHECK_HEADER(bluetooth/bluetooth.h,
1227                 [
1228                   AC_DEFINE(PCAP_SUPPORT_BT, 1, [target host supports Bluetooth sniffing])
1229                   BT_SRC=pcap-bt-linux.c
1230                   AC_MSG_NOTICE(Bluetooth sniffing is supported)
1231                 ],
1232                 AC_MSG_NOTICE(Bluetooth sniffing is not supported; install bluez-lib devel to enable it)
1233                )
1234                ;;
1235         *)
1236                AC_MSG_NOTICE(no Bluetooth sniffing support)
1237                ;;
1238         esac
1239         AC_SUBST(PCAP_SUPPORT_BT)
1240         AC_SUBST(BT_SRC)
1241 fi
1242
1243 AC_PROG_INSTALL
1244
1245 AC_CONFIG_HEADER(config.h)
1246
1247 AC_OUTPUT(Makefile pcap-filter.manmisc pcap-linktype.manmisc
1248         pcap-savefile.manfile pcap.3pcap pcap_compile.3pcap
1249         pcap_datalink.3pcap pcap_dump_open.3pcap
1250         pcap_list_datalinks.3pcap pcap_open_dead.3pcap
1251         pcap_open_offline.3pcap)
1252
1253 if test -f .devel ; then
1254         make depend
1255 fi
1256 exit 0