The Tcpdump Group git mirrors - libpcap/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/libpcap/configure.in,v 1.168 2008-12-23 20:49:26 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 #
  10 # See
  11 #
  12 #       http://ftp.gnu.org/gnu/config/README
  13 #
  14 # for the URLs to use to fetch new versions of config.guess and
  15 # config.sub.
  16 #
  17
  18 AC_REVISION($Revision: 1.168 $)
  19 AC_PREREQ(2.50)
  20 AC_INIT(pcap.c)
  21
  22 AC_CANONICAL_SYSTEM
  23
  24 AC_LBL_C_INIT_BEFORE_CC(V_CCOPT, V_INCLS)
  25 AC_PROG_CC
  26 AC_LBL_C_INIT(V_CCOPT, V_INCLS)
  27 AC_LBL_SHLIBS_INIT
  28 AC_LBL_C_INLINE
  29 AC_C___ATTRIBUTE__
  30
  31 AC_CHECK_HEADERS(sys/bitypes.h)
  32
  33 AC_CHECK_TYPE([int8_t], ,
  34         [AC_DEFINE([int8_t], [signed char],
  35         [Define to `signed char' if int8_t not defined.])],
  36         [AC_INCLUDES_DEFAULT
  37 #ifdef HAVE_SYS_BITYPES_H
  38 #include <sys/bitypes.h>
  39 #endif])
  40 AC_CHECK_TYPE([u_int8_t], ,
  41         [AC_DEFINE([u_int8_t], [unsigned char],
  42         [Define to `unsigned char' if u_int8_t not defined.])],
  43         [AC_INCLUDES_DEFAULT
  44 #ifdef HAVE_SYS_BITYPES_H
  45 #include <sys/bitypes.h>
  46 #endif])
  47 AC_CHECK_TYPE([int16_t], ,
  48         [AC_DEFINE([int16_t], [short],
  49         [Define to `short' if int16_t not defined.])]
  50         [AC_INCLUDES_DEFAULT
  51 #ifdef HAVE_SYS_BITYPES_H
  52 #include <sys/bitypes.h>
  53 #endif])
  54 AC_CHECK_TYPE([u_int16_t], ,
  55         [AC_DEFINE([u_int16_t], [unsigned short],
  56         [Define to `unsigned short' if u_int16_t not defined.])],
  57         [AC_INCLUDES_DEFAULT
  58 #ifdef HAVE_SYS_BITYPES_H
  59 #include <sys/bitypes.h>
  60 #endif])
  61 AC_CHECK_TYPE([int32_t], ,
  62         [AC_DEFINE([int32_t], [int],
  63         [Define to `int' if int32_t not defined.])],
  64         [AC_INCLUDES_DEFAULT
  65 #ifdef HAVE_SYS_BITYPES_H
  66 #include <sys/bitypes.h>
  67 #endif])
  68 AC_CHECK_TYPE([u_int32_t], ,
  69         [AC_DEFINE([u_int32_t], [unsigned int],
  70         [Define to `unsigned int' if u_int32_t not defined.])],
  71         [AC_INCLUDES_DEFAULT
  72 #ifdef HAVE_SYS_BITYPES_H
  73 #include <sys/bitypes.h>
  74 #endif])
  75 AC_CHECK_TYPE([int64_t], ,
  76         [AC_DEFINE([int64_t], [long long],
  77         [Define to `long long' if int64_t not defined.])],
  78         [AC_INCLUDES_DEFAULT
  79 #ifdef HAVE_SYS_BITYPES_H
  80 #include <sys/bitypes.h>
  81 #endif])
  82 AC_CHECK_TYPE([u_int64_t], ,
  83         [AC_DEFINE([u_int64_t], [unsigned long long],
  84         [Define to `unsigned long long' if u_int64_t not defined.])],
  85         [AC_INCLUDES_DEFAULT
  86 #ifdef HAVE_SYS_BITYPES_H
  87 #include <sys/bitypes.h>
  88 #endif])
  89
  90 #
  91 # Try to arrange for large file support.
  92 #
  93 AC_SYS_LARGEFILE
  94 AC_FUNC_FSEEKO
  95
  96 dnl
  97 dnl Even if <net/bpf.h> were, on all OSes that support BPF, fixed to
  98 dnl include <sys/ioccom.h>, and we were to drop support for older
  99 dnl releases without that fix, so that pcap-bpf.c doesn't need to
 100 dnl include <sys/ioccom.h>, the test program in "AC_LBL_FIXINCLUDES"
 101 dnl in "aclocal.m4" uses it, so we would still have to test for it
 102 dnl and set "HAVE_SYS_IOCCOM_H" if we have it, otherwise
 103 dnl "AC_LBL_FIXINCLUDES" wouldn't work on some platforms such as Solaris.
 104 dnl
 105 AC_CHECK_HEADERS(sys/ioccom.h sys/sockio.h limits.h paths.h)
 106 AC_CHECK_HEADERS(net/pfvar.h, , , [#include <sys/types.h>
 107 #include <sys/socket.h>
 108 #include <net/if.h>])
 109 if test "$ac_cv_header_net_pfvar_h" = yes; then
 110         #
 111         # Check for various PF actions.
 112         #
 113         AC_MSG_CHECKING(whether net/pfvar.h defines PF_NAT through PF_NORDR)
 114         AC_TRY_COMPILE(
 115             [#include <sys/types.h>
 116             #include <sys/socket.h>
 117             #include <net/if.h>
 118             #include <net/pfvar.h>],
 119             [return PF_NAT+PF_NONAT+PF_BINAT+PF_NOBINAT+PF_RDR+PF_NORDR;],
 120             [
 121                 AC_MSG_RESULT(yes)
 122                 AC_DEFINE(HAVE_PF_NAT_THROUGH_PF_NORDR, 1,
 123                     [define if net/pfvar.h defines PF_NAT through PF_NORDR])
 124             ],
 125             AC_MSG_RESULT(no))
 126 fi
 127 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
 128 #include <sys/socket.h>])
 129 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
 130         #
 131         # The simple test didn't work.
 132         # Do we need to include <net/if.h> first?
 133         # Unset ac_cv_header_netinet_if_ether_h so we don't
 134         # treat the previous failure as a cached value and
 135         # suppress the next test.
 136         #
 137         AC_MSG_NOTICE([Rechecking with some additional includes])
 138         unset ac_cv_header_netinet_if_ether_h
 139         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
 140 #include <sys/socket.h>
 141 #include <netinet/in.h>
 142 struct mbuf;
 143 struct rtentry;
 144 #include <net/if.h>])
 145 fi
 146
 147 AC_LBL_FIXINCLUDES
 148
 149 AC_CHECK_FUNCS(strerror strlcpy)
 150
 151 needsnprintf=no
 152 AC_CHECK_FUNCS(vsnprintf snprintf,,
 153         [needsnprintf=yes])
 154 if test $needsnprintf = yes; then
 155         AC_LIBOBJ([snprintf])
 156 fi
 157
 158 #
 159 # Do this before checking for ether_hostton(), as it's a
 160 # "gethostbyname() -ish function".
 161 #
 162 AC_LBL_LIBRARY_NET
 163
 164 #
 165 # You are in a twisty little maze of UN*Xes, all different.
 166 # Some might not have ether_hostton().
 167 # Some might have it, but not declare it in any header file.
 168 # Some might have it, but declare it in <netinet/if_ether.h>.
 169 # Some might have it, but declare it in <netinet/ether.h>
 170 # (And some might have it but document it as something declared in
 171 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
 172 #
 173 # Before you is a C compiler.
 174 #
 175 AC_CHECK_FUNCS(ether_hostton)
 176 if test "$ac_cv_func_ether_hostton" = yes; then
 177         #
 178         # OK, we have ether_hostton().  Do we have <netinet/if_ether.h>?
 179         #
 180         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
 181                 #
 182                 # Yes.  Does it declare ether_hostton()?
 183                 #
 184                 AC_CHECK_DECL(ether_hostton,
 185                     [
 186                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_HOSTTON,,
 187                             [Define to 1 if netinet/if_ether.h declares `ether_hostton'])
 188                     ],,
 189                     [
 190 #include <sys/types.h>
 191 #include <sys/socket.h>
 192 #include <netinet/in.h>
 193 #include <arpa/inet.h>
 194 struct mbuf;
 195 struct rtentry;
 196 #include <net/if.h>
 197 #include <netinet/if_ether.h>
 198                     ])
 199         fi
 200         #
 201         # Did that succeed?
 202         #
 203         if test "$ac_cv_have_decl_ether_hostton" != yes; then
 204                 #
 205                 # No, how about <netinet/ether.h>, as on Linux?
 206                 #
 207                 AC_CHECK_HEADERS(netinet/ether.h)
 208                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 209                         #
 210                         # We have it - does it declare ether_hostton()?
 211                         # Unset ac_cv_have_decl_ether_hostton so we don't
 212                         # treat the previous failure as a cached value and
 213                         # suppress the next test.
 214                         #
 215                         unset ac_cv_have_decl_ether_hostton
 216                         AC_CHECK_DECL(ether_hostton,
 217                             [
 218                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_HOSTTON,,
 219                                     [Define to 1 if netinet/ether.h declares `ether_hostton'])
 220                             ],,
 221                             [
 222 #include <netinet/ether.h>
 223                             ])
 224                 fi
 225         fi
 226         #
 227         # Is ether_hostton() declared?
 228         #
 229         if test "$ac_cv_have_decl_ether_hostton" != yes; then
 230                 #
 231                 # No, we'll have to declare it ourselves.
 232                 # Do we have "struct ether_addr"?
 233                 #
 234                 AC_CHECK_TYPES(struct ether_addr,,,
 235                     [
 236 #include <sys/types.h>
 237 #include <sys/socket.h>
 238 #include <netinet/in.h>
 239 #include <arpa/inet.h>
 240 struct mbuf;
 241 struct rtentry;
 242 #include <net/if.h>
 243 #include <netinet/if_ether.h>
 244                     ])
 245                 AC_DEFINE(HAVE_DECL_ETHER_HOSTTON, 0,
 246                     [Define to 1 if you have the declaration of `ether_hostton', and to 0 if you
 247 don't.])
 248         else
 249                 AC_DEFINE(HAVE_DECL_ETHER_HOSTTON, 1,
 250                     [Define to 1 if you have the declaration of `ether_hostton', and to 0 if you
 251 don't.])
 252         fi
 253 fi
 254
 255 dnl to pacify those who hate protochain insn
 256 AC_MSG_CHECKING(if --disable-protochain option is specified)
 257 AC_ARG_ENABLE(protochain,
 258 AC_HELP_STRING([--disable-protochain],[disable \"protochain\" insn]))
 259 case "x$enable_protochain" in
 260 xyes)   enable_protochain=enabled       ;;
 261 xno)    enable_protochain=disabled      ;;
 262 x)      enable_protochain=enabled       ;;
 263 esac
 264
 265 if test "$enable_protochain" = "disabled"; then
 266         AC_DEFINE(NO_PROTOCHAIN,1,[do not use protochain])
 267 fi
 268 AC_MSG_RESULT(${enable_protochain})
 269
 270 #
 271 # SITA support is mutually exclusive with native capture support;
 272 # "--with-sita" selects SITA support.
 273 #
 274 AC_ARG_WITH(sita,
 275 AC_HELP_STRING([--with-sita],[include SITA support]),
 276 [
 277         if test ! "x$withval" = "xno" ; then
 278                 AC_DEFINE(SITA,1,[include ACN support])
 279                 AC_MSG_NOTICE(Enabling SITA ACN support)
 280                 V_PCAP=sita
 281                 V_FINDALLDEVS=sita
 282         fi
 283 ],
 284 [
 285 dnl
 286 dnl Not all versions of test support -c (character special) but it's a
 287 dnl better way of testing since the device might be protected. So we
 288 dnl check in our normal order using -r and then check the for the /dev
 289 dnl guys again using -c.
 290 dnl
 291 dnl XXX This could be done for cross-compiling, but for now it's not.
 292 dnl
 293 if test -z "$with_pcap" && test "$cross_compiling" = yes; then
 294         AC_MSG_ERROR(pcap type not determined when cross-compiling; use --with-pcap=...)
 295 fi
 296 AC_ARG_WITH(pcap,
 297 AC_HELP_STRING([--with-pcap=TYPE],[use packet capture TYPE]))
 298 AC_MSG_CHECKING(packet capture type)
 299 if test ! -z "$with_pcap" ; then
 300         V_PCAP="$withval"
 301 elif test -r /dev/bpf -o -h /dev/bpf ; then
 302         #
 303         # Cloning BPF device.
 304         #
 305         V_PCAP=bpf
 306         AC_DEFINE(HAVE_CLONING_BPF,1,[define if you have a cloning BPF device])
 307 elif test -r /dev/bpf0 ; then
 308         V_PCAP=bpf
 309 elif test -r /usr/include/net/pfilt.h ; then
 310         V_PCAP=pf
 311 elif test -r /dev/enet ; then
 312         V_PCAP=enet
 313 elif test -r /dev/nit ; then
 314         V_PCAP=snit
 315 elif test -r /usr/include/sys/net/nit.h ; then
 316         V_PCAP=nit
 317 elif test -r /usr/include/linux/socket.h ; then
 318         V_PCAP=linux
 319 elif test -r /usr/include/net/raw.h ; then
 320         V_PCAP=snoop
 321 elif test -r /usr/include/odmi.h ; then
 322         #
 323         # On AIX, the BPF devices might not yet be present - they're
 324         # created the first time libpcap runs after booting.
 325         # We check for odmi.h instead.
 326         #
 327         V_PCAP=bpf
 328 elif test -c /dev/bpf0 ; then           # check again in case not readable
 329         V_PCAP=bpf
 330 elif test -r /usr/include/sys/dlpi.h ; then
 331         V_PCAP=dlpi
 332 elif test -c /dev/enet ; then           # check again in case not readable
 333         V_PCAP=enet
 334 elif test -c /dev/nit ; then            # check again in case not readable
 335         V_PCAP=snit
 336 else
 337         V_PCAP=null
 338 fi
 339 AC_MSG_RESULT($V_PCAP)
 340
 341 #
 342 # Do capture-mechanism-dependent tests.
 343 #
 344 case "$V_PCAP" in
 345 dlpi)
 346         #
 347         # Checks to see if Solaris has the public libdlpi(3LIB) library.
 348         # Note: The existence of /usr/include/libdlpi.h does not mean it is the
 349         # public libdlpi(3LIB) version. Before libdlpi was made public, a
 350         # private version also existed, which did not have the same APIs.
 351         # Due to a gcc bug, the default search path for 32-bit libraries does
 352         # not include /lib, we add it explicitly here.
 353         # [http://bugs.opensolaris.org/view_bug.do?bug_id=6619485].
 354         # Also, due to the bug above applications that link to libpcap with
 355         # libdlpi will have to add "-L/lib" option to "configure".
 356         #
 357         saved_ldflags=$LDFLAGS
 358         LDFLAGS="$LIBS -L/lib"
 359         AC_CHECK_LIB(dlpi, dlpi_walk,
 360                 LIBS="-ldlpi $LIBS"
 361                 V_PCAP=libdlpi
 362                 AC_DEFINE(HAVE_LIBDLPI,1,[if libdlpi exists]),
 363                 V_PCAP=dlpi)
 364         LDFLAGS=$saved_ldflags
 365
 366         #
 367         # Checks whether <sys/dlpi.h> is usable, to catch weird SCO
 368         # versions of DLPI.
 369         #
 370         AC_MSG_CHECKING(whether <sys/dlpi.h> is usable)
 371         AC_CACHE_VAL(ac_cv_sys_dlpi_usable,
 372                 AC_TRY_COMPILE(
 373                     [
 374                         #include <sys/types.h>
 375                         #include <sys/time.h>
 376                         #include <sys/dlpi.h>
 377                     ],
 378                     [int i = DL_PROMISC_PHYS;],
 379                     ac_cv_sys_dlpi_usable=yes,
 380                     ac_cv_sys_dlpi_usable=no))
 381         AC_MSG_RESULT($ac_cv_sys_dlpi_usable)
 382         if test $ac_cv_sys_dlpi_usable = no ; then
 383                 AC_MSG_ERROR(<sys/dlpi.h> is not usable on this system; it probably has a non-standard DLPI)
 384         fi
 385
 386         #
 387         # Check whether we have a /dev/dlpi device or have multiple devices.
 388         #
 389         AC_MSG_CHECKING(for /dev/dlpi device)
 390         if test -c /dev/dlpi ; then
 391                 AC_MSG_RESULT(yes)
 392                 AC_DEFINE(HAVE_DEV_DLPI, 1, [define if you have a /dev/dlpi])
 393         else
 394                 AC_MSG_RESULT(no)
 395                 dir="/dev/dlpi"
 396                 AC_MSG_CHECKING(for $dir directory)
 397                 if test -d $dir ; then
 398                         AC_MSG_RESULT(yes)
 399                         AC_DEFINE_UNQUOTED(PCAP_DEV_PREFIX, "$dir", [/dev/dlpi directory])
 400                 else
 401                         AC_MSG_RESULT(no)
 402                 fi
 403         fi
 404
 405         #
 406         # This check is for Solaris with DLPI support for passive modes.
 407         # See dlpi(7P) for more details.
 408         #
 409         AC_LBL_DL_PASSIVE_REQ_T
 410         ;;
 411
 412 linux)
 413         #
 414         # Do we have the wireless extensions?
 415         #
 416         AC_CHECK_HEADERS(linux/wireless.h, [], [],
 417         [
 418 #include <sys/socket.h>
 419 #include <linux/if.h>
 420 #include <linux/types.h>
 421         ])
 422
 423         #
 424         # Do we have libnl?
 425         #
 426         AC_ARG_WITH(libnl,
 427         AC_HELP_STRING([--without-libnl],[disable libnl support @<:@default=yes, on Linux, if present@:>@]),
 428                 with_libnl=$withval,,)
 429
 430         if test x$with_libnl != xno ; then
 431                 #
 432                 # Try libnl 2.x first.
 433                 #
 434                 AC_CHECK_LIB(nl, nl_socket_alloc,
 435                 [
 436                         #
 437                         # Yes, we have libnl 2.x.
 438                         #
 439                         LIBS="-lnl-genl -lnl $LIBS"
 440                         AC_DEFINE(HAVE_LIBNL,1,[if libnl exists])
 441                         AC_DEFINE(HAVE_LIBNL_2_x,1,[if libnl exists and is version 2.x])
 442                 ],
 443                 [
 444                         #
 445                         # No, we don't; do we have libnl 1.x?
 446                         #
 447                         AC_CHECK_LIB(nl, nl_handle_alloc,
 448                         [
 449                                 #
 450                                 # Yes.
 451                                 #
 452                                 LIBS="-lnl $LIBS"
 453                                 AC_DEFINE(HAVE_LIBNL,1,[if libnl exists])
 454                         ],
 455                         [
 456                                 #
 457                                 # No, we don't have libnl at all.
 458                                 #
 459                                 if test x$with_libnl = xyes ; then
 460                                         AC_MSG_ERROR([libnl support requested but libnl not found])
 461                                 fi
 462                         ])
 463                 ])
 464         fi
 465
 466         AC_CHECK_HEADERS(linux/ethtool.h)
 467         AC_LBL_TPACKET_STATS
 468         AC_LBL_LINUX_TPACKET_AUXDATA_TP_VLAN_TCI
 469         ;;
 470
 471 bpf)
 472         #
 473         # Check whether we have the *BSD-style ioctls.
 474         #
 475         AC_CHECK_HEADERS(net/if_media.h)
 476
 477         AC_MSG_CHECKING(whether the system supports zerocopy BPF)
 478         AC_TRY_COMPILE(
 479             [#include <sys/socket.h>
 480             #include <sys/ioctl.h>
 481             #include <net/if.h>
 482             #include <net/bpf.h>],
 483             [return (BIOCROTZBUF + BPF_BUFMODE_ZBUF);],
 484             [
 485                 AC_MSG_RESULT(yes)
 486                 AC_DEFINE(HAVE_ZEROCOPY_BPF, 1,
 487                 [define if the system supports zerocopy BPF])
 488             ],
 489             AC_MSG_RESULT(no))
 490
 491             #
 492             # Check whether we have struct BPF_TIMEVAL.
 493             #
 494             AC_CHECK_TYPES(struct BPF_TIMEVAL,,,
 495                 [
 496 #include <sys/types.h>
 497 #include <sys/ioctl.h>
 498 #ifdef HAVE_SYS_IOCCOM_H
 499 #include <sys/ioccom.h>
 500 #endif
 501 #include <net/bpf.h>
 502                     ])
 503         ;;
 504
 505 dag)
 506         V_DEFS="$V_DEFS -DDAG_ONLY"
 507         ;;
 508
 509 septel)
 510         V_DEFS="$V_DEFS -DSEPTEL_ONLY"
 511         ;;
 512
 513 snf)
 514         V_DEFS="$V_DEFS -DSNF_ONLY"
 515         ;;
 516
 517 null)
 518         AC_MSG_WARN(cannot determine packet capture interface)
 519         AC_MSG_WARN((see the INSTALL doc for more info))
 520         ;;
 521 esac
 522
 523 dnl
 524 dnl Now figure out how we get a list of interfaces and addresses,
 525 dnl if we support capturing.  Don't bother if we don't support
 526 dnl capturing.
 527 dnl
 528 if test "$V_PCAP" = null
 529 then
 530         #
 531         # We can't capture, so we can't open any capture
 532         # devices, so we won't return any interfaces.
 533         #
 534         V_FINDALLDEVS=null
 535 else
 536         AC_CHECK_FUNC(getifaddrs,[
 537                 #
 538                 # We have "getifaddrs()"; make sure we have <ifaddrs.h>
 539                 # as well, just in case some platform is really weird.
 540                 #
 541                 AC_CHECK_HEADER(ifaddrs.h,[
 542                     #
 543                     # We have the header, so we use "getifaddrs()" to
 544                     # get the list of interfaces.
 545                     #
 546                     V_FINDALLDEVS=getad
 547                 ],[
 548                     #
 549                     # We don't have the header - give up.
 550                     # XXX - we could also fall back on some other
 551                     # mechanism, but, for now, this'll catch this
 552                     # problem so that we can at least try to figure
 553                     # out something to do on systems with "getifaddrs()"
 554                     # but without "ifaddrs.h", if there is something
 555                     # we can do on those systems.
 556                     #
 557                     AC_MSG_ERROR([Your system has getifaddrs() but doesn't have a usable <ifaddrs.h>.])
 558                 ])
 559         ],[
 560                 #
 561                 # Well, we don't have "getifaddrs()", so we have to use
 562                 # some other mechanism; determine what that mechanism is.
 563                 #
 564                 # The first thing we use is the type of capture mechanism,
 565                 # which is somewhat of a proxy for the OS we're using.
 566                 #
 567                 case "$V_PCAP" in
 568
 569                 dlpi|libdlpi)
 570                         AC_CHECK_HEADERS(sys/bufmod.h sys/dlpi_ext.h)
 571                         #
 572                         # This might be Solaris 8 or later, with
 573                         # SIOCGLIFCONF, or it might be some other OS
 574                         # or some older version of Solaris, with
 575                         # just SIOCGIFCONF.
 576                         #
 577                         AC_MSG_CHECKING(whether we have SIOCGLIFCONF)
 578                         AC_CACHE_VAL(ac_cv_lbl_have_siocglifconf,
 579                             AC_TRY_COMPILE(
 580                                 [#include <sys/param.h>
 581                                 #include <sys/file.h>
 582                                 #include <sys/ioctl.h>
 583                                 #include <sys/socket.h>
 584                                 #include <sys/sockio.h>],
 585                                 [ioctl(0, SIOCGLIFCONF, (char *)0);],
 586                                 ac_cv_lbl_have_siocglifconf=yes,
 587                                 ac_cv_lbl_have_siocglifconf=no))
 588                         AC_MSG_RESULT($ac_cv_lbl_have_siocglifconf)
 589                         if test $ac_cv_lbl_have_siocglifconf = yes ; then
 590                                 V_FINDALLDEVS=glifc
 591                         else
 592                                 V_FINDALLDEVS=gifc
 593                         fi
 594                         #
 595                         # Needed for common functions used by pcap-[dlpi,libdlpi].c
 596                         #
 597                         SSRC="dlpisubs.c"
 598                         ;;
 599
 600                 *)
 601                         #
 602                         # Assume we just have SIOCGIFCONF.
 603                         # (XXX - on at least later Linux kernels, there's
 604                         # another mechanism, and we should be using that
 605                         # instead.)
 606                         #
 607                         V_FINDALLDEVS=gifc
 608                         ;;
 609                 esac])
 610 fi
 611 ])
 612
 613 AC_MSG_CHECKING(for socklen_t)
 614 AC_TRY_COMPILE([
 615         #include <sys/types.h>
 616         #include <sys/socket.h>
 617         ],
 618         [ socklen_t x; ],
 619         have_socklen_t=yes,
 620         have_socklen_t=no)
 621 if test "x$have_socklen_t" = "xyes"; then
 622         AC_DEFINE(HAVE_SOCKLEN_T, 1, [define if socklen_t is defined])
 623 fi
 624 AC_MSG_RESULT($have_socklen_t)
 625
 626 AC_ARG_ENABLE(ipv6,
 627 AC_HELP_STRING([--enable-ipv6],[build IPv6-capable version @<:@default=yes, if getaddrinfo available@:>@]),
 628     [],
 629     [enable_ipv6=ifavailable])
 630 if test "$enable_ipv6" != "no"; then
 631         AC_CHECK_FUNC(getaddrinfo,
 632             [
 633                 AC_DEFINE(INET6,1,[IPv6])
 634             ],
 635             [
 636                 if test "$enable_ipv6" != "ifavailable"; then
 637                         AC_MSG_FAILURE([--enable-ipv6 was given, but getaddrinfo isn't available])
 638                 fi
 639             ])
 640 fi
 641
 642 AC_MSG_CHECKING(whether to build optimizer debugging code)
 643 AC_ARG_ENABLE(optimizer-dbg,
 644 AC_HELP_STRING([--enable-optimizer-dbg],[build optimizer debugging code]))
 645 if test "$enable_optimizer_dbg" = "yes"; then
 646         AC_DEFINE(BDEBUG,1,[Enable optimizer debugging])
 647 fi
 648 AC_MSG_RESULT(${enable_optimizer_dbg-no})
 649
 650 AC_MSG_CHECKING(whether to build parser debugging code)
 651 AC_ARG_ENABLE(yydebug,
 652 AC_HELP_STRING([--enable-yydebug],[build parser debugging code]))
 653 if test "$enable_yydebug" = "yes"; then
 654         AC_DEFINE(YYDEBUG,1,[Enable parser debugging])
 655 fi
 656 AC_MSG_RESULT(${enable_yydebug-no})
 657
 658 # Check for Endace DAG card support.
 659 AC_ARG_WITH([dag],
 660 AC_HELP_STRING([--with-dag@<:@=DIR@:>@],[include Endace DAG support @<:@"yes", "no" or DIR; default="yes" on BSD and Linux if present@:>@]),
 661 [
 662         if test "$withval" = no
 663         then
 664                 # User doesn't want DAG support.
 665                 want_dag=no
 666         elif test "$withval" = yes
 667         then
 668                 # User wants DAG support but hasn't specified a directory.
 669                 want_dag=yes
 670         else
 671                 # User wants DAG support and has specified a directory, so use the provided value.
 672                 want_dag=yes
 673                 dag_root=$withval
 674         fi
 675 ],[
 676         #
 677         # Use DAG API if present, otherwise don't
 678         #
 679         want_dag=ifpresent
 680 ])
 681
 682 AC_ARG_WITH([dag-includes],
 683 AC_HELP_STRING([--with-dag-includes=DIR],[Endace DAG include directory]),
 684 [
 685         # User wants DAG support and has specified a header directory, so use the provided value.
 686         want_dag=yes
 687         dag_include_dir=$withval
 688 ],[])
 689
 690 AC_ARG_WITH([dag-libraries],
 691 AC_HELP_STRING([--with-dag-libraries=DIR],[Endace DAG library directory]),
 692 [
 693         # User wants DAG support and has specified a library directory, so use the provided value.
 694         want_dag=yes
 695         dag_lib_dir=$withval
 696 ],[])
 697
 698 case "$V_PCAP" in
 699 linux|bpf|dag)
 700         #
 701         # We support the DAG API if we're on Linux or BSD, or if we're
 702         # building a DAG-only libpcap.
 703         #
 704         ;;
 705 *)
 706         #
 707         # If the user explicitly requested DAG, tell them it's not
 708         # supported.
 709         #
 710         # If they expressed no preference, don't include it.
 711         #
 712         if test $want_dag = yes; then
 713                 AC_MSG_ERROR([DAG support is only available with 'linux' 'bpf' and 'dag' packet capture types])
 714         elif test $want_dag = yes; then
 715                 want_dag=no
 716         fi
 717         ;;
 718 esac
 719
 720 ac_cv_lbl_dag_api=no
 721 if test "$want_dag" != no; then
 722
 723         AC_MSG_CHECKING([whether we have DAG API headers])
 724
 725         # If necessary, set default paths for DAG API headers and libraries.
 726         if test -z "$dag_root"; then
 727             dag_root=/usr/local
 728         fi
 729
 730         if test -z "$dag_include_dir"; then
 731                 dag_include_dir="$dag_root/include"
 732         fi
 733
 734         if test -z "$dag_lib_dir"; then
 735             dag_lib_dir="$dag_root/lib"
 736         fi
 737
 738         if test -z "$dag_tools_dir"; then
 739             dag_tools_dir="$dag_root/tools"
 740         fi
 741
 742         if test -r $dag_include_dir/dagapi.h; then
 743                 ac_cv_lbl_dag_api=yes
 744         fi
 745         AC_MSG_RESULT([$ac_cv_lbl_dag_api ($dag_include_dir)])
 746 fi
 747
 748 if test $ac_cv_lbl_dag_api = yes; then
 749         V_INCLS="$V_INCLS -I$dag_include_dir"
 750
 751         if test $V_PCAP != dag ; then
 752                  SSRC="pcap-dag.c"
 753         fi
 754
 755         # See if we can find a general version string.
 756         # Don't need to save and restore LIBS to prevent -ldag being
 757         # included if there's a found-action (arg 3).
 758         saved_ldflags=$LDFLAGS
 759         LDFLAGS="-L$dag_lib_dir"
 760         AC_CHECK_LIB([dag], [dag_attach_stream], [dag_streams="1"], [dag_streams="0"])
 761         AC_CHECK_LIB([dag],[dag_get_erf_types], [
 762                 AC_DEFINE(HAVE_DAG_GET_ERF_TYPES, 1, [define if you have dag_get_erf_types()])])
 763         AC_CHECK_LIB([dag],[dag_get_stream_erf_types], [
 764                 AC_DEFINE(HAVE_DAG_GET_STREAM_ERF_TYPES, 1, [define if you have dag_get_stream_erf_types()])])
 765
 766         LDFLAGS=$saved_ldflags
 767
 768         if test "$dag_streams" = 1; then
 769                 AC_DEFINE(HAVE_DAG_STREAMS_API, 1, [define if you have streams capable DAG API])
 770                 LIBS="$LIBS -ldag"
 771                 LDFLAGS="$LDFLAGS -L$dag_lib_dir"
 772
 773                 AC_CHECK_LIB([vdag],[vdag_set_device_info], [ac_dag_have_vdag="1"], [ac_dag_have_vdag="0"])
 774                 if test "$ac_dag_have_vdag" = 1; then
 775                         AC_DEFINE(HAVE_DAG_VDAG, 1, [define if you have vdag_set_device_info()])
 776                         LIBS="$LIBS -lpthread"
 777                 fi
 778         fi
 779
 780         AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
 781 fi
 782
 783 AC_MSG_CHECKING(whether we have the DAG API)
 784
 785 if test $ac_cv_lbl_dag_api = no; then
 786         AC_MSG_RESULT(no)
 787         if test "$want_dag" = yes; then
 788                 # User wanted DAG support but we couldn't find it.
 789                 AC_MSG_ERROR([DAG API requested, but not found at $dag_root: use --without-dag])
 790         fi
 791
 792         if test "$V_PCAP" = dag; then
 793                 # User requested "dag" capture type but the DAG API wasn't
 794                 # found.
 795                 AC_MSG_ERROR([Specifying the capture type as "dag" requires the DAG API to be present; use the --with-dag options to specify the location. (Try "./configure --help" for more information.)])
 796         fi
 797 else
 798         AC_MSG_RESULT(yes)
 799 fi
 800
 801 AC_ARG_WITH(septel,
 802 AC_HELP_STRING([--with-septel@<:@=DIR@:>@],[include Septel support (located in directory DIR, if supplied).  @<:@default=yes, on Linux, if present@:>@]),
 803 [
 804         if test "$withval" = no
 805         then
 806                 want_septel=no
 807         elif test "$withval" = yes
 808         then
 809                 want_septel=yes
 810                 septel_root=
 811         else
 812                 want_septel=yes
 813                 septel_root=$withval
 814         fi
 815 ],[
 816         #
 817         # Use Septel API if present, otherwise don't
 818         #
 819         want_septel=ifpresent
 820         septel_root=./../septel
 821 ])
 822 ac_cv_lbl_septel_api=no
 823 case "$V_PCAP" in
 824 linux|septel)
 825         #
 826         # We support the Septel API if we're on Linux, or if we're building
 827         # a Septel-only libpcap.
 828         #
 829         ;;
 830 *)
 831         #
 832         # If the user explicitly requested Septel, tell them it's not
 833         # supported.
 834         #
 835         # If they expressed no preference, don't include it.
 836         #
 837         if test $want_septel = yes; then
 838                 AC_MSG_ERROR(Septel support only available with 'linux' and 'septel' packet capture types)
 839         elif test $want_septel = yes; then
 840                 want_septel=no
 841         fi
 842         ;;
 843 esac
 844
 845 if test "$with_septel" != no; then
 846         AC_MSG_CHECKING(whether we have Septel API)
 847
 848         if test -z "$septel_root"; then
 849                 septel_root=$srcdir/../septel
 850         fi
 851
 852         septel_tools_dir="$septel_root"
 853         septel_include_dir="$septel_root/INC"
 854
 855         ac_cv_lbl_septel_api=no
 856         if test -r "$septel_include_dir/msg.h"; then
 857                 V_INCLS="$V_INCLS -I$septel_include_dir"
 858                 ADDLOBJS="$ADDLOBJS $septel_tools_dir/asciibin.o $septel_tools_dir/bit2byte.o $septel_tools_dir/confirm.o $septel_tools_dir/fmtmsg.o $septel_tools_dir/gct_unix.o $septel_tools_dir/hqueue.o $septel_tools_dir/ident.o $septel_tools_dir/mem.o $septel_tools_dir/pack.o $septel_tools_dir/parse.o $septel_tools_dir/pool.o $septel_tools_dir/sdlsig.o $septel_tools_dir/strtonum.o $septel_tools_dir/timer.o $septel_tools_dir/trace.o"
 859                 ADDLARCHIVEOBJS="$ADDLARCHIVEOBJS $septel_tools_dir/asciibin.o $septel_tools_dir/bit2byte.o $septel_tools_dir/confirm.o $septel_tools_dir/fmtmsg.o $septel_tools_dir/gct_unix.o $septel_tools_dir/hqueue.o $septel_tools_dir/ident.o $septel_tools_dir/mem.o $septel_tools_dir/pack.o $septel_tools_dir/parse.o $septel_tools_dir/pool.o $septel_tools_dir/sdlsig.o $septel_tools_dir/strtonum.o $septel_tools_dir/timer.o $septel_tools_dir/trace.o"
 860
 861                 if test "$V_PCAP" != septel ; then
 862                          SSRC="pcap-septel.c"
 863                 fi
 864                 ac_cv_lbl_septel_api=yes
 865         fi
 866
 867         AC_MSG_RESULT($ac_cv_lbl_septel_api)
 868         if test $ac_cv_lbl_septel_api = no; then
 869                 if test "$want_septel" = yes; then
 870                         AC_MSG_ERROR(Septel API not found under directory $septel_root; use --without-septel)
 871                 fi
 872         else
 873                 AC_DEFINE(HAVE_SEPTEL_API, 1, [define if you have a Septel API])
 874         fi
 875 fi
 876
 877 if test "$V_PCAP" = septel -a "$ac_cv_lbl_septel_api" = no; then
 878         AC_MSG_ERROR(Specifying the capture type as 'septel' requires the Septel API to be present; use --with-septel=DIR)
 879 fi
 880
 881 # Check for Myricom SNF support.
 882 AC_ARG_WITH([snf],
 883 AC_HELP_STRING([--with-snf@<:@=DIR@:>@],[include Myricom SNF support @<:@"yes", "no" or DIR; default="yes" on BSD and Linux if present@:>@]),
 884 [
 885         if test "$withval" = no
 886         then
 887                 # User explicitly doesn't want SNF
 888                 want_snf=no
 889         elif test "$withval" = yes
 890         then
 891                 # User wants SNF support but hasn't specific a directory.
 892                 want_snf=yes
 893         else
 894                 # User wants SNF support with a specified directory.
 895                 want_snf=yes
 896                 snf_root=$withval
 897         fi
 898 ],[
 899         #
 900         # Use Sniffer API if present, otherwise don't
 901         #
 902         want_snf=ifpresent
 903 ])
 904
 905 AC_ARG_WITH([snf-includes],
 906 AC_HELP_STRING([--with-snf-includes=DIR],[Myricom SNF include directory]),
 907 [
 908         # User wants SNF with specific header directory
 909         want_snf=yes
 910         snf_include_dir=$withval
 911 ],[])
 912
 913 AC_ARG_WITH([snf-libraries],
 914 AC_HELP_STRING([--with-snf-libraries=DIR],[Myricom SNF library directory]),
 915 [
 916         # User wants SNF with specific lib directory
 917         want_snf=yes
 918         snf_lib_dir=$withval
 919 ],[])
 920
 921 case "$V_PCAP" in
 922 bpf|linux|snf)
 923         #
 924         # We support the Sniffer API if we're on BSD, Linux, or if we're
 925         # building a Sniffer-only libpcap.
 926         #
 927         ;;
 928 *)
 929         #
 930         # If the user explicitly requested Sniffer, tell them it's not
 931         # supported.
 932         #
 933         # If they expressed no preference, don't include it.
 934         #
 935         if test $want_snf = yes; then
 936                 AC_MSG_ERROR(Myricom SNF support only available with 'bpf' 'linux' and 'snf' packet capture types)
 937         elif test $want_snf = yes; then
 938                 want_snf=no
 939         fi
 940         ;;
 941 esac
 942
 943 ac_cv_lbl_snf_api=no
 944 if test "$with_snf" != no; then
 945
 946         AC_MSG_CHECKING(whether we have Myricom Sniffer API)
 947
 948         if test -z "$snf_root"; then
 949                 snf_root=/opt/snf
 950         fi
 951
 952         if test -z "$snf_include_dir"; then
 953                 snf_include_dir="$snf_root/include"
 954         fi
 955
 956         if test -z "$snf_lib_dir"; then
 957                 snf_lib_dir="$snf_root/lib"
 958         fi
 959
 960         if test -f "$snf_include_dir/snf.h"; then
 961                 ac_cv_lbl_snf_api=yes
 962         fi
 963         AC_MSG_RESULT([$ac_cv_lbl_snf_api ($snf_root)])
 964
 965         if test $ac_cv_lbl_snf_api = no; then
 966                 if test "$want_snf" = yes; then
 967                         AC_MSG_ERROR(SNF API headers not found under $snf_include_dir; use --without-snf)
 968                 fi
 969         else
 970                 saved_ldflags=$LDFLAGS
 971                 LDFLAGS="$LDFLAGS -L$snf_lib_dir"
 972                 AC_CHECK_LIB([snf], [snf_init], [ac_cv_lbl_snf_api="yes"], [ac_cv_lbl_snf_api="no"])
 973                 LDFLAGS="$saved_ldflags"
 974
 975                 if test $ac_cv_lbl_snf_api = no; then
 976                         if test "$want_snf" = yes; then
 977                                 AC_MSG_ERROR(SNF API cannot correctly be linked check config.log; use --without-snf)
 978                         fi
 979                 else
 980                         V_INCLS="$V_INCLS -I$snf_include_dir"
 981                         LIBS="$LIBS -lsnf"
 982                         LDFLAGS="$LDFLAGS -L$snf_lib_dir"
 983                         if test "$V_PCAP" != snf ; then
 984                                 SSRC="pcap-snf.c"
 985                         fi
 986                         AC_DEFINE(HAVE_SNF_API, 1, [define if you have Myricom SNF API])
 987                 fi
 988         fi
 989 fi
 990
 991 if test "$V_PCAP" = snf -a "$ac_cv_lbl_snf_api" = no; then
 992         AC_MSG_ERROR(Specifying the capture type as 'snf' requires the Myricom Sniffer API to be present; use --with-snf=DIR)
 993 fi
 994
 995 AC_LBL_LEX_AND_YACC(V_LEX, V_YACC, pcap_)
 996 if test "$V_LEX" = lex ; then
 997 # Some versions of lex can't handle the definitions section of scanner.l .
 998 # Try lexing it and complain if it can't deal.
 999         AC_CACHE_CHECK([for capable lex], tcpdump_cv_capable_lex,
1000                 if lex -t scanner.l > /dev/null 2>&1; then
1001                         tcpdump_cv_capable_lex=yes
1002                 else
1003                         tcpdump_cv_capable_lex=insufficient
1004                 fi)
1005         if test $tcpdump_cv_capable_lex = insufficient ; then
1006                 AC_MSG_ERROR([Your operating system's lex is insufficient to compile
1007  libpcap.  flex is a lex replacement that has many advantages, including
1008  being able to compile libpcap.  For more information, see
1009  http://www.gnu.org/software/flex/flex.html .])
1010         fi
1011 fi
1012
1013 #
1014 # Assume, by default, no support for shared libraries and V7/BSD convention
1015 # for man pages (file formats in section 5, miscellaneous info in section 7).
1016 # Individual cases can override this.
1017 #
1018 DYEXT="none"
1019 MAN_FILE_FORMATS=5
1020 MAN_MISC_INFO=7
1021 case "$host_os" in
1022
1023 aix*)
1024         dnl Workaround to enable certain features
1025         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
1026
1027         #
1028         # AIX makes it fun to build shared and static libraries,
1029         # because they're *both* ".a" archive libraries.  We
1030         # build the static library for the benefit of the traditional
1031         # scheme of building libpcap and tcpdump in subdirectories of
1032         # the same directory, with tcpdump statically linked with the
1033         # libpcap in question, but we also build a shared library as
1034         # "libpcap.shareda" and install *it*, rather than the static
1035         # library, as "libpcap.a".
1036         #
1037         DYEXT="shareda"
1038
1039         case "$V_PCAP" in
1040
1041         dlpi)
1042                 #
1043                 # If we're using DLPI, applications will need to
1044                 # use /lib/pse.exp if present, as we use the
1045                 # STREAMS routines.
1046                 #
1047                 pseexe="/lib/pse.exp"
1048                 AC_MSG_CHECKING(for $pseexe)
1049                 if test -f $pseexe ; then
1050                         AC_MSG_RESULT(yes)
1051                         LIBS="-I:$pseexe"
1052                 fi
1053                 ;;
1054
1055         bpf)
1056                 #
1057                 # If we're using BPF, we need "-lodm" and "-lcfg", as
1058                 # we use them to load the BPF module.
1059                 #
1060                 LIBS="-lodm -lcfg"
1061                 ;;
1062         esac
1063         ;;
1064
1065 darwin*)
1066         DYEXT="dylib"
1067         V_CCOPT="$V_CCOPT -fno-common"
1068         AC_ARG_ENABLE(universal,
1069         AC_HELP_STRING([--disable-universal],[don't build universal on OS X]))
1070         if test "$enable_universal" != "no"; then
1071                 case "$host_os" in
1072
1073                 darwin9.*)
1074                         #
1075                         # Leopard.  Build for 32-bit PowerPC, 64-bit
1076                         # PowerPC, x86, and x86-64, with 32-bit PowerPC
1077                         # first.  (That's what Apple does.)
1078                         #
1079                         V_CCOPT="$V_CCOPT -arch ppc -arch ppc64 -arch i386 -arch x86_64"
1080                         LDFLAGS="$LDFLAGS -arch ppc -arch ppc64 -arch i386 -arch x86_64"
1081                         ;;
1082
1083                 darwin10.*)
1084                         #
1085                         # Snow Leopard.  Build for x86-64, x86, and
1086                         # 32-bit PowerPC, with x86-64 first.  (That's
1087                         # what Apple does, even though Snow Leopard
1088                         # doesn't run on PPC, so PPC libpcap runs under
1089                         # Rosetta, and Rosetta doesn't support BPF
1090                         # ioctls, so PPC programs can't do live
1091                         # captures.)
1092                         #
1093                         V_CCOPT="$V_CCOPT -arch x86_64 -arch i386 -arch ppc"
1094                         LDFLAGS="$LDFLAGS -arch x86_64 -arch i386 -arch ppc"
1095                         ;;
1096                 esac
1097         fi
1098         ;;
1099
1100 hpux9*)
1101         AC_DEFINE(HAVE_HPUX9,1,[on HP-UX 9.x])
1102
1103         #
1104         # Use System V conventions for man pages.
1105         #
1106         MAN_FILE_FORMATS=4
1107         MAN_MISC_INFO=5
1108         ;;
1109
1110 hpux10.0*)
1111
1112         #
1113         # Use System V conventions for man pages.
1114         #
1115         MAN_FILE_FORMATS=4
1116         MAN_MISC_INFO=5
1117         ;;
1118
1119 hpux10.1*)
1120
1121         #
1122         # Use System V conventions for man pages.
1123         #
1124         MAN_FILE_FORMATS=4
1125         MAN_MISC_INFO=5
1126         ;;
1127
1128 hpux*)
1129         dnl HPUX 10.20 and above is similar to HPUX 9, but
1130         dnl not the same....
1131         dnl
1132         dnl XXX - DYEXT should be set to "sl" if this is building
1133         dnl for 32-bit PA-RISC, but should be left as "so" for
1134         dnl 64-bit PA-RISC or, I suspect, IA-64.
1135         AC_DEFINE(HAVE_HPUX10_20_OR_LATER,1,[on HP-UX 10.20 or later])
1136         if test "`uname -m`" = "ia64"; then
1137                 DYEXT="so"
1138         else
1139                 DYEXT="sl"
1140         fi
1141
1142         #
1143         # "-b" builds a shared library; "+h" sets the soname.
1144         #
1145         SHLIB_OPT="-b"
1146         SONAME_OPT="+h"
1147
1148         #
1149         # Use System V conventions for man pages.
1150         #
1151         MAN_FILE_FORMATS=4
1152         MAN_MISC_INFO=5
1153         ;;
1154
1155 irix*)
1156         #
1157         # Use System V conventions for man pages.
1158         #
1159         MAN_FILE_FORMATS=4
1160         MAN_MISC_INFO=5
1161         ;;
1162
1163 linux*|freebsd*|netbsd*|openbsd*|dragonfly*)
1164         DYEXT="so"
1165
1166         #
1167         # Compiler assumed to be GCC; run-time linker may require a -R
1168         # flag.
1169         #
1170         if test "$libdir" != "/usr/lib"; then
1171                 V_RFLAGS=-Wl,-R$libdir
1172         fi
1173         ;;
1174
1175 osf*)
1176         DYEXT="so"
1177
1178         #
1179         # Use System V conventions for man pages.
1180         #
1181         MAN_FILE_FORMATS=4
1182         MAN_MISC_INFO=5
1183         ;;
1184
1185 sinix*)
1186         AC_MSG_CHECKING(if SINIX compiler defines sinix)
1187         AC_CACHE_VAL(ac_cv_cc_sinix_defined,
1188                 AC_TRY_COMPILE(
1189                     [],
1190                     [int i = sinix;],
1191                     ac_cv_cc_sinix_defined=yes,
1192                     ac_cv_cc_sinix_defined=no))
1193             AC_MSG_RESULT($ac_cv_cc_sinix_defined)
1194             if test $ac_cv_cc_sinix_defined = no ; then
1195                     AC_DEFINE(sinix,1,[on sinix])
1196             fi
1197         ;;
1198
1199 solaris*)
1200         AC_DEFINE(HAVE_SOLARIS,1,[On solaris])
1201
1202         DYEXT="so"
1203         #
1204         # Use System V conventions for man pages.
1205         #
1206         MAN_FILE_FORMATS=4
1207         MAN_MISC_INFO=5
1208         ;;
1209 esac
1210
1211 AC_PROG_RANLIB
1212 AC_CHECK_TOOL([AR], [ar])
1213
1214 AC_LBL_DEVEL(V_CCOPT)
1215
1216 AC_LBL_SOCKADDR_SA_LEN
1217
1218 AC_LBL_SOCKADDR_STORAGE
1219
1220 AC_LBL_HP_PPA_INFO_T_DL_MODULE_ID_1
1221
1222 AC_LBL_UNALIGNED_ACCESS
1223
1224 #
1225 # Makefile.in includes rules to generate version.h, so we assume
1226 # that it will be generated if autoconf is used.
1227 #
1228 AC_DEFINE(HAVE_VERSION_H, 1, [define if version.h is generated in the build procedure])
1229
1230 rm -f net
1231 ln -s ${srcdir}/bpf/net net
1232
1233 AC_SUBST(V_CCOPT)
1234 AC_SUBST(V_DEFS)
1235 AC_SUBST(V_FINDALLDEVS)
1236 AC_SUBST(V_INCLS)
1237 AC_SUBST(V_LEX)
1238 AC_SUBST(V_PCAP)
1239 AC_SUBST(V_SHLIB_CMD)
1240 AC_SUBST(V_SHLIB_OPT)
1241 AC_SUBST(V_SONAME_OPT)
1242 AC_SUBST(V_RPATH_OPT)
1243 AC_SUBST(V_YACC)
1244 AC_SUBST(ADDLOBJS)
1245 AC_SUBST(ADDLARCHIVEOBJS)
1246 AC_SUBST(SSRC)
1247 AC_SUBST(DYEXT)
1248 AC_SUBST(MAN_FILE_FORMATS)
1249 AC_SUBST(MAN_MISC_INFO)
1250
1251 dnl check for USB sniffing support
1252 AC_MSG_CHECKING(for USB sniffing support)
1253 case "$host_os" in
1254 linux*)
1255        AC_DEFINE(PCAP_SUPPORT_USB, 1, [target host supports USB sniffing])
1256        USB_SRC=pcap-usb-linux.c
1257        AC_MSG_RESULT(yes)
1258        ac_usb_dev_name=`udevinfo -q name -p /sys/class/usb_device/usbmon 2>/dev/null`
1259        if test $? -ne 0 ; then
1260                ac_usb_dev_name="usbmon"
1261        fi
1262        AC_DEFINE_UNQUOTED(LINUX_USB_MON_DEV, "/dev/$ac_usb_dev_name", [path for device for USB sniffing])
1263        AC_MSG_NOTICE(Device for USB sniffing is /dev/$ac_usb_dev_name)
1264        #
1265        # Do we have a version of <linux/compiler.h> available?
1266        # If so, we might need it for <linux/usbdevice_fs.h>.
1267        #
1268        AC_CHECK_HEADERS(linux/compiler.h)
1269        if test "$ac_cv_header_linux_compiler_h" = yes; then
1270          #
1271          # Yes - include it when testing for <linux/usbdevice_fs.h>.
1272          #
1273          AC_CHECK_HEADERS(linux/usbdevice_fs.h,,,[#include <linux/compiler.h>])
1274        else
1275          AC_CHECK_HEADERS(linux/usbdevice_fs.h)
1276        fi
1277        if test "$ac_cv_header_linux_usbdevice_fs_h" = yes; then
1278          #
1279          # OK, does it define bRequestType?  Older versions of the kernel
1280          # define fields with names like "requesttype, "request", and
1281          # "value", rather than "bRequestType", "bRequest", and
1282          # "wValue".
1283          #
1284          AC_MSG_CHECKING(if usbdevfs_ctrltransfer struct has bRequestType member)
1285          AC_CACHE_VAL(ac_cv_usbdevfs_ctrltransfer_has_bRequestType,
1286            AC_TRY_COMPILE([
1287 AC_INCLUDES_DEFAULT
1288 #ifdef HAVE_SYS_BITYPES_H
1289 #include <sys/bitypes.h>
1290 #endif
1291 #ifdef HAVE_LINUX_COMPILER_H
1292 #include <linux/compiler.h>
1293 #endif
1294 #            include <linux/usbdevice_fs.h>],
1295              [u_int i = sizeof(((struct usbdevfs_ctrltransfer *)0)->bRequestType)],
1296              ac_cv_usbdevfs_ctrltransfer_has_bRequestType=yes,
1297              ac_cv_usbdevfs_ctrltransfer_has_bRequestType=no))
1298          AC_MSG_RESULT($ac_cv_usbdevfs_ctrltransfer_has_bRequestType)
1299          if test $ac_cv_usbdevfs_ctrltransfer_has_bRequestType = yes ; then
1300             AC_DEFINE(HAVE_USBDEVFS_CTRLTRANSFER_BREQUESTTYPE,1,
1301               [if struct usbdevfs_ctrltransfer has bRequestType])
1302          fi
1303        fi
1304        ;;
1305 *)
1306        AC_MSG_RESULT(no)
1307        ;;
1308 esac
1309 AC_SUBST(PCAP_SUPPORT_USB)
1310 AC_SUBST(USB_SRC)
1311
1312 AC_ARG_ENABLE([bluetooth],
1313 [AC_HELP_STRING([--enable-bluetooth],[enable Bluetooth support @<:@default=yes, if support available@:>@])],
1314 ,enable_bluetooth=yes)
1315
1316 if test "x$enable_bluetooth" != "xno" ; then
1317         dnl check for Bluetooth sniffing support
1318         case "$host_os" in
1319         linux*)
1320                AC_CHECK_HEADER(bluetooth/bluetooth.h,
1321                 [
1322                   AC_DEFINE(PCAP_SUPPORT_BT, 1, [target host supports Bluetooth sniffing])
1323                   BT_SRC=pcap-bt-linux.c
1324                   AC_MSG_NOTICE(Bluetooth sniffing is supported)
1325                 ],
1326                 AC_MSG_NOTICE(Bluetooth sniffing is not supported; install bluez-lib devel to enable it)
1327                )
1328                ;;
1329         *)
1330                AC_MSG_NOTICE(no Bluetooth sniffing support implemented for $host_os)
1331                ;;
1332         esac
1333         AC_SUBST(PCAP_SUPPORT_BT)
1334         AC_SUBST(BT_SRC)
1335 fi
1336
1337 AC_ARG_ENABLE([can],
1338 [AC_HELP_STRING([--enable-can],[enable CAN support @<:@default=yes, if support available@:>@])],
1339 ,enable_can=yes)
1340
1341 if test "x$enable_can" != "xno" ; then
1342         dnl check for CAN sniffing support
1343         case "$host_os" in
1344         linux*)
1345                 AC_CHECK_HEADER(linux/can.h,
1346                         [ AC_DEFINE(PCAP_SUPPORT_CAN, 1, [target host supports CAN sniffing])
1347                         CAN_SRC=pcap-can-linux.c
1348                         AC_MSG_NOTICE(CAN sniffing is supported)],
1349                         AC_MSG_NOTICE(CAN sniffing is not supported),
1350                         [#include <sys/socket.h>]
1351                    )
1352                 ;;
1353         *)
1354                 AC_MSG_NOTICE(no CAN sniffing support implemented for $host_os)
1355                 ;;
1356         esac
1357         AC_SUBST(PCAP_SUPPORT_CAN)
1358         AC_SUBST(CAN_SRC)
1359 fi
1360
1361 dnl check for hardware timestamp support
1362 case "$host_os" in
1363 linux*)
1364         AC_CHECK_HEADERS([linux/net_tstamp.h])
1365         ;;
1366 *)
1367         AC_MSG_NOTICE(no hardware timestamp support implemented for $host_os)
1368         ;;
1369 esac
1370
1371 AC_PROG_INSTALL
1372
1373 AC_CONFIG_HEADER(config.h)
1374
1375 AC_OUTPUT(Makefile pcap-filter.manmisc pcap-linktype.manmisc
1376         pcap-tstamp.manmisc pcap-savefile.manfile pcap.3pcap
1377         pcap_compile.3pcap pcap_datalink.3pcap pcap_dump_open.3pcap
1378         pcap_list_datalinks.3pcap pcap_list_tstamp_types.3pcap
1379         pcap_open_dead.3pcap pcap_open_offline.3pcap
1380         pcap_set_tstamp_type.3pcap)
1381
1382 if test -f .devel ; then
1383         make depend
1384 fi
1385 exit 0