The Tcpdump Group git mirrors - libpcap/blob - configure.in

   1 dnl @(#) $Header: /tcpdump/master/libpcap/configure.in,v 1.120.2.4 2005-04-23 22:43:31 guy Exp $ (LBL)
   2 dnl
   3 dnl Copyright (c) 1994, 1995, 1996, 1997
   4 dnl     The Regents of the University of California.  All rights reserved.
   5 dnl
   6 dnl Process this file with autoconf to produce a configure script.
   7 dnl
   8
   9 AC_REVISION($Revision: 1.120.2.4 $)
  10 AC_PREREQ(2.50)
  11 AC_INIT(pcap.c)
  12
  13 AC_CANONICAL_SYSTEM
  14
  15 AC_LBL_C_INIT(V_CCOPT, V_INCLS, V_LIBS)
  16 AC_LBL_C_INLINE
  17 AC_C___ATTRIBUTE__
  18
  19 AC_LBL_CHECK_TYPE(u_int8_t, u_char)
  20 AC_LBL_CHECK_TYPE(u_int16_t, u_short)
  21 AC_LBL_CHECK_TYPE(u_int32_t, u_int)
  22
  23 dnl
  24 dnl libpcap doesn't itself use <sys/ioccom.h>; however, the test program
  25 dnl in "AC_LBL_FIXINCLUDES" in "aclocal.m4" uses it, so we have to
  26 dnl test for it and set "HAVE_SYS_IOCCOM_H" if we have it, otherwise
  27 dnl "AC_LBL_FIXINCLUDES" won't work on some platforms such as Solaris.
  28 dnl
  29 AC_CHECK_HEADERS(sys/ioccom.h sys/sockio.h limits.h)
  30 AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  31 #include <sys/socket.h>])
  32 if test "$ac_cv_header_netinet_if_ether_h" != yes; then
  33         #
  34         # The simple test didn't work.
  35         # Do we need to include <net/if.h> first?
  36         # Unset ac_cv_header_netinet_if_ether_h so we don't
  37         # treat the previous failure as a cached value and
  38         # suppress the next test.
  39         #
  40         AC_MSG_NOTICE([Rechecking with some additional includes])
  41         unset ac_cv_header_netinet_if_ether_h
  42         AC_CHECK_HEADERS(netinet/if_ether.h, , , [#include <sys/types.h>
  43 #include <sys/socket.h>
  44 #include <netinet/in.h>
  45 struct mbuf;
  46 struct rtentry;
  47 #include <net/if.h>])
  48 fi
  49
  50 AC_LBL_FIXINCLUDES
  51
  52 AC_CHECK_FUNCS(strerror strlcpy)
  53
  54 needsnprintf=no
  55 AC_CHECK_FUNCS(vsnprintf snprintf,,
  56         [needsnprintf=yes])
  57 if test $needsnprintf = yes; then
  58         AC_LIBOBJ(snprintf)
  59 fi
  60
  61 #
  62 # Do this before checking for ether_hostton(), as it's a
  63 # "gethostbyname() -ish function".
  64 #
  65 AC_LBL_LIBRARY_NET
  66
  67 #
  68 # You are in a twisty little maze of UN*Xes, all different.
  69 # Some might not have ether_hostton().
  70 # Some might have it, but not declare it in any header file.
  71 # Some might have it, but declare it in <netinet/if_ether.h>.
  72 # Some might have it, but declare it in <netinet/ether.h>
  73 # (And some might have it but document it as something declared in
  74 # <netinet/ethernet.h>, although <netinet/if_ether.h> appears to work.)
  75 #
  76 # Before you is a C compiler.
  77 #
  78 AC_CHECK_FUNCS(ether_hostton)
  79 if test "$ac_cv_func_ether_hostton" = yes; then
  80         #
  81         # OK, we have ether_hostton().  Do we have <netinet/if_ether.h>?
  82         #
  83         if test "$ac_cv_header_netinet_if_ether_h" = yes; then
  84                 #
  85                 # Yes.  Does it declare ether_hostton()?
  86                 #
  87                 AC_CHECK_DECL(ether_hostton,
  88                     [
  89                         AC_DEFINE(NETINET_IF_ETHER_H_DECLARES_ETHER_HOSTTON,,
  90                             [Define to 1 if netinet/if_ether.h declares `ether_hostton'])
  91                     ],,
  92                     [
  93 #include <sys/types.h>
  94 #include <sys/socket.h>
  95 #include <netinet/in.h>
  96 #include <arpa/inet.h>
  97 struct mbuf;
  98 struct rtentry;
  99 #include <net/if.h>
 100 #include <netinet/if_ether.h>
 101                     ])
 102         fi
 103         #
 104         # Did that succeed?
 105         #
 106         if test "$ac_cv_have_decl_ether_hostton" != yes; then
 107                 #
 108                 # No, how about <netinet/ether.h>, as on Linux?
 109                 #
 110                 AC_CHECK_HEADERS(netinet/ether.h)
 111                 if test "$ac_cv_header_netinet_ether_h" = yes; then
 112                         #
 113                         # We have it - does it declare ether_hostton()?
 114                         # Unset ac_cv_have_decl_ether_hostton so we don't
 115                         # treat the previous failure as a cached value and
 116                         # suppress the next test.
 117                         #
 118                         unset ac_cv_have_decl_ether_hostton
 119                         AC_CHECK_DECL(ether_hostton,
 120                             [
 121                                 AC_DEFINE(NETINET_ETHER_H_DECLARES_ETHER_HOSTTON,,
 122                                     [Define to 1 if netinet/ether.h declares `ether_hostton'])
 123                             ],,
 124                             [
 125 #include <netinet/ether.h>
 126                             ])
 127                 fi
 128         fi
 129         #
 130         # Is ether_hostton() declared?
 131         #
 132         if test "$ac_cv_have_decl_ether_hostton" != yes; then
 133                 #
 134                 # No, we'll have to declare it ourselves.
 135                 # Do we have "struct ether_addr"?
 136                 #
 137                 AC_CHECK_TYPES(struct ether_addr,,,
 138                     [
 139 #include <sys/types.h>
 140 #include <sys/socket.h>
 141 #include <netinet/in.h>
 142 #include <arpa/inet.h>
 143 struct mbuf;
 144 struct rtentry;
 145 #include <net/if.h>
 146 #include <netinet/if_ether.h>
 147                     ])
 148                 AC_DEFINE(HAVE_DECL_ETHER_HOSTTON, 0,
 149                     [Define to 1 if you have the declaration of `ether_hostton', and to 0 if you
 150 don't.])
 151         else
 152                 AC_DEFINE(HAVE_DECL_ETHER_HOSTTON, 1,
 153                     [Define to 1 if you have the declaration of `ether_hostton', and to 0 if you
 154 don't.])
 155         fi
 156 fi
 157
 158 dnl to pacify those who hate protochain insn
 159 AC_MSG_CHECKING(if --disable-protochain option is specified)
 160 AC_ARG_ENABLE(protochain, [  --disable-protochain    disable \"protochain\" insn])
 161 case "x$enable_protochain" in
 162 xyes)   enable_protochain=enabled       ;;
 163 xno)    enable_protochain=disabled      ;;
 164 x)      enable_protochain=enabled       ;;
 165 esac
 166
 167 if test "$enable_protochain" = "disabled"; then
 168         AC_DEFINE(NO_PROTOCHAIN,1,[do not use protochain])
 169 fi
 170 AC_MSG_RESULT(${enable_protochain})
 171
 172 dnl
 173 dnl Not all versions of test support -c (character special) but it's a
 174 dnl better way of testing since the device might be protected. So we
 175 dnl check in our normal order using -r and then check the for the /dev
 176 dnl guys again using -c.
 177 dnl
 178 dnl XXX This could be done for cross-compiling, but for now it's not.
 179 dnl
 180 if test -z "$with_pcap" && test "$cross_compiling" = yes; then
 181         AC_MSG_ERROR(pcap type not determined when cross-compiling; use --with-pcap=...)
 182 fi
 183 AC_ARG_WITH(pcap, [  --with-pcap=TYPE        use packet capture TYPE])
 184 AC_MSG_CHECKING(packet capture type)
 185 if test ! -z "$with_pcap" ; then
 186         V_PCAP="$withval"
 187 elif test -r /dev/bpf0 ; then
 188         V_PCAP=bpf
 189 elif test -r /usr/include/net/pfilt.h ; then
 190         V_PCAP=pf
 191 elif test -r /dev/enet ; then
 192         V_PCAP=enet
 193 elif test -r /dev/nit ; then
 194         V_PCAP=snit
 195 elif test -r /usr/include/sys/net/nit.h ; then
 196         V_PCAP=nit
 197 elif test -r /usr/include/linux/socket.h ; then
 198         V_PCAP=linux
 199 elif test -r /usr/include/net/raw.h ; then
 200         V_PCAP=snoop
 201 elif test -r /usr/include/odmi.h ; then
 202         #
 203         # On AIX, the BPF devices might not yet be present - they're
 204         # created the first time libpcap runs after booting.
 205         # We check for odmi.h instead.
 206         #
 207         V_PCAP=bpf
 208 elif test -r /usr/include/sys/dlpi.h ; then
 209         V_PCAP=dlpi
 210 elif test -c /dev/bpf0 ; then           # check again in case not readable
 211         V_PCAP=bpf
 212 elif test -c /dev/enet ; then           # check again in case not readable
 213         V_PCAP=enet
 214 elif test -c /dev/nit ; then            # check again in case not readable
 215         V_PCAP=snit
 216 else
 217         V_PCAP=null
 218 fi
 219 AC_MSG_RESULT($V_PCAP)
 220
 221 dnl
 222 dnl Now figure out how we get a list of interfaces and addresses,
 223 dnl if we support capturing.  Don't bother if we don't support
 224 dnl capturing.
 225 dnl
 226 if test "$V_PCAP" = null
 227 then
 228         #
 229         # We can't capture, so we can't open any capture
 230         # devices, so we won't return any interfaces.
 231         #
 232         V_FINDALLDEVS=null
 233 else
 234         AC_CHECK_FUNC(getifaddrs,[
 235                 #
 236                 # We have "getifaddrs()"; make sure we have <ifaddrs.h>
 237                 # as well, just in case some platform is really weird.
 238                 #
 239                 AC_CHECK_HEADER(ifaddrs.h,[
 240                     #
 241                     # We have the header, so we use "getifaddrs()" to
 242                     # get the list of interfaces.
 243                     #
 244                     V_FINDALLDEVS=getad
 245                 ],[
 246                     #
 247                     # We don't have the header - give up.
 248                     # XXX - we could also fall back on some other
 249                     # mechanism, but, for now, this'll catch this
 250                     # problem so that we can at least try to figure
 251                     # out something to do on systems with "getifaddrs()"
 252                     # but without "ifaddrs.h", if there is something
 253                     # we can do on those systems.
 254                     #
 255                     AC_MSG_ERROR([Your system has getifaddrs() but doesn't have a usable <ifaddrs.h>.])
 256                 ])
 257         ],[
 258                 #
 259                 # Well, we don't have "getifaddrs()", so we have to use
 260                 # some other mechanism; determine what that mechanism is.
 261                 #
 262                 # The first thing we use is the type of capture mechanism,
 263                 # which is somewhat of a proxy for the OS we're using.
 264                 #
 265                 case "$V_PCAP" in
 266
 267                 dlpi)
 268                         #
 269                         # This might be Solaris 8 or later, with
 270                         # SIOCGLIFCONF, or it might be some other OS
 271                         # or some older version of Solaris, with
 272                         # just SIOCGIFCONF.
 273                         #
 274                         AC_MSG_CHECKING(whether we have SIOCGLIFCONF)
 275                         AC_CACHE_VAL(ac_cv_lbl_have_siocglifconf,
 276                             AC_TRY_COMPILE(
 277                                 [#include <sys/param.h>
 278                                 #include <sys/file.h>
 279                                 #include <sys/ioctl.h>
 280                                 #include <sys/socket.h>
 281                                 #include <sys/sockio.h>],
 282                                 [ioctl(0, SIOCGLIFCONF, (char *)0);],
 283                                 ac_cv_lbl_have_siocglifconf=yes,
 284                                 ac_cv_lbl_have_siocglifconf=no))
 285                         AC_MSG_RESULT($ac_cv_lbl_have_siocglifconf)
 286                         if test $ac_cv_lbl_have_siocglifconf = yes ; then
 287                                 V_FINDALLDEVS=glifc
 288                         else
 289                                 V_FINDALLDEVS=gifc
 290                         fi
 291                         ;;
 292
 293                 *)
 294                         #
 295                         # Assume we just have SIOCGIFCONF.
 296                         # (XXX - on at least later Linux kernels, there's
 297                         # another mechanism, and we should be using that
 298                         # instead.)
 299                         #
 300                         V_FINDALLDEVS=gifc
 301                         ;;
 302                 esac])
 303 fi
 304
 305 AC_MSG_CHECKING(if --enable-ipv6 option is specified)
 306 AC_ARG_ENABLE(ipv6, [  --enable-ipv6           build IPv6-capable version])
 307 if test "$enable_ipv6" = "yes"; then
 308         AC_DEFINE(INET6,1,[IPv6])
 309 fi
 310 AC_MSG_RESULT(${enable_ipv6-no})
 311
 312 AC_MSG_CHECKING(whether to build optimizer debugging code)
 313 AC_ARG_ENABLE(optimizer-dbg, [  --enable-optimizer-dbg  build optimizer debugging code])
 314 if test "$enable_optimizer_dbg" = "yes"; then
 315         AC_DEFINE(BDEBUG,1,[Enable optimizer debugging])
 316 fi
 317 AC_MSG_RESULT(${enable_optimizer_dbg-no})
 318
 319 AC_MSG_CHECKING(whether to build parser debugging code)
 320 AC_ARG_ENABLE(yydebug, [  --enable-yydebug        build parser debugging code])
 321 if test "$enable_yydebug" = "yes"; then
 322         AC_DEFINE(YYDEBUG,1,[Enable parser debugging])
 323 fi
 324 AC_MSG_RESULT(${enable_yydebug-no})
 325
 326 case "$V_PCAP" in
 327
 328 dlpi)
 329         AC_CHECK_HEADERS(sys/bufmod.h sys/dlpi_ext.h)
 330         AC_MSG_CHECKING(for /dev/dlpi device)
 331         if test -c /dev/dlpi ; then
 332                 AC_MSG_RESULT(yes)
 333                 AC_DEFINE(HAVE_DEV_DLPI, 1, [define if you have a /dev/dlpi])
 334         else
 335                 AC_MSG_RESULT(no)
 336                 dir="/dev/dlpi"
 337                 AC_MSG_CHECKING(for $dir directory)
 338                 if test -d $dir ; then
 339                         AC_MSG_RESULT(yes)
 340                         AC_DEFINE_UNQUOTED(PCAP_DEV_PREFIX, "$dir", [/dev/dlpi directory])
 341                 else
 342                         AC_MSG_RESULT(no)
 343                 fi
 344         fi
 345         ;;
 346
 347 linux)
 348         AC_MSG_CHECKING(Linux kernel version)
 349         if test "$cross_compiling" = yes; then
 350                 AC_CACHE_VAL(ac_cv_linux_vers,
 351                     ac_cv_linux_vers=unknown)
 352         else
 353                 AC_CACHE_VAL(ac_cv_linux_vers,
 354                     ac_cv_linux_vers=`uname -r 2>&1 | \
 355                         sed -n -e '$s/.* //' -e '$s/\..*//p'`)
 356         fi
 357         AC_MSG_RESULT($ac_cv_linux_vers)
 358         if test $ac_cv_linux_vers = unknown ; then
 359                 AC_MSG_ERROR(cannot determine linux version when cross-compiling)
 360         fi
 361         if test $ac_cv_linux_vers -lt 2 ; then
 362                 AC_MSG_ERROR(version 2 or higher required; see the INSTALL doc for more info)
 363         fi
 364         AC_LBL_TPACKET_STATS
 365         ;;
 366
 367 dag)
 368         V_DEFS="$V_DEFS -DDAG_ONLY"
 369         ;;
 370
 371 null)
 372         AC_MSG_WARN(cannot determine packet capture interface)
 373         AC_MSG_WARN((see the INSTALL doc for more info))
 374         ;;
 375
 376 esac
 377
 378 AC_MSG_CHECKING(whether we have /proc/net/dev)
 379 if test -r /proc/net/dev ; then
 380         ac_cv_lbl_proc_net_dev=yes
 381 else
 382         ac_cv_lbl_proc_net_dev=no
 383 fi
 384 if test $ac_cv_lbl_proc_net_dev = yes; then
 385         AC_DEFINE(HAVE_PROC_NET_DEV, 1, [define if you have a /proc/net/dev])
 386 fi
 387 AC_MSG_RESULT($ac_cv_lbl_proc_net_dev)
 388
 389 # Check for Endace DAG card support.
 390 AC_ARG_WITH([dag], [  --with-dag[[=DIR]]          include Endace DAG support ("yes", "no" or DIR; default="yes" on BSD and Linux if present)],
 391 [
 392         if test "$withval" = no
 393         then
 394                 # User doesn't want DAG support.
 395                 want_dag=no
 396         elif test "$withval" = yes
 397         then
 398                 # User wants DAG support but hasn't specified a directory.
 399                 want_dag=yes
 400         else
 401                 # User wants DAG support and has specified a directory, so use the provided value.
 402                 want_dag=yes
 403                 dag_root=$withval
 404         fi
 405 ],[
 406         #
 407         # Use DAG API if present, otherwise don't
 408         #
 409         want_dag=ifpresent
 410 ])
 411
 412 AC_ARG_WITH([dag-includes], [  --with-dag-includes=DIR   Endace DAG include directory],
 413 [
 414         # User wants DAG support and has specified a header directory, so use the provided value.
 415         want_dag=yes
 416         dag_include_dir=$withval
 417 ],[])
 418
 419 AC_ARG_WITH([dag-libraries], [  --with-dag-libraries=DIR  Endace DAG library directory],
 420 [
 421         # User wants DAG support and has specified a library directory, so use the provided value.
 422         want_dag=yes
 423         dag_lib_dir=$withval
 424 ],[])
 425
 426 case "$V_PCAP" in
 427 linux|bpf|dag)
 428         #
 429         # We support the DAG API on Linux or BSD, or if we're building a
 430         # DAG-only libpcap.
 431         #
 432         ;;
 433 *)
 434         #
 435         # If the user explicitly requested DAG, tell them it's not
 436         # supported.
 437         #
 438         # If they expressed no preference, don't include it.
 439         #
 440         if test $want_dag = yes; then
 441                 AC_MSG_ERROR([DAG support is only available with 'linux' 'bpf' and 'dag' packet capture types])
 442         elif test $want_dag = yes; then
 443                 want_dag=no
 444         fi
 445         ;;
 446 esac
 447
 448 ac_cv_lbl_dag_api=no
 449 if test "$want_dag" != no; then
 450
 451         AC_MSG_CHECKING([whether we have DAG API headers])
 452
 453     # If necessary, set default paths for DAG API headers and libraries.
 454         if test -z "$dag_root"; then
 455             dag_root=/usr/local
 456         fi
 457
 458         if test -z "$dag_include_dir"; then
 459                 dag_include_dir="$dag_root/include"
 460         fi
 461
 462         if test -z "$dag_lib_dir"; then
 463             dag_lib_dir="$dag_root/lib"
 464         fi
 465
 466         if test -z "$dag_tools_dir"; then
 467             dag_tools_dir="$dag_root/tools"
 468                 fi
 469
 470         if test -r $dag_include_dir/dagapi.h; then
 471                 ac_cv_lbl_dag_api=yes
 472         fi
 473     AC_MSG_RESULT([$ac_cv_lbl_dag_api ($dag_include_dir)])
 474 fi
 475
 476 if test $ac_cv_lbl_dag_api = yes; then
 477
 478         AC_MSG_CHECKING([dagapi.o])
 479         dagapi_obj=no
 480         if test -r $dag_tools_dir/dagapi.o; then
 481
 482             # 2.4.x.
 483                 dagapi_obj=$dag_tools_dir/dagapi.o
 484
 485         elif test -r $dag_lib_dir/dagapi.o; then
 486
 487             # 2.5.x.
 488             dagapi_obj=$dag_lib_dir/dagapi.o
 489
 490     elif test -r $dag_lib_dir/libdag.a; then
 491
 492         # 2.5.x.
 493                 ar x $dag_lib_dir/libdag.a dagapi.o
 494                 if test -r ./dagapi.o; then
 495                     dagapi_obj=./dagapi.o
 496                 fi
 497     fi
 498
 499         if test $dagapi_obj = no; then
 500             AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_tools_dir  $dag_lib_dir/libdag.a)])
 501                         ac_cv_lbl_dag_api=no
 502         else
 503                 AC_MSG_RESULT([yes ($dagapi_obj)])
 504                 fi
 505 fi
 506
 507 if test $ac_cv_lbl_dag_api = yes; then
 508
 509         AC_MSG_CHECKING([dagopts.o])
 510         dagopts_obj=no
 511         if test -r $dag_tools_dir/dagopts.o; then
 512
 513             # 2.4.x.
 514                 dagopts_obj=$dag_tools_dir/dagopts.o
 515
 516         elif test -r $dag_lib_dir/dagopts.o; then
 517
 518             # 2.5.x.
 519             dagopts_obj=$dag_lib_dir/dagopts.o
 520
 521     elif test -r $dag_lib_dir/libdag.a; then
 522
 523         # 2.5.x.
 524                 ar x $dag_lib_dir/libdag.a dagopts.o
 525                 if test -r ./dagopts.o; then
 526                     dagopts_obj=./dagopts.o
 527         fi
 528         fi
 529
 530         if test $dagopts_obj = no; then
 531             AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_tools_dir  $dag_lib_dir/libdag.a)])
 532                 ac_cv_lbl_dag_api=no
 533         else
 534                 AC_MSG_RESULT([yes ($dagopts_obj)])
 535         fi
 536 fi
 537
 538 if test $ac_cv_lbl_dag_api = yes; then
 539
 540         # Under 2.5.x only we need to add dagreg.o.
 541         if test -r $dag_include_dir/dagreg.h; then
 542
 543             AC_MSG_CHECKING([dagreg.o])
 544             dagreg_obj=no
 545             if test -r $dag_lib_dir/dagreg.o; then
 546
 547                   # Object file is ready and waiting.
 548                   dagreg_obj=$dag_lib_dir/dagreg.o
 549
 550         elif test -r $dag_lib_dir/libdag.a; then
 551
 552                     # Extract from libdag.a.
 553                         ar x $dag_lib_dir/libdag.a dagreg.o
 554                         if test -r ./dagreg.o; then
 555                             dagreg_obj=./dagreg.o
 556                 fi
 557                 fi
 558
 559                 if test $dagreg_obj = no; then
 560                     AC_MSG_RESULT([no (checked $dag_lib_dir  $dag_lib_dir/libdag.a)])
 561                         ac_cv_lbl_dag_api=no
 562         else
 563                         AC_MSG_RESULT([yes ($dagreg_obj)])
 564                 fi
 565         fi
 566 fi
 567
 568 if test $ac_cv_lbl_dag_api = yes; then
 569
 570         V_INCLS="$V_INCLS -I$dag_include_dir"
 571         V_LIBS="$V_LIBS $dagapi_obj $dagopts_obj $dagreg_obj"
 572         if test $V_PCAP != dag ; then
 573                  SSRC="pcap-dag.c"
 574         fi
 575
 576         # See if we can find a general version string.
 577     # Don't need to save and restore LIBS to prevent -ldag being included if there's a found-action (arg 3).
 578         saved_ldflags=$LDFLAGS
 579         LDFLAGS="-L$dag_lib_dir"
 580         AC_CHECK_LIB([dag], [dag_attach_stream], [dag_version="2.5.x"], [dag_version="2.4.x"])
 581         LDFLAGS=$saved_ldflags
 582
 583         # See if we can find a specific version string.
 584         AC_MSG_CHECKING([the DAG API version])
 585         if test -r "$dag_root/VERSION"; then
 586                 dag_version="`cat $dag_root/VERSION`"
 587         fi
 588     AC_MSG_RESULT([$dag_version])
 589         AC_DEFINE(HAVE_DAG_API, 1, [define if you have the DAG API])
 590 fi
 591
 592 if test $ac_cv_lbl_dag_api = no; then
 593         if test "$want_dag" = yes; then
 594         # User wanted DAG support but we couldn't find it.
 595                 AC_MSG_ERROR([DAG API requested, but not found at $dag_root: use --without-dag])
 596         fi
 597
 598     if test "$V_PCAP" = dag; then
 599             # User requested "dag" capture type but the DAG API wasn't found.
 600             AC_MSG_ERROR([Specifying the capture type as "dag" requires the DAG API to be present; use the --with-dag options to specify the location. (Try "./configure --help" for more information.)])
 601     fi
 602 fi
 603
 604
 605 AC_LBL_LEX_AND_YACC(V_LEX, V_YACC, pcap_)
 606 if test "$V_LEX" = lex ; then
 607 # Some versions of lex can't handle the definitions section of scanner.l .
 608 # Try lexing it and complain if it can't deal.
 609         AC_CACHE_CHECK([for capable lex], tcpdump_cv_capable_lex,
 610                 if lex -t scanner.l > /dev/null 2>&1; then
 611                         tcpdump_cv_capable_lex=yes
 612                 else
 613                         tcpdump_cv_capable_lex=insufficient
 614                 fi)
 615         if test $tcpdump_cv_capable_lex = insufficient ; then
 616                 AC_MSG_ERROR([Your operating system's lex is insufficient to compile
 617  libpcap.  flex is a lex replacement that has many advantages, including
 618  being able to compile libpcap.  For more information, see
 619  http://www.gnu.org/software/flex/flex.html .])
 620         fi
 621 fi
 622
 623 DYEXT="so"
 624 case "$host_os" in
 625
 626 aix*)
 627         dnl Workaround to enable certain features
 628         AC_DEFINE(_SUN,1,[define on AIX to get certain functions])
 629         ;;
 630
 631 hpux9*)
 632         AC_DEFINE(HAVE_HPUX9,1,[on HP-UX 9.x])
 633         ;;
 634
 635 hpux10.0*)
 636         ;;
 637
 638 hpux10.1*)
 639         ;;
 640
 641 hpux*)
 642         dnl HPUX 10.20 and above is similar to HPUX 9, but
 643         dnl not the same....
 644         dnl
 645         dnl XXX - DYEXT should be set to "sl" if this is building
 646         dnl for 32-bit PA-RISC, but should be left as "so" for
 647         dnl 64-bit PA-RISC or, I suspect, IA-64.
 648         AC_DEFINE(HAVE_HPUX10_20_OR_LATER,1,[on HP-UX 10.20 or later])
 649         ;;
 650
 651 sinix*)
 652         AC_MSG_CHECKING(if SINIX compiler defines sinix)
 653         AC_CACHE_VAL(ac_cv_cc_sinix_defined,
 654                 AC_TRY_COMPILE(
 655                     [],
 656                     [int i = sinix;],
 657                     ac_cv_cc_sinix_defined=yes,
 658                     ac_cv_cc_sinix_defined=no))
 659             AC_MSG_RESULT($ac_cv_cc_sinix_defined)
 660             if test $ac_cv_cc_sinix_defined = no ; then
 661                     AC_DEFINE(sinix,1,[on sinix])
 662             fi
 663         ;;
 664
 665 solaris*)
 666         AC_DEFINE(HAVE_SOLARIS,1,[On solaris])
 667         ;;
 668
 669 darwin*)
 670         DYEXT="dylib"
 671         V_CCOPT="$V_CCOPT -fno-common"
 672         ;;
 673 esac
 674
 675 AC_PROG_RANLIB
 676
 677 AC_LBL_DEVEL(V_CCOPT)
 678
 679 AC_LBL_SOCKADDR_SA_LEN
 680
 681 AC_LBL_SOCKADDR_STORAGE
 682
 683 AC_LBL_HP_PPA_INFO_T_DL_MODULE_ID_1
 684
 685 AC_LBL_UNALIGNED_ACCESS
 686
 687 #
 688 # Makefile.in includes rules to generate version.h, so we assume
 689 # that it will be generated if autoconf is used.
 690 #
 691 AC_DEFINE(HAVE_VERSION_H, 1, [define if version.h is generated in the build procedure])
 692
 693 rm -f net
 694 ln -s ${srcdir}/bpf/net net
 695
 696 AC_SUBST(V_CCOPT)
 697 AC_SUBST(V_DEFS)
 698 AC_SUBST(V_INCLS)
 699 AC_SUBST(V_LIBS)
 700 AC_SUBST(V_LEX)
 701 AC_SUBST(V_PCAP)
 702 AC_SUBST(V_FINDALLDEVS)
 703 AC_SUBST(V_RANLIB)
 704 AC_SUBST(V_YACC)
 705 AC_SUBST(SSRC)
 706 AC_SUBST(DYEXT)
 707
 708 AC_PROG_INSTALL
 709
 710 AC_CONFIG_HEADER(config.h)
 711
 712 AC_OUTPUT(Makefile)
 713
 714 if test -f .devel ; then
 715         make depend
 716 fi
 717 exit 0