The Tcpdump Group git mirrors - libpcap/blob - grammar.y

   1 %{
   2 /*
   3  * Copyright (c) 1988, 1989, 1990, 1991, 1992, 1993, 1994, 1995, 1996
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that: (1) source code distributions
   8  * retain the above copyright notice and this paragraph in its entirety, (2)
   9  * distributions including binary code include the above copyright notice and
  10  * this paragraph in its entirety in the documentation or other materials
  11  * provided with the distribution, and (3) all advertising materials mentioning
  12  * features or use of this software display the following acknowledgement:
  13  * ``This product includes software developed by the University of California,
  14  * Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15  * the University nor the names of its contributors may be used to endorse
  16  * or promote products derived from this software without specific prior
  17  * written permission.
  18  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19  * WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21  *
  22  */
  23 #ifndef lint
  24 static const char rcsid[] _U_ =
  25     "@(#) $Header: /tcpdump/master/libpcap/grammar.y,v 1.87 2005-04-19 04:25:01 guy Exp $ (LBL)";
  26 #endif
  27
  28 #ifdef HAVE_CONFIG_H
  29 #include "config.h"
  30 #endif
  31
  32 #ifdef WIN32
  33 #include <pcap-stdinc.h>
  34 #else /* WIN32 */
  35 #include <sys/types.h>
  36 #include <sys/socket.h>
  37 #endif /* WIN32 */
  38
  39 #include <stdlib.h>
  40
  41 #ifndef WIN32
  42 #if __STDC__
  43 struct mbuf;
  44 struct rtentry;
  45 #endif
  46
  47 #include <netinet/in.h>
  48 #endif /* WIN32 */
  49
  50 #include <stdio.h>
  51
  52 #include "pcap-int.h"
  53
  54 #include "gencode.h"
  55 #include "pf.h"
  56 #include <pcap-namedb.h>
  57
  58 #ifdef HAVE_OS_PROTO_H
  59 #include "os-proto.h"
  60 #endif
  61
  62 #define QSET(q, p, d, a) (q).proto = (p),\
  63                          (q).dir = (d),\
  64                          (q).addr = (a)
  65
  66 int n_errors = 0;
  67
  68 static struct qual qerr = { Q_UNDEF, Q_UNDEF, Q_UNDEF, Q_UNDEF };
  69
  70 static void
  71 yyerror(char *msg)
  72 {
  73         ++n_errors;
  74         bpf_error("%s", msg);
  75         /* NOTREACHED */
  76 }
  77
  78 #ifndef YYBISON
  79 int yyparse(void);
  80
  81 int
  82 pcap_parse()
  83 {
  84         return (yyparse());
  85 }
  86 #endif
  87
  88 %}
  89
  90 %union {
  91         int i;
  92         bpf_u_int32 h;
  93         u_char *e;
  94         char *s;
  95         struct stmt *stmt;
  96         struct arth *a;
  97         struct {
  98                 struct qual q;
  99                 int atmfieldtype;
 100                 struct block *b;
 101         } blk;
 102         struct block *rblk;
 103 }
 104
 105 %type   <blk>   expr id nid pid term rterm qid
 106 %type   <blk>   head
 107 %type   <i>     pqual dqual aqual ndaqual
 108 %type   <a>     arth narth
 109 %type   <i>     byteop pname pnum relop irelop
 110 %type   <blk>   and or paren not null prog
 111 %type   <rblk>  other pfvar
 112 %type   <i>     atmtype atmmultitype
 113 %type   <blk>   atmfield
 114 %type   <blk>   atmfieldvalue atmvalue atmlistvalue
 115
 116 %token  DST SRC HOST GATEWAY
 117 %token  NET NETMASK PORT PORTRANGE LESS GREATER PROTO PROTOCHAIN CBYTE
 118 %token  ARP RARP IP SCTP TCP UDP ICMP IGMP IGRP PIM VRRP
 119 %token  ATALK AARP DECNET LAT SCA MOPRC MOPDL
 120 %token  TK_BROADCAST TK_MULTICAST
 121 %token  NUM INBOUND OUTBOUND
 122 %token  PF_IFNAME PF_RSET PF_RNR PF_SRNR PF_REASON PF_ACTION
 123 %token  LINK
 124 %token  GEQ LEQ NEQ
 125 %token  ID EID HID HID6 AID
 126 %token  LSH RSH
 127 %token  LEN
 128 %token  IPV6 ICMPV6 AH ESP
 129 %token  VLAN MPLS
 130 %token  ISO ESIS CLNP ISIS L1 L2 IIH LSP SNP CSNP PSNP
 131 %token  STP
 132 %token  IPX
 133 %token  NETBEUI
 134 %token  LANE LLC METAC BCC SC ILMIC OAMF4EC OAMF4SC
 135 %token  OAM OAMF4 CONNECTMSG METACONNECT
 136 %token  VPI VCI
 137
 138 %type   <s> ID
 139 %type   <e> EID
 140 %type   <e> AID
 141 %type   <s> HID HID6
 142 %type   <i> NUM action reason
 143
 144 %left OR AND
 145 %nonassoc  '!'
 146 %left '|'
 147 %left '&'
 148 %left LSH RSH
 149 %left '+' '-'
 150 %left '*' '/'
 151 %nonassoc UMINUS
 152 %%
 153 prog:     null expr
 154 {
 155         finish_parse($2.b);
 156 }
 157         | null
 158         ;
 159 null:     /* null */            { $$.q = qerr; }
 160         ;
 161 expr:     term
 162         | expr and term         { gen_and($1.b, $3.b); $$ = $3; }
 163         | expr and id           { gen_and($1.b, $3.b); $$ = $3; }
 164         | expr or term          { gen_or($1.b, $3.b); $$ = $3; }
 165         | expr or id            { gen_or($1.b, $3.b); $$ = $3; }
 166         ;
 167 and:      AND                   { $$ = $<blk>0; }
 168         ;
 169 or:       OR                    { $$ = $<blk>0; }
 170         ;
 171 id:       nid
 172         | pnum                  { $$.b = gen_ncode(NULL, (bpf_u_int32)$1,
 173                                                    $$.q = $<blk>0.q); }
 174         | paren pid ')'         { $$ = $2; }
 175         ;
 176 nid:      ID                    { $$.b = gen_scode($1, $$.q = $<blk>0.q); }
 177         | HID '/' NUM           { $$.b = gen_mcode($1, NULL, $3,
 178                                     $$.q = $<blk>0.q); }
 179         | HID NETMASK HID       { $$.b = gen_mcode($1, $3, 0,
 180                                     $$.q = $<blk>0.q); }
 181         | HID                   {
 182                                   /* Decide how to parse HID based on proto */
 183                                   $$.q = $<blk>0.q;
 184                                   $$.b = gen_ncode($1, 0, $$.q);
 185                                 }
 186         | HID6 '/' NUM          {
 187 #ifdef INET6
 188                                   $$.b = gen_mcode6($1, NULL, $3,
 189                                     $$.q = $<blk>0.q);
 190 #else
 191                                   bpf_error("'ip6addr/prefixlen' not supported "
 192                                         "in this configuration");
 193 #endif /*INET6*/
 194                                 }
 195         | HID6                  {
 196 #ifdef INET6
 197                                   $$.b = gen_mcode6($1, 0, 128,
 198                                     $$.q = $<blk>0.q);
 199 #else
 200                                   bpf_error("'ip6addr' not supported "
 201                                         "in this configuration");
 202 #endif /*INET6*/
 203                                 }
 204         | EID                   {
 205                                   $$.b = gen_ecode($1, $$.q = $<blk>0.q);
 206                                   /*
 207                                    * $1 was allocated by "pcap_ether_aton()",
 208                                    * so we must free it now that we're done
 209                                    * with it.
 210                                    */
 211                                   free($1);
 212                                 }
 213         | AID                   {
 214                                   $$.b = gen_acode($1, $$.q = $<blk>0.q);
 215                                   /*
 216                                    * $1 was allocated by "pcap_ether_aton()",
 217                                    * so we must free it now that we're done
 218                                    * with it.
 219                                    */
 220                                   free($1);
 221                                 }
 222         | not id                { gen_not($2.b); $$ = $2; }
 223         ;
 224 not:      '!'                   { $$ = $<blk>0; }
 225         ;
 226 paren:    '('                   { $$ = $<blk>0; }
 227         ;
 228 pid:      nid
 229         | qid and id            { gen_and($1.b, $3.b); $$ = $3; }
 230         | qid or id             { gen_or($1.b, $3.b); $$ = $3; }
 231         ;
 232 qid:      pnum                  { $$.b = gen_ncode(NULL, (bpf_u_int32)$1,
 233                                                    $$.q = $<blk>0.q); }
 234         | pid
 235         ;
 236 term:     rterm
 237         | not term              { gen_not($2.b); $$ = $2; }
 238         ;
 239 head:     pqual dqual aqual     { QSET($$.q, $1, $2, $3); }
 240         | pqual dqual           { QSET($$.q, $1, $2, Q_DEFAULT); }
 241         | pqual aqual           { QSET($$.q, $1, Q_DEFAULT, $2); }
 242         | pqual PROTO           { QSET($$.q, $1, Q_DEFAULT, Q_PROTO); }
 243         | pqual PROTOCHAIN      { QSET($$.q, $1, Q_DEFAULT, Q_PROTOCHAIN); }
 244         | pqual ndaqual         { QSET($$.q, $1, Q_DEFAULT, $2); }
 245         ;
 246 rterm:    head id               { $$ = $2; }
 247         | paren expr ')'        { $$.b = $2.b; $$.q = $1.q; }
 248         | pname                 { $$.b = gen_proto_abbrev($1); $$.q = qerr; }
 249         | arth relop arth       { $$.b = gen_relation($2, $1, $3, 0);
 250                                   $$.q = qerr; }
 251         | arth irelop arth      { $$.b = gen_relation($2, $1, $3, 1);
 252                                   $$.q = qerr; }
 253         | other                 { $$.b = $1; $$.q = qerr; }
 254         | atmtype               { $$.b = gen_atmtype_abbrev($1); $$.q = qerr; }
 255         | atmmultitype          { $$.b = gen_atmmulti_abbrev($1); $$.q = qerr; }
 256         | atmfield atmvalue     { $$.b = $2.b; $$.q = qerr; }
 257         ;
 258 /* protocol level qualifiers */
 259 pqual:    pname
 260         |                       { $$ = Q_DEFAULT; }
 261         ;
 262 /* 'direction' qualifiers */
 263 dqual:    SRC                   { $$ = Q_SRC; }
 264         | DST                   { $$ = Q_DST; }
 265         | SRC OR DST            { $$ = Q_OR; }
 266         | DST OR SRC            { $$ = Q_OR; }
 267         | SRC AND DST           { $$ = Q_AND; }
 268         | DST AND SRC           { $$ = Q_AND; }
 269         ;
 270 /* address type qualifiers */
 271 aqual:    HOST                  { $$ = Q_HOST; }
 272         | NET                   { $$ = Q_NET; }
 273         | PORT                  { $$ = Q_PORT; }
 274         | PORTRANGE             { $$ = Q_PORTRANGE; }
 275         ;
 276 /* non-directional address type qualifiers */
 277 ndaqual:  GATEWAY               { $$ = Q_GATEWAY; }
 278         ;
 279 pname:    LINK                  { $$ = Q_LINK; }
 280         | IP                    { $$ = Q_IP; }
 281         | ARP                   { $$ = Q_ARP; }
 282         | RARP                  { $$ = Q_RARP; }
 283         | SCTP                  { $$ = Q_SCTP; }
 284         | TCP                   { $$ = Q_TCP; }
 285         | UDP                   { $$ = Q_UDP; }
 286         | ICMP                  { $$ = Q_ICMP; }
 287         | IGMP                  { $$ = Q_IGMP; }
 288         | IGRP                  { $$ = Q_IGRP; }
 289         | PIM                   { $$ = Q_PIM; }
 290         | VRRP                  { $$ = Q_VRRP; }
 291         | ATALK                 { $$ = Q_ATALK; }
 292         | AARP                  { $$ = Q_AARP; }
 293         | DECNET                { $$ = Q_DECNET; }
 294         | LAT                   { $$ = Q_LAT; }
 295         | SCA                   { $$ = Q_SCA; }
 296         | MOPDL                 { $$ = Q_MOPDL; }
 297         | MOPRC                 { $$ = Q_MOPRC; }
 298         | IPV6                  { $$ = Q_IPV6; }
 299         | ICMPV6                { $$ = Q_ICMPV6; }
 300         | AH                    { $$ = Q_AH; }
 301         | ESP                   { $$ = Q_ESP; }
 302         | ISO                   { $$ = Q_ISO; }
 303         | ESIS                  { $$ = Q_ESIS; }
 304         | ISIS                  { $$ = Q_ISIS; }
 305         | L1                    { $$ = Q_ISIS_L1; }
 306         | L2                    { $$ = Q_ISIS_L2; }
 307         | IIH                   { $$ = Q_ISIS_IIH; }
 308         | LSP                   { $$ = Q_ISIS_LSP; }
 309         | SNP                   { $$ = Q_ISIS_SNP; }
 310         | PSNP                  { $$ = Q_ISIS_PSNP; }
 311         | CSNP                  { $$ = Q_ISIS_CSNP; }
 312         | CLNP                  { $$ = Q_CLNP; }
 313         | STP                   { $$ = Q_STP; }
 314         | IPX                   { $$ = Q_IPX; }
 315         | NETBEUI               { $$ = Q_NETBEUI; }
 316         ;
 317 other:    pqual TK_BROADCAST    { $$ = gen_broadcast($1); }
 318         | pqual TK_MULTICAST    { $$ = gen_multicast($1); }
 319         | LESS NUM              { $$ = gen_less($2); }
 320         | GREATER NUM           { $$ = gen_greater($2); }
 321         | CBYTE NUM byteop NUM  { $$ = gen_byteop($3, $2, $4); }
 322         | INBOUND               { $$ = gen_inbound(0); }
 323         | OUTBOUND              { $$ = gen_inbound(1); }
 324         | VLAN pnum             { $$ = gen_vlan($2); }
 325         | VLAN                  { $$ = gen_vlan(-1); }
 326         | MPLS pnum             { $$ = gen_mpls($2); }
 327         | MPLS                  { $$ = gen_mpls(-1); }
 328         | pfvar                 { $$ = $1; }
 329         ;
 330
 331 pfvar:    PF_IFNAME ID          { $$ = gen_pf_ifname($2); }
 332         | PF_RSET ID            { $$ = gen_pf_ruleset($2); }
 333         | PF_RNR NUM            { $$ = gen_pf_rnr($2); }
 334         | PF_SRNR NUM           { $$ = gen_pf_srnr($2); }
 335         | PF_REASON reason      { $$ = gen_pf_reason($2); }
 336         | PF_ACTION action      { $$ = gen_pf_action($2); }
 337         ;
 338
 339 reason:   NUM                   { $$ = $1; }
 340         | ID                    { const char *reasons[] = PFRES_NAMES;
 341                                   int i;
 342                                   for (i = 0; reasons[i]; i++) {
 343                                           if (pcap_strcasecmp($1, reasons[i]) == 0) {
 344                                                   $$ = i;
 345                                                   break;
 346                                           }
 347                                   }
 348                                   if (reasons[i] == NULL)
 349                                           bpf_error("unknown PF reason");
 350                                 }
 351         ;
 352
 353 action:   ID                    { if (pcap_strcasecmp($1, "pass") == 0 ||
 354                                       pcap_strcasecmp($1, "accept") == 0)
 355                                         $$ = PF_PASS;
 356                                   else if (pcap_strcasecmp($1, "drop") == 0 ||
 357                                       pcap_strcasecmp($1, "block") == 0)
 358                                         $$ = PF_DROP;
 359                                   else
 360                                           bpf_error("unknown PF action");
 361                                 }
 362         ;
 363
 364 relop:    '>'                   { $$ = BPF_JGT; }
 365         | GEQ                   { $$ = BPF_JGE; }
 366         | '='                   { $$ = BPF_JEQ; }
 367         ;
 368 irelop:   LEQ                   { $$ = BPF_JGT; }
 369         | '<'                   { $$ = BPF_JGE; }
 370         | NEQ                   { $$ = BPF_JEQ; }
 371         ;
 372 arth:     pnum                  { $$ = gen_loadi($1); }
 373         | narth
 374         ;
 375 narth:    pname '[' arth ']'            { $$ = gen_load($1, $3, 1); }
 376         | pname '[' arth ':' NUM ']'    { $$ = gen_load($1, $3, $5); }
 377         | arth '+' arth                 { $$ = gen_arth(BPF_ADD, $1, $3); }
 378         | arth '-' arth                 { $$ = gen_arth(BPF_SUB, $1, $3); }
 379         | arth '*' arth                 { $$ = gen_arth(BPF_MUL, $1, $3); }
 380         | arth '/' arth                 { $$ = gen_arth(BPF_DIV, $1, $3); }
 381         | arth '&' arth                 { $$ = gen_arth(BPF_AND, $1, $3); }
 382         | arth '|' arth                 { $$ = gen_arth(BPF_OR, $1, $3); }
 383         | arth LSH arth                 { $$ = gen_arth(BPF_LSH, $1, $3); }
 384         | arth RSH arth                 { $$ = gen_arth(BPF_RSH, $1, $3); }
 385         | '-' arth %prec UMINUS         { $$ = gen_neg($2); }
 386         | paren narth ')'               { $$ = $2; }
 387         | LEN                           { $$ = gen_loadlen(); }
 388         ;
 389 byteop:   '&'                   { $$ = '&'; }
 390         | '|'                   { $$ = '|'; }
 391         | '<'                   { $$ = '<'; }
 392         | '>'                   { $$ = '>'; }
 393         | '='                   { $$ = '='; }
 394         ;
 395 pnum:     NUM
 396         | paren pnum ')'        { $$ = $2; }
 397         ;
 398 atmtype: LANE                   { $$ = A_LANE; }
 399         | LLC                   { $$ = A_LLC; }
 400         | METAC                 { $$ = A_METAC; }
 401         | BCC                   { $$ = A_BCC; }
 402         | OAMF4EC               { $$ = A_OAMF4EC; }
 403         | OAMF4SC               { $$ = A_OAMF4SC; }
 404         | SC                    { $$ = A_SC; }
 405         | ILMIC                 { $$ = A_ILMIC; }
 406         ;
 407 atmmultitype: OAM               { $$ = A_OAM; }
 408         | OAMF4                 { $$ = A_OAMF4; }
 409         | CONNECTMSG            { $$ = A_CONNECTMSG; }
 410         | METACONNECT           { $$ = A_METACONNECT; }
 411         ;
 412         /* ATM field types quantifier */
 413 atmfield: VPI                   { $$.atmfieldtype = A_VPI; }
 414         | VCI                   { $$.atmfieldtype = A_VCI; }
 415         ;
 416 atmvalue: atmfieldvalue
 417         | relop NUM             { $$.b = gen_atmfield_code($<blk>0.atmfieldtype, (u_int)$2, (u_int)$1, 0); }
 418         | irelop NUM            { $$.b = gen_atmfield_code($<blk>0.atmfieldtype, (u_int)$2, (u_int)$1, 1); }
 419         | paren atmlistvalue ')' { $$.b = $2.b; $$.q = qerr; }
 420         ;
 421 atmfieldvalue: NUM {
 422         $$.atmfieldtype = $<blk>0.atmfieldtype;
 423         if ($$.atmfieldtype == A_VPI ||
 424             $$.atmfieldtype == A_VCI)
 425                 $$.b = gen_atmfield_code($$.atmfieldtype, (u_int) $1, BPF_JEQ, 0);
 426         }
 427         ;
 428 atmlistvalue: atmfieldvalue
 429         | atmlistvalue or atmfieldvalue { gen_or($1.b, $3.b); $$ = $3; }
 430         ;
 431 %%