The Tcpdump Group git mirrors - libpcap/blob - testprogs/CMakeLists.txt

   1 if(MSVC)
   2   file(GLOB PROJECT_SOURCE_LIST_WIN32_C ${pcap_SOURCE_DIR}/missing/getopt.c)
   3   include_directories(${pcap_SOURCE_DIR}/missing)
   4 endif(MSVC)
   5
   6 add_custom_target(testprogs)
   7
   8 macro(add_test_executable _executable)
   9   add_executable(${_executable} EXCLUDE_FROM_ALL
  10     ${_executable}.c ${PROJECT_SOURCE_LIST_WIN32_C})
  11   if(NOT C_ADDITIONAL_FLAGS STREQUAL "")
  12     set_target_properties(${_executable} PROPERTIES
  13       COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})
  14   endif()
  15   if(WIN32)
  16     target_link_libraries(${_executable}
  17       ${ARGN} ${LIBRARY_NAME} ${PCAP_LINK_LIBRARIES})
  18   else(WIN32)
  19     target_link_libraries(${_executable}
  20       ${ARGN} ${LIBRARY_NAME}_static ${PCAP_LINK_LIBRARIES})
  21   endif(WIN32)
  22   if(NOT "${SANITIZER_FLAGS}" STREQUAL "")
  23     set_target_properties(${_executable} PROPERTIES
  24         LINK_FLAGS "${SANITIZER_FLAGS}")
  25   endif()
  26   add_dependencies(testprogs ${_executable})
  27 endmacro()
  28
  29 add_test_executable(can_set_rfmon_test)
  30 add_test_executable(capturetest)
  31 add_test_executable(filtertest)
  32 add_test_executable(findalldevstest)
  33 add_test_executable(opentest)
  34 add_test_executable(reactivatetest)
  35
  36 if(NOT WIN32)
  37   add_test_executable(selpolltest)
  38 endif()
  39
  40 add_test_executable(threadsignaltest ${CMAKE_THREAD_LIBS_INIT})
  41
  42 if(NOT WIN32)
  43   add_test_executable(valgrindtest)
  44 endif()
  45
  46 add_subdirectory(fuzz)