build.gradle

/*
 * Copyright 2024 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'com.android.application'
apply plugin: 'org.jetbrains.kotlin.android'
apply plugin: 'com.google.android.libraries.mapsplatform.secrets-gradle-plugin'

ext {
    androidxLifecycleVersion = "2.6.2"
    glideVersion = "4.13.2"
    navSdkVersion = "7.9.0"
}

android {
    namespace 'com.example.navigationapidemo'
    compileSdk 36

    buildFeatures {
        buildConfig true
    }

    defaultConfig {
        applicationId "com.example.navigationapidemo"
        // Navigation SDK supports a minimum of SDK 24.
        minSdkVersion 24
        targetSdkVersion 36
        versionCode 1
        versionName "1.0"
        // Set this to the languages you actually use, otherwise you'll include resource strings
        // for all Navigation SDK supported languages.
        resConfigs "en"
    }

    dexOptions {
        // This increases the amount of memory available to the dexer. This is required to build
        // apps using the Navigation SDK.
        javaMaxHeapSize "4g"
    }
    buildTypes {
        // Run proguard. Note that the Navigation SDK includes its own proguard config, and that
        // will be included transitively by depending on the Navigation SDK.
        // If the proguard step takes too long, consider enabling multidex for development work
        // instead.
        all {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        coreLibraryDesugaringEnabled true
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }

    kotlinOptions {
        jvmTarget = "11"
    }
}

// This tells gradle where to look to find additional libraries
repositories {
    google()
}

dependencies {
    // Include the Google Navigation SDK.
    // Note: remember to exclude Google play service Maps SDK from your transitive
    // dependencies to avoid duplicate copies of the Google Maps SDK.
    api "com.google.android.libraries.navigation:navigation:${navSdkVersion}"

    // Add: android.useDeprecatedNdk=true
    // to local.properties.
    api "org.chromium.net:cronet-fallback:119.6045.31"
    // Optional for Cronet users:
    // api "org.chromium.net:cronet-api:69.3497.100"

    // Add LeakCanary to debugImplementation because LeakCanary should only run
    // in debug builds.
    debugImplementation 'com.squareup.leakcanary:leakcanary-android:2.14'

    // And dependencies.
    api "androidx.appcompat:appcompat:1.7.1"
    api "androidx.cardview:cardview:1.0.0"
    api "androidx.constraintlayout:constraintlayout:2.1.4"
    api "androidx.customview:customview:1.1.0"
    api "androidx.legacy:legacy-support-v4:1.0.0"
    api "androidx.lifecycle:lifecycle-common-java8:${androidxLifecycleVersion}"
    api "androidx.lifecycle:lifecycle-process:${androidxLifecycleVersion}"
    api "androidx.mediarouter:mediarouter:1.4.0"
    api "androidx.preference:preference:1.2.1"
    api "androidx.recyclerview:recyclerview:1.3.1"
    api "androidx.tracing:tracing:1.1.0"
    api "androidx.transition:transition:1.5.1"
    api "androidx.viewpager2:viewpager2:1.0.0"
    api "androidx.window:window:1.1.0"
    api "com.github.bumptech.glide:glide:${glideVersion}"
    api "com.google.android.datatransport:transport-api:3.0.0"
    api "com.google.android.datatransport:transport-backend-cct:3.1.4"
    api "com.google.android.datatransport:transport-runtime:3.1.4"
    api "joda-time:joda-time:2.10.14"
    // Also include the Google Places SDK, which is used by this example, but
    // isn't required by the Navigation SDK.
    api "com.google.android.libraries.places:places:4.0.0"
    api "com.google.android.material:material:1.12.0"
    api 'org.jetbrains.kotlin:kotlin-reflect:2.3.0'
    api 'org.jetbrains.kotlin:kotlin-stdlib:2.3.0'
    api 'com.google.guava:guava:31.0.1-android'

    annotationProcessor "androidx.annotation:annotation:1.7.0"
    annotationProcessor "com.github.bumptech.glide:compiler:${glideVersion}"
    coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs_nio:2.1.5'
}

secrets {
    // To add your Maps API key to this project:
    // 1. Open the root project's local.properties file
    // 2. Add this line, where YOUR_API_KEY is your API key:
    //        MAPS_API_KEY=YOUR_API_KEY
    defaultPropertiesFileName 'local.defaults.properties'
}