Better vcpkg support (ptsouchlos#45)

Use cmake directly to install library instead of PackageProject

Author: Paul T

.github/workflows/install.yml

@@ -35,12 +35,12 @@ jobs:
 
       - name: build and install library
         run: |
-          cmake -S. -Bbuild -DCMAKE_BUILD_TYPE=Release -DTP_BUILD_EXAMPLES=OFF -DTP_BUILD_TESTS=ON -DTP_BUILD_BENCHMARKS=OFF
+          cmake -S. -Bbuild -DCMAKE_BUILD_TYPE=Release -DTP_BUILD_EXAMPLES=OFF -DTP_BUILD_TESTS=ON -DTP_BUILD_BENCHMARKS=OFF -DCMAKE_INSTALL_PREFIX="/usr/local"
           sudo cmake --build build --target install
           rm -rf build
 
       - name: configure
-        run: cmake -Stest -Bbuild -DTEST_INSTALLED_VERSION=1
+        run: cmake -Stest -Bbuild -DTEST_INSTALLED_VERSION=1 -Dthread-pool_DIR="/usr/local/lib/cmake/thread-pool-0.6.0/"
 
       - name: build
         run: cmake --build build --config Debug -j4

CMakeLists.txt

@@ -4,7 +4,7 @@ cmake_minimum_required(VERSION 3.19 FATAL_ERROR)
 
 # Note: update this to your new project's name and version
 project(
-    ThreadPool
+    thread-pool
     VERSION 0.6.0
     LANGUAGES CXX
 )
@@ -56,21 +56,17 @@ if(PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR)
     )
 endif()
 
-# ---- Add dependencies via CPM ----
 # see https://github.com/TheLartians/CPM.cmake for more info
 include(cmake/CPM.cmake)
 
-# PackageProject.cmake will be used to make our target installable
-CPMAddPackage("gh:TheLartians/[email protected]")
-
-# ---- Add source files ----
+# add source files
 file(GLOB_RECURSE headers CONFIGURE_DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/include/*.h")
 
 find_package(Threads REQUIRED)
 
 # ---- Create library ----
 add_library(${PROJECT_NAME} INTERFACE)
-add_library(dp::thread-pool ALIAS ${PROJECT_NAME})
+add_library(dp::${PROJECT_NAME} ALIAS ${PROJECT_NAME})
 
 target_link_libraries(${PROJECT_NAME} INTERFACE Threads::Threads)
 
@@ -83,31 +79,62 @@ endif()
 # being a cross-platform target, we enforce standards conformance on MSVC
 target_compile_options(${PROJECT_NAME} INTERFACE $<$<COMPILE_LANG_AND_ID:CXX,MSVC>:/permissive->)
 
-target_include_directories(
-    ${PROJECT_NAME} INTERFACE $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
-                              $<INSTALL_INTERFACE:include/${PROJECT_NAME}-${PROJECT_VERSION}>
-)
-
-# ---- Create an installable target ----
-# this allows users to install and find the library via `find_package()`.
-
 # the location where the project's version header will be placed should match the project's regular
 # header paths here we get the root folder of the include directory but getting the directory name
 # from one of the headers paths
 list(GET headers 0 first_header)
 get_filename_component(include_dir_path ${first_header} DIRECTORY)
 get_filename_component(include_dir_name ${include_dir_path} NAME)
-string(TOLOWER ${include_dir_name}/version.h VERSION_HEADER_LOCATION)
-packageProject(
-    NAME ${PROJECT_NAME}
-    VERSION ${PROJECT_VERSION}
-    NAMESPACE ${PROJECT_NAME}
-    BINARY_DIR ${PROJECT_BINARY_DIR}
-    INCLUDE_DIR ${PROJECT_SOURCE_DIR}/include
-    INCLUDE_DESTINATION include/${PROJECT_NAME}-${PROJECT_VERSION}
-    VERSION_HEADER "${VERSION_HEADER_LOCATION}"
-    COMPATIBILITY SameMajorVersion
-    DEPENDENCIES "Threads" ARCH_INDEPENDENT YES
+
+configure_file(
+    ${PROJECT_SOURCE_DIR}/cmake/version.h.in ${PROJECT_BINARY_DIR}/include/thread_pool/version.h
+    @ONLY
+)
+
+target_include_directories(
+    ${PROJECT_NAME}
+    INTERFACE $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
+              $<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/include>
+              $<INSTALL_INTERFACE:include/${PROJECT_NAME}-${PROJECT_VERSION}>
+)
+
+# ---- Create an installable target ----
+# this allows users to install and find the library via `find_package()`.
+
+include(CMakePackageConfigHelpers)
+include(GNUInstallDirs)
+
+# Installation help
+configure_package_config_file(
+    "${PROJECT_SOURCE_DIR}/cmake/${PROJECT_NAME}-config.cmake.in"
+    "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config.cmake"
+    INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}-${PROJECT_VERSION}"
+)
+
+write_basic_package_version_file(
+    "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake" COMPATIBILITY SameMajorVersion
+                                                                               ARCH_INDEPENDENT
+)
+
+install(TARGETS ${PROJECT_NAME} EXPORT ${PROJECT_NAME}-targets)
+
+install(
+    EXPORT ${PROJECT_NAME}-targets
+    NAMESPACE dp::
+    DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}-${PROJECT_VERSION}"
+    FILE "${PROJECT_NAME}-targets.cmake"
+)
+
+install(FILES "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config.cmake"
+              "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake"
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}-${PROJECT_VERSION}
+)
+
+install(FILES ${headers}
+        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}-${PROJECT_VERSION}/thread_pool
+)
+install(FILES ${PROJECT_BINARY_DIR}/include/thread_pool/version.h
+        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}-${PROJECT_VERSION}/thread_pool
 )
 
 option(TP_BUILD_TESTS "Turn on to build unit tests." ON)

CMakePresets.json

@@ -7,7 +7,6 @@
       "description": "Target the Windows Subsystem for Linux (WSL) or a remote Linux system.",
       "generator": "Ninja",
       "binaryDir": "${sourceDir}/out/build/${presetName}",
-      "installDir": "${sourceDir}/out/install/${presetName}",
       "condition": {
         "type": "equals",
         "lhs": "${hostSystemName}",

benchmark/CMakeLists.txt

@@ -1,6 +1,6 @@
 cmake_minimum_required(VERSION 3.19 FATAL_ERROR)
 
-project(ThreadPoolBenchmarks LANGUAGES CXX)
+project(thread-pool-benchmarks LANGUAGES CXX)
 
 # --- Import tools ----
 include(../cmake/tools.cmake)

cmake/thread-pool-config.cmake.in

@@ -0,0 +1,6 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/thread-pool-targets.cmake")
+
+include(CMakeFindDependencyMacro)
+find_dependency(Threads REQUIRED)

cmake/version.h.in

@@ -0,0 +1,8 @@
+#pragma once
+
+#define THREADPOOL_VERSION "@PROJECT_VERSION@"
+
+#define THREADPOOL_VERSION_MAJOR @PROJECT_VERSION_MAJOR@
+#define THREADPOOL_VERSION_MINOR @PROJECT_VERSION_MINOR@
+#define THREADPOOL_VERSION_PATCH @PROJECT_VERSION_PATCH@
+#define THREADPOOL_VERSION_TWEAK @PROJECT_VERSION_TWEAK@

test/CMakeLists.txt

@@ -1,6 +1,6 @@
 cmake_minimum_required(VERSION 3.19 FATAL_ERROR)
 
-project(ThreadPoolTests LANGUAGES CXX)
+project(thread-pool-tests LANGUAGES CXX)
 
 # ---- Options ----
 option(TEST_INSTALLED_VERSION "Test the version found by find_package" OFF)
@@ -26,15 +26,16 @@ CPMAddPackage(
 )
 
 if(TEST_INSTALLED_VERSION)
+    # testing the installed version, so we assume this is the top level CMakeLists.txt
     enable_testing()
-    find_package(ThreadPool REQUIRED)
+    find_package(thread-pool REQUIRED)
 endif()
 
 # ---- Create binary ----
 
 file(GLOB sources CONFIGURE_DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/source/*.cpp)
 add_executable(${PROJECT_NAME} ${sources})
-target_link_libraries(${PROJECT_NAME} doctest::doctest ThreadPool::ThreadPool)
+target_link_libraries(${PROJECT_NAME} doctest::doctest dp::thread-pool)
 
 target_compile_options(
     ${PROJECT_NAME} INTERFACE $<$<COMPILE_LANG_AND_ID:CXX,MSVC>:/fsanitize=address>