title Block Faker
author Droqen
homepage www.droqen.com

require_player_movement
key_repeat_interval 0.2

background_color white
text_color black

gradient_top white
gradient_middle lightgrey
gradient_bottom white

color_palette c64
(
A port of first several levels of Droqen's beautiful game:

http://dl.dropboxusercontent.com/u/4452540/locklake/index.html

(his game has secrets that this one does not)

)

(3D Modifications by Farbs. I hope you don't mind.)

========
OBJECTS
========

Background
White

Grille
voxel
LightGrey
.
&
.
&
.
&
.
&
.
&
.
&
0...0
.0.0.
..0..
.0.0.
0...0

EndPoint
Green

Player
transparent
.

Wall
wall
Gray

WallBlock
voxel
DarkGrey
.
&
.
&
.
&
.
&
.
&
.
&
0

BlueBlock
voxel
throw
Blue
...
...
...
&
...
...
...
&
...
.0.
...

GreenBlock
voxel
throw
LightGreen
...
...
...
&
...
...
...
&
...
.0.
...

PinkBlock
voxel
throw
Red
...
...
...
&
...
...
...
&
...
.0.
...


PurpleBlock
voxel
throw
Purple
...
...
...
&
...
...
...
&
...
.0.
...


OrangeBlock
voxel
throw
Orange
...
...
...
&
...
...
...
&
...
.0.
...



=======
LEGEND
=======

Block = PinkBlock or BlueBlock or PurpleBlock or OrangeBlock or GreenBlock
Moveable = Player or Block
PlayerObstacle = Block or Wall or WallBlock
BlockObstacle = Player or Wall or WallBlock or Grille or Block or EndPoint
. = Background
# = Wall
@ = WallBlock
P = Player
B = BlueBlock
G = GreenBLock
K = PinkBlock
R = PurpleBlock
O = OrangeBlock
E = EndPoint
x = Grille
H = Grille and Player


=========
SOUNDS
=========

================
COLLISIONLAYERS
================

Background
EndPoint
Grille
Player, Wall, WallBlock, PinkBlock, BlueBlock, PurpleBlock, OrangeBlock, GreenBlock

======
RULES
======

[ >  Moveable | Moveable ] -> [ > Moveable | > Moveable ]

[ > Block | Grille ] -> [ Block | Grille ]

late [ PinkBlock | PinkBlock | PinkBlock ] -> [ | | ]
late [ BlueBlock | BlueBlock | BlueBlock ] -> [ | | ]
late [ PurpleBlock | PurpleBlock | PurpleBlock ] -> [ | | ]
late [ OrangeBlock | OrangeBlock | OrangeBlock ] -> [ | | ]
late [ GreenBlock | GreenBlock | GreenBlock ] -> [ | | ]

==============
WINCONDITIONS
==============
some player on endpoint
=======
LEVELS
=======

........########
################
########@@@@@###
####@@@@@...@###
###@..OO....@@##
##@..@@@@@....@#
##@.@..@@@..E@@#
#@..@.O...@@@@##
##@...@.P.######
####@.@@@@######
####@@##########
########........

message congrats: level 2!

##########
####R.R###
#x....#x##
#xO#O.OxE#
#xx##.#xx#
#####R####
#####P####
O#########

message congrats: level 3!

......#######...
.....##P.#####..
....###....####.
..#####O...#B..#
..#####.#.##BB.#
##EBB..O.O.....#
..#####.#.#....#
..######..#G.###
....####..#.OOx.
.....###.GG.#x..
......#######...

message congrats: level 4!

######xx######
######GG######
##xx#...#xEx##
##..O...#x..##
##..#...##O###
#..##.......##
xG....##....Gx
xG....##....Gx
##.......GG###
###G##...#xx##
##x..#...O.x##
##.P.#...#xx##
######GG######
######xx######

message congrats: level 5!

......##......
....######....
..##########..
..#.OG..kk.#..
.##OPO..Gkk##.
.##GOG..GGk##.
###...##...###
###...##...###
.##kkG##ROR##.
.##Gkk..OEO##.
..#.Gk..RO.#..
..##########..
....######....
......##......

message now go play the real game
