title Several Rigid Bodies
author Stephen Lavelle
homepage www.puzzlescript.net

========
OBJECTS
========

Background
darkgreen

Target
YELLOW

Player
PINK

RedCrate q
RED

GreenCrate w
Green

BlueCrate e
Blue

SmallCrate r
Purple
.....
.000.
.000.
.000.
.....

Wall
DARKBROWN

=======
LEGEND
=======

. = Background
# = Wall
P = Player
bigcrate = redcrate or greencrate or bluecrate
Crate = smallcrate or bigcrate
O = Target

=========
SOUNDS
=========

================
COLLISIONLAYERS
================

Background
Target
Player, Wall, Crate

======
RULES
======

startloop

[ > Player | Smallcrate ] -> [ > Player | > SmallCrate ]

[ >  Player | RedCrate ] -> [  >  Player | > RedCrate  ]
+ rigid [ moving RedCrate | RedCrate ] -> [ moving RedCrate | moving RedCrate ]
+ [ >  Crate | RedCrate ] -> [  >  Crate | > RedCrate  ]

[ >  Player | GreenCrate ] -> [  >  Player | > GreenCrate  ]
+ rigid [ moving GreenCrate | GreenCrate ] -> [ moving GreenCrate | moving GreenCrate ]
+ [ >  Crate | GreenCrate ] -> [  >  Crate | > GreenCrate  ]


[ >  Player | BlueCrate ] -> [  >  Player | > BlueCrate  ]
+ rigid [ moving BlueCrate | BlueCrate ] -> [ moving BlueCrate | moving BlueCrate ]
+ [ >  Crate | BlueCrate ] -> [  >  Crate | > BlueCrate  ]

[ > Crate | SmallCrate ] -> [  > Crate | > SmallCrate ]

endloop

==============
WINCONDITIONS
==============

=======
LEVELS
=======

...............
...............
...............
.....#.........
...............
...r.r.........
..P....#.......
..qq..w.eer....
..q.wwweer.....
..q.#..........
...............
...............
...............

