title Ponies Jumping Synchronously
author vytah

background_color #990044
text_color white

========
OBJECTS
========


Background  (special, automatically placed in its own layer)
lightblue

JumpVariableA
lightblue
0...0
.000.
.0.0.
.000.
0...0

JumpVariableA1
lightblue
0...0
..0..
..0..
..0..
0...0

JumpVariableA2
lightblue
0...0
.0.0.
.0.0.
.0.0.
0...0

JumpVariableT
lightblue
..0..
.000.
.0.0.
.000.
.....

JumpVariableT1
lightblue
..0..
..0..
..0..
..0..
.....

JumpVariableT2
lightblue
..0..
.0.0.
.0.0.
.0.0.
.....

JumpVariableB
lightblue
.....
.000.
.0.0.
.000.
..0..

JumpVariableB1
lightblue
.....
..0..
..0..
..0..
..0..

JumpVariableB2
lightblue
.....
.0.0.
.0.0.
.0.0.
..0..

Dirt
brown darkbrown
00000
01000
00000
00010
00000

Tunnel
brown darkbrown
00000
01000
.....
.....
.....


Grass
brown lightgreen green darkBrown
11211
21020
00000
00030
00000

Exit
pink red
.1.1.
10101
10001
.101.
..1..

WoodenWall
Brown orange
.111.
.001.
.111.
.100.
.111.

Teleport
Brown darkBrown pink white
23332
02220
00000
00010
00000

Fire
red orange yellow
..0..
.00..
0110.
01210
.020.

TwiLeft
purple
.0...
00...
.0000
.0.0.
.0.0.

TwiRight
purple
...0.
...00
0000.
.0.0.
.0.0.

TeleportingTwilight
purple
...0.
...00
0000.
.0.0.
.0.0.

RdLeft
#00dddd
.0...
00...
.0000
.0.0.
.0.0.

RdRight
#00dddd
...0.
...00
0000.
.0.0.
.0.0.

AbLeft
yellow red
..1..
.01..
00...
.0000
.0.0.

AbRight
yellow red
..1..
..10.
...00
0000.
.0.0.

AjLeft
orange
.0...
00...
.0000
.0.0.
.0.0.

AjRight
orange
...0.
...00
0000.
.0.0.
.0.0.

DeadPony
lightGray darkGray
.111.
10001
10101
10001
10101

Boulder
lightGray darkGray
.....
.111.
10001
10001
.111.

=======
LEGEND
=======

Applejack=AjLeft or AjRight
RainbowDash=RdLeft or RdRight
Twilight=TwiLeft or TwiRight
AppleBloom=AbLeft or AbRight
(NotPegasus=Twilight or Applejack or AppleBloom or TeleportingTwilight)
Player=Twilight or Applejack or AppleBloom or RainbowDash
Obstacle=Grass or Dirt or DeadPony or WoodenWall or Teleport or Boulder
JumpObstacle=Obstacle or Player or Tunnel
JumpObstacleForFillies=Obstacle or Player
JumpVariablePositiveA=JumpVariableA1 or JumpVariableA2
JumpVariablePositiveT=JumpVariableT1 or JumpVariableT2
JumpVariablePositiveB=JumpVariableB1 or JumpVariableB2

. = Background
# = Dirt
~ = Grass
| = WoodenWall
T = TwiRight
A = AjRight
D = RdRight
B = AbRight
J = JumpVariableA
H = JumpVariableT
L = JumpVariableB
E = Exit
^ = Teleport
F = Fire
O = Boulder
- = Tunnel

=========
SOUNDS
=========

sfx0 47251907 (aj push)
sfx1 13930501 (twi zap)
sfx2 99083104 (death)
sfx3 12667901 (twi teleport)
sfx4 60310105 (jump)
sfx5 58764102 (rd smash)
sfx7 74120302 (aj buck)
endlevel 64815700



================
COLLISIONLAYERS
================

Background
JumpVariableA, JumpVariablePositiveA, JumpVariableT,JumpVariablePositiveT, JumpVariableB, JumpVariablePositiveB
Exit, Fire, Tunnel
Player, Obstacle, TeleportingTwilight

======
RULES
======

[> Player |Stationary Player] -> cancel
[> Player |< Player] -> cancel

[> Applejack| Tunnel] -> [Applejack|Tunnel]
[> RainbowDash| Tunnel] -> [RainbowDash|Tunnel]
[> Twilight| Tunnel] -> [Twilight|Tunnel]
Vertical [> AppleBloom|Tunnel] -> [AppleBloom|Tunnel]

[Left TwiRight] -> [Left TwiLeft]
[Right TwiLeft] -> [Right TwiRight]
[Left RdRight] -> [Left RdLeft]
[Right RdLeft] -> [Right RdRight]
[Left AjRight] -> [Left AjLeft]
[Right AjLeft] -> [Right AjRight]
[Left AbRight] -> [Left AbLeft]
[Right AbLeft] -> [Right AbRight]

Right[Action Applejack|WoodenWall] -> [AjLeft|]sfx7
Left[Action Applejack|WoodenWall] -> [AjRight|]sfx7

Down[Action Twilight|Teleport][no Player|Teleport]-> [|Teleport][TeleportingTwilight|Teleport] sfx3
late[TeleportingTwilight]->[TwiRight]


UP [ Up Applejack | No Obstacle No Player no tunnel] [JumpVariableA] -> [ Up Applejack | ] [JumpVariableA2] sfx4
DOWN [ Up Applejack | no obstacle No Player no tunnel ][JumpVariablePositiveA] -> [ Applejack | ][JumpVariablePositiveA]
DOWN [ Up Applejack | no obstacle No Player no tunnel][JumpVariableA2] -> [ Applejack | ][JumpVariableA2]
HORIZONTAL [ > Applejack | NO obstacle No Player no tunnel][JumpVariableA1] -> [ | Applejack ][JumpVariableA]
HORIZONTAL [ > Applejack | NO obstacle No Player no tunnel][JumpVariableA2] -> [ | Applejack ][JumpVariableA1]
HORIZONTAL [ > Applejack | JumpObstacle][JumpVariableA1] -> [ Applejack|JumpObstacle ][JumpVariableA]
HORIZONTAL [ > Applejack | JumpObstacle][JumpVariableA2] -> [ Applejack|JumpObstacle ][JumpVariableA1]
LATE DOWN [ Applejack | NO obstacle No Player no tunnel][JumpVariableA] -> [ | Applejack ][JumpVariableA]
LATE DOWN [ Applejack | Obstacle ][JumpVariablePositiveA] -> [ Applejack | Obstacle ][JumpVariableA]


UP [ Up Twilight | No Obstacle No Player no tunnel] [JumpVariableT] -> [ Up Twilight | ] [JumpVariableT2] sfx4
DOWN [ Up Twilight | no obstacle No Player no tunnel ][JumpVariablePositiveT] -> [ Twilight | ][JumpVariablePositiveT]
DOWN [ Up Twilight | no obstacle No Player no tunnel][JumpVariableT2] -> [ Twilight | ][JumpVariableT2]
HORIZONTAL [ > Twilight | NO obstacle No Player no tunnel][JumpVariableT1] -> [ | Twilight ][JumpVariableT]
HORIZONTAL [ > Twilight | NO obstacle No Player no tunnel][JumpVariableT2] -> [ | Twilight ][JumpVariableT1]
HORIZONTAL [ > Twilight | JumpObstacle][JumpVariableT1] -> [ Twilight|JumpObstacle ][JumpVariableT]
HORIZONTAL [ > Twilight | JumpObstacle][JumpVariableT2] -> [ Twilight|JumpObstacle ][JumpVariableT1]
LATE DOWN [ Twilight | NO obstacle No Player no tunnel][JumpVariableT] -> [ | Twilight ][JumpVariableT]
LATE DOWN [ Twilight | Obstacle ][JumpVariablePositiveT] -> [ Twilight | Obstacle ][JumpVariableT]


UP [ Up AppleBloom | No Obstacle No Player no tunnel] [JumpVariableB] -> [ Up AppleBloom | ] [JumpVariableB2] sfx4
DOWN [ Up AppleBloom | no obstacle No Player no tunnel ][JumpVariablePositiveB] -> [ AppleBloom | ][JumpVariablePositiveB]
DOWN [ Up AppleBloom | no obstacle No Player no tunnel][JumpVariableB2] -> [ AppleBloom | ][JumpVariableB2]
HORIZONTAL [ > AppleBloom | NO obstacle No Player][JumpVariableB1][ -> [ | AppleBloom ][JumpVariableB]
HORIZONTAL [ > AppleBloom | NO obstacle No Player][JumpVariableB2] -> [ | AppleBloom ][JumpVariableB1]
HORIZONTAL [ > AppleBloom | JumpObstacleForFillies][JumpVariableB1] -> [ AppleBloom|JumpObstacleForFillies ][JumpVariableB]
HORIZONTAL [ > AppleBloom | JumpObstacleForFillies][JumpVariableB2] -> [ AppleBloom|JumpObstacleForFillies ][JumpVariableB1]
LATE DOWN [ AppleBloom | NO obstacle No Player no tunnel][JumpVariableB] -> [ | AppleBloom ][JumpVariableB]
LATE DOWN [ AppleBloom | Obstacle ][JumpVariablePositiveB] -> [ AppleBloom | Obstacle ][JumpVariableB]
)

late [Player Fire] -> [DeadPony Fire] sfx2

[> Applejack|Boulder|no Obstacle No Player] -> [> Applejack| > Boulder |] sfx0
[> RainbowDash|Boulder|no Obstacle No Player] -> [> RainbowDash||] sfx5
Right [Action TwiRight|Boulder] -> [TwiRight|] sfx1
Left [Action TwiLeft|Boulder] -> [TwiLeft|] sfx1

[Boulder Fire] -> [Boulder]

late down [Boulder|Player] -> [|DeadPony] sfx2
late down [Boulder| no Obstacle no Tunnel] -> [|Boulder no Fire]
late [Boulder Fire] -> [Boulder]

==============
WINCONDITIONS
==============

some Player
all Exit on Player
no DeadPony


=======
LEVELS
=======

(message #1. Grab the Crystal Heart.)

..........H
...........
.........E.
..T....~~~~
~~~~~~#####
###########


message #2. Applejack bucks and pushes.

..........J
..~~~~~~~~~
...########
.A.|.o...E#
######.####
###########

message #3. Twilight teleports and zaps.

...........H
............
............
.T....E.O...
~^~FFF~~~~^~
############

message #4. Rainbow Dash flies and smashes.

#########
....#..E#
....O..##
....#..##
.D..#..##
#########

message #5. Rocks fall, everyone dies.

.........J
..........
...~~~~~.~
~~O..O...#
##|A.O..E#
##########

message #6. Cooperate with friends.

J.....###
......###
...D..#.E
....#..O#
.A..O..|#
~~~######
#########

message #7. Cooperate with family.

##.......JL#####
---..O.A.O.#...#
###~.~~~~~.#..E#
###.F..B..F-.###
####.#####.#####
################


message #8. Help a filly get a cutie mark!
~~~~~..........L
#####.........D.
###E-....O......
######...O......
#######.###...B.
############~~~~

message Aww... Still no cutie mark...

message #9. Explore dangerous caves!

.........##############
.......###O############
JHL..#####O############
...#######O############
..#####..-O------O-E###
######..##O######O#####
#####..###|...A..O.....
####..####O###^.#######
####.-----O-------...B.
##########O############
..........O..........T.
############^##########

message #10. Friendship is magic!

JH.........###
.......O.#.#OE
DAT....|.#..O#
~~~.~~~.~###O#
.......F.#..O#
########^#^###

message #11. Evil enchantress.
~~~~~...............JHL
#####~~~~~~~~~~........
################.......
###......###...........
###..O.O.F.....#.#..D..
#E-..#B#.|O........A.T.
#############.~~~~~~~~~
#######################


message #12. Equestrian Games.

###############################
#########O#####################
#########O#####################
###......O..................JHL
###..O.#.O..............D......
#E-..#B#.O.....................
#########O#####################
#........|.....................
#########O#####..|.|.|.|.|.....
#........O....##.#.#.#.#.#.A...
############...################
#############..................
###############...F........T...
###############################

message Congratulations!

message The Mushroom Kingdom is now safe!

message I mean, the Crystal Empire.