title Dungeon Janitor
author Farbs
homepage www.farbs.org
noundo
noaction
key_repeat_interval 0.1

========
OBJECTS
========

Background
DARKBLUE BLACK
11111
10000
10000
10000
10000

Entry
LIGHTBROWN BROWN DARKBROWN GRAY
30103
10101
10121
10101
10101

ExitClosed
LIGHTBROWN BROWN DARKBROWN GRAY
30103
10101
10121
10101
10101

ExitOpen
GRAY BLACK DARKBLUE
01110
11111
11111
11111
12221

Slime
LIGHTGREEN GREEN DARKGREEN
.....
.....
.....
.....
.....

Head
LIGHTGREEN GREEN DARKGREEN BLACK
.000.
03130
11111
23332
.222.

SlimeU
LIGHTGREEN GREEN DARKGREEN
11111
21112
.222.
.....
.....

SlimeD
LIGHTGREEN GREEN DARKGREEN
.....
.....
.000.
01110
11111

SlimeUD
LIGHTGREEN GREEN DARKGREEN
11111
11111
11111
11111
11111

SlimeL
LIGHTGREEN GREEN DARKGREEN
00...
110..
111..
112..
22...

SlimeR
LIGHTGREEN GREEN DARKGREEN
...00
..011
..111
..211
...22

SlimeLR
LIGHTGREEN GREEN DARKGREEN
00000
11111
11111
11111
22222

SlimeUL
LIGHTGREEN GREEN DARKGREEN
11111
11112
1112.
112..
22...

SlimeUR
LIGHTGREEN GREEN DARKGREEN
11111
21111
.2111
..211
...22

SlimeULR
LIGHTGREEN GREEN DARKGREEN
11111
11111
11111
11111
22222

SlimeDL
LIGHTGREEN GREEN DARKGREEN
00...
110..
1110.
11110
11111

SlimeDR
LIGHTGREEN GREEN DARKGREEN
...00
..011
.0111
01111
11111

SlimeDLR
LIGHTGREEN GREEN DARKGREEN
00000
11111
11111
11111
11111

SlimeUDLR
LIGHTGREEN GREEN DARKGREEN
11111
11111
11111
11111
11111

SlimeSolo
LIGHTGREEN GREEN DARKGREEN
.000.
01110
11111
21112
.222.

Wall
LIGHTGREY GREY
11111
01000
01000
11111
00010

PlayerA
Black Orange White Blue Brown
.....
.11..
2224.
333.4
3.322

PlayerB
Black Orange White Blue Brown
.....
.11..
.4222
4.333
223.3

Temp
PINK
00000
00000
00000
00000
00000

=======
LEGEND
=======

. = Background
# = Wall
E = Wall AND Entry
P = PlayerA
O = Slime AND Head
X = Wall AND ExitClosed

SlimeDecal = SlimeU OR SlimeD OR SlimeUD OR SlimeL OR SlimeR OR SlimeLR OR SlimeUL OR SlimeUR OR SlimeULR OR SlimeDL OR SlimeDR OR SlimeDLR OR SlimeUDLR OR SlimeSolo
Player = PlayerA OR PlayerB

=======
SOUNDS
=======

================
COLLISIONLAYERS
================

Background
Slime
SlimeU, SlimeD, SlimeUD, SlimeL, SlimeR, SlimeLR, SlimeUL, SlimeUR, SlimeULR, SlimeDL, SlimeDR, SlimeDLR, SlimeUDLR, SlimeSolo, ExitOpen
Player, Wall, PlayerA, PlayerB, Temp
Head, Entry, ExitClosed

======
RULES
======

(Stomp Heads)
[ > Player | Head ] -> [ > Player | NO Head ]
[ > Player | Slime ] -> [ > Player | NO Slime ]

(New Head)
[ Head ] -> []
RANDOM [ Slime NO Player ] -> [ Slime Head ]

(Grow Slime)
[ Head | NO Slime NO Wall NO Player ] -> [ Head | Slime ]

(Clear Slime from under player)
[ > Player | Slime ] -> [ > Player | NO Slime ]
LATE [ Player Slime ] -> [ Player NO Head ]

(Make slime pretty)
[ SlimeDecal ] ->[ ]
VERTICAL [ Slime | Slime | Slime ] -> [ Slime | Slime SlimeUD | Slime ]
UP [ Slime NO SlimeUD | Slime ] -> [ Slime SlimeU | Slime ]
DOWN [ Slime NO SlimeUD | Slime ] -> [ Slime SlimeD | Slime ]
HORIZONTAL [ Slime | Slime NO SlimeU NO SlimeD NO SlimeUD | Slime ] -> [ Slime | Slime SlimeLR | Slime ]
LEFT [ Slime NO SlimeU NO SlimeD NO SlimeUD NO SlimeLR | Slime ] -> [ Slime SlimeL | Slime ]
RIGHT [ Slime NO SlimeU NO SlimeD NO SlimeUD NO SlimeLR | Slime ] -> [ Slime SlimeR | Slime ]
HORIZONTAL [ Slime | Slime SlimeU | Slime ] -> [ Slime | Slime SlimeULR | Slime ]
LEFT [ Slime SlimeU | Slime ] -> [ Slime SlimeUL | Slime ]
RIGHT [ Slime SlimeU | Slime ] -> [ Slime SlimeUR | Slime ]
HORIZONTAL [ Slime | Slime SlimeD | Slime ] -> [ Slime | Slime SlimeDLR | Slime ]
LEFT [ Slime SlimeD | Slime ] -> [ Slime SlimeDL | Slime ]
RIGHT [ Slime SlimeD | Slime ] -> [ Slime SlimeDR | Slime ]
[ Slime NO SlimeDecal ] -> [ Slime SlimeSolo ]

( Shut the door if slime still around)
( Have to open it first unfortunately )
[ ExitClosed Wall ] -> [ ExitOpen ]
[ ExitOpen ][ Slime ] -> [ ExitClosed Wall ][ Slime ]

(Player Anim)
[ LEFT PlayerB ] -> [ LEFT PlayerA ]
[ RIGHT PlayerA ] -> [ RIGHT PlayerB ]
LATE [ PlayerA ] -> [ Temp ]
LATE [ PlayerB ] -> [ PlayerA ]
LATE [ Temp ] -> [ PlayerB ]
==============
WINCONDITIONS
==============

ALL Player ON ExitOpen

=======
LEVELS
=======

MESSAGE It's Thursday.
MESSAGE Today I mop the slime pit.


##X##
##.##
##.##
##O##
##.##
##P##
##E##

MESSAGE Damn slime sticking to my shoes.

..####..
..#O.#..
###..###
#......#
#P#..#.#
#E#..#X#
..####..

MESSAGE Goes SHLUCK SHCLUK when I walk.

######X#############
###......#...#...###
###.##.#...#...#...#
##.....###########.#
#..#.#.....#.......#
#.##.###.#.##.######
#......#.#.#.O.....#
#.####.#.#.#.#####.#
#P.....#.#.........#
#E##################

MESSAGE Last room before home.
MESSAGE This one can take a while.

##########X#########
#..................#
#..................#
#..#######.######..#
#..#.#...#.#.#..#..#
#..#...#.#.#.#..#..#
#..#.....#.#.#..#..#
#..##....#.#...##..#
#..#............#..#
#..#......O.....#..#
#..#............#..#
#..#............#..#
#..##############..#
#.........P........#
##########E#########

MESSAGE Done for the day. Back tomorrow.
MESSAGE Fridays is rat scrubbing day.