title Collapse
author Terry Cavanagh
homepage www.distractionware.com

color_palette pastel
youtube 4XglYW89WLQ

background_color Black
text_color LightRed

noaction

flickscreen 16x10

========
OBJECTS
========

Exit D
Black
.....
.....
.....
.....
.....

OutdoorBackground
lightred

IndoorBackground
white lightgray
11011
11011
11011
11011
11011


Wall W
Yellow Orange
00000
00010
00000
01000
00000

SolidWall Q
#FF0000 #992222
00000
00001
00111
01111
11111

Door X
DarkBlue White Blue
00200
10201
00200
10201
00200

Jettrail1
DarkGray
..0..
.000.
00.00
.000.
..0..


Jettrail2
DarkGray
.....
..0..
.0.0.
..0..
.....

Key
Blue
.000.
.0.0.
.000.
..0..
.00..

Flower F
DarkBlue Green blue
.22..
2002.
.22..
..1..
..1..

Mine M
Red #BB0000
10001
01110
11011
01110
10001

Blood
#FF0000 #AA0000
10101
01110
11011
01110
10101

Blood2
#FF0000 #AA0000
01010
10101
01010
10101
01010


PlayerDead
Red Black
10001
10001
00000
10001
10101

PlayerGround P
Black
.000.
.000.
00000
.000.
.0.0.

PlayerHover
Black
.000.
00000
.000.
.000.
0...0

PlayerHoverLeft
Black
.000.
0000.
.000.
.000.
..0.0

PlayerHoverRight
Black
.000.
.0000
.000.
.000.
0.0..

Temp
black

=======
LEGEND
=======

Background = OutdoorBackground or IndoorBackground
Player = PlayerGround or PlayerHover or PlayerHoverLeft or PlayerHoverRight or PlayerDead
InGamePlayer = PlayerGround or PlayerHover
FlyingPlayer = PlayerHoverLeft or PlayerHoverRight
Obstacle = Wall or Mine or SolidWall or Door
ObstacleExMine = Wall or SolidWall or Door

. = OutdoorBackground
, = IndoorBackground
# = Wall
P = Player
k = Key and IndoorBackground

=======
SOUNDS
=======

sfx0 53720504 (jump up)
sfx1 14370308 (bomb)
sfx2 41983504 (jetpack)
sfx3 86827507 (fall)
sfx4 56160703 (door)
sfx5 98568902 (blockpush)
sfx6 77665108 (collapse)

================
COLLISIONLAYERS
================

Background
Jettrail1, Jettrail2, Exit
Player, Wall, Solidwall, temp, playerhoverleft, playerhoverright, mine, Key, Flower, Door
blood, blood2

======
RULES
======

right [ moving Playerdead] -> [PlayerDead]

[> IngamePlayer | mine ] -> [ > PlayerDead | blood ] sfx1
Vertical [ PlayerGround | mine ] -> [ playerdead | blood2 ] sfx1
Horizontal [flyingplayer | mine ] -> [ playerdead | blood2 ] sfx1

Horizontal [> PlayerGround | Key] [Door] -> [> PlayerGround | Key] []
Horizontal [> PlayerGround | Key]-> [> PlayerGround | ] sfx4

Horizontal [> PlayerGround | Flower] [Door] -> [> PlayerGround | Flower] []
Horizontal [> PlayerGround | Flower]-> [> PlayerGround | ] sfx6

UP [Up PlayerGround | No Obstacle | No Obstacle] -> [ | | PlayerHover ] sfx0
UP [Up PlayerGround | No Obstacle] -> [ | PlayerHover ] sfx0


right [right PlayerHover] -> [PlayerHoverRight]
left [left PlayerHover] -> [PlayerHoverLeft]
up [up PlayerHover] -> [PlayerHover]
down [down PlayerHover] -> [PlayerGround]

down [JetTrail2] -> []
down [JetTrail1] -> [JetTrail2]

(random rule here is a hack workaround)
random right [ PlayerHoverRight | No Obstacle] -> [ JetTrail1 | PlayerHoverRight] again sfx2
horizontal [ PlayerHoverRight | ObstacleExMine] -> [ PlayerGround | ObstacleExMine]
down [ PlayerHoverRight | ObstacleExMine] -> [ PlayerGround | ObstacleExMine]

random left [ PlayerHoverLeft | No Obstacle] -> [JetTrail1 | PlayerHoverLeft] again sfx2
horizontal [ PlayerHoverLeft | ObstacleExMine] -> [ PlayerGround | ObstacleExMine]
down [ PlayerHoverLeft | ObstacleExMine] -> [ PlayerGround | ObstacleExMine]

horizontal [> PlayerGround | Wall] -> [> PlayerGround | > wall] sfx5
horizontal [> Wall | Wall] -> [> Wall | > wall]
horizontal [> Wall | Mine] -> [> Wall | > Mine]

down [stationary wall] -> [ down wall] again
down [stationary mine] -> [ down mine] again

[blood | no blood ] -> [blood | blood2] again
[blood2 | no blood ] -> [blood2 | blood] again

late down [  PlayerGround | No Obstacle ] -> [ JetTrail1 |  temp] again sfx3
late down [temp] -> [playerground]

==============
WINCONDITIONS
==============
No Flower
All Player on Exit

=======
LEVELS
=======

MESSAGE The last flower...
MESSAGE Will I find it on this planet?

qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq
q,,,,,,,,,,,,,,qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq
q,,,,,,,,,,,,,,,,,,,,,,,q,,,,,,,,,,,,qqqqqqqqqqq
q,,,,,,,,qq,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,x,D
q,,,,,,,,qqqqqqqqqqqqq,,K,,,,,,,,,,,,,,,,,,,,x,D
qqq,,,,,,qqqqqqqqqqqqq,,qqqqqqqqqqq,,,,,,,,,,x,D
qqq,p,,,,qqqqqqqqqqqqq,,,,,,,,,,,,,,,,,,qqq,,x,D
qqqqq,,,,qqqqqqqqqqqqq,,,,,,,,,,,,,,,,,,qqqqqqqq
qqqqqmmmmqqqqqqqqqqqqqmqqmmmmmmmmmmmmmqqqqqqqqqq
qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq

qq................q........q..........w....qmmmmmmq.............q
qq..................w.................w....qmmmmmmq.............q
qq...............q..w.................wm....qmmmmmq.............q
qqq..............q..w.................ww....qmmmmqq...........f.q
qqq..............qwww.......w.........ww.....qmmmq...........wwwq
q.........ww......wqwmmw....w.........ww..w..qwqqq...........wwwq
DP........ww......q.mqwww...w........wwwwwwwwwwwww...........wwwq
qww.......ww........qqqqq...w.wwwww..wwwwwwwwwqwww..........wwwwm
qwwwwm..wwwwwwwwwwwww.qqqqmmw.wwwwww.wwwwwwwwwqqww...q...wwwmwwwq
qwwwwwwqwwwwmwwwwwmww.wqqqwwwwwwwwwwmwwwwwwwwwqqqqwwwwwwwwqwwwwwq
mxxxxxxxxxxxxxxxxxxxxxxqxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxq
m....................q.q................................m.......q
m......................q................................q.......q
m......................q........................................q
m......................q........................................q
m......................q........................w...............q
m...............w......q........w............w..w...............q
mmm.....m..m....w.mmmm.mmm...m..w....mm..m...wmmw..m.mm.....m...q
mwmmmmmmm.mmwmmmmmmmmmmmmwmmmmmmmwmmmmwmmmmmmmmmmmmmmmmm.mmmmmm.q
mmwmmmmwmmmmmmmmmwmmmwmmmmmmmwmmmmmmmmmmwmmmmmmmmmmmmmmmmmmmmmmmq

MESSAGE Collapse
MESSAGE Music [Cryptobiosis by Sync24]
MESSAGE Thanks for playing